referencing combobox value to populate lines in textbox with proper entries

[Watchdawg]

I've looked around and I'm having some trouble finding this (probably not wording it right).
I have a list of functions in A5:A50
A list of names spans D3:V3
D5:V50 involves boxes containing "C", "R", or "I" referencing that they have a responsibility in the function in column A

The userform populates from the functions in A, so when that changes, a textbox populates. What I need is the textbox to populate with a list of names (each on a single line) that have the C, R or I designator in the box matching both the name and the function.

Wow, I really hope that came across correctly.
Anyone that can help? Or lead me to a thread that I've missed?

 

[DanteAmor]

Forget all of the above, use the following to populate textbox1 and textbox2.

Private Sub ComboBox1_Change()
  Dim f As Range
  Dim sh As Worksheet
  Dim i As Long, j As Long
  
  With TextBox2
    TextBox1.Value = ""
    .MultiLine = True
    .Value = ""

    Set sh = Sheets("Functional Contacts")
    Set f = sh.Range("A:A").Find(ComboBox1.Value, , xlValues, xlWhole, , , False)
    If Not f Is Nothing Then
      i = f.Row
      For j = 4 To sh.Cells(i, Columns.Count).End(1).Column
        Select Case sh.Cells(i, j).Value
          Case "C", "R", "I"
            .Value = .Value & vbCr & sh.Cells(3, j)
        End Select
      Next
      
      TextBox1.Value = sh.Range("C" & i).Value
      
    End If
  End With
End Sub

 

[DanteAmor]

I can't download your file because it asks me to sign up for dropbox.

But I think you're using the RowSource property of the combobox as follows:

If not, also forget it, try the code of the post #11

 

[Watchdawg]

Forget all of the above, use the following to populate textbox1 and textbox2.

Private Sub ComboBox1_Change()
  Dim f As Range
  Dim sh As Worksheet
  Dim i As Long, j As Long
 
  With TextBox2
    TextBox1.Value = ""
    .MultiLine = True
    .Value = ""

    Set sh = Sheets("Functional Contacts")
    Set f = sh.Range("A:A").Find(ComboBox1.Value, , xlValues, xlWhole, , , False)
    If Not f Is Nothing Then
      i = f.Row
      For j = 4 To sh.Cells(i, Columns.Count).End(1).Column
        Select Case sh.Cells(i, j).Value
          Case "C", "R", "I"
            .Value = .Value & vbCr & sh.Cells(3, j)
        End Select
      Next
     
      TextBox1.Value = sh.Range("C" & i).Value
     
    End If
  End With
End Sub

Thank you so much! That worked like a charm, I really appreciate your patience.

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.