Return cells only containing certain letters

[oaj1977]

Here’s my scenario:

I have a list of words and a list of letters.
I want to return the words that contain letters from the list of letters and ONLY from the list of letters. For example:

WORDS: cog, bib, ab, back, cab
LETTERS: A, B, C
WORDS returned: ab, cab

Thoughts?

 

[Peter_SSs]

It runs, but it seems to be returning all words that contain any of the letters.

Yes, the code was incorrect. I edited the code as I posted and missed one correction. Oops again.
If you wish, you could give this corrected version a try. Also modified to be not case-sensitive.

Sub Get_Allowed_v3()
  Dim a As Variant, b As Variant
  Dim i As Long, k As Long
  Dim sLike As String
  
  a = Range("A2", Range("A" & Rows.Count).End(xlUp)).Value
  ReDim b(1 To UBound(a), 1 To 1)
 
  sLike = "*[!" & UCase(Join(Application.Transpose(Range("D1", Range("D" & Rows.Count).End(xlUp))), "")) & "]*"
  For i = 1 To UBound(a)
    If Not UCase(a(i, 1)) Like sLike Then
      k = k + 1
      b(k, 1) = a(i, 1)
    End If
  Next i
  Range("B2").Resize(k).Value = b
End Sub

Some sample data and results:

oaj1977.xlsm
	A	B	C	D
1	Words	Allowed	Letters:	d
2	Cat	dog		o
3	dog	god		t
4	mouse	Godot		g
5	god	toogood
6	Godot
7	togs
8	ban
9	toogood
10
Sheet3