ComboBox Only Recognizes Text Items When Selecting a Value To Populate ListBox

[RunTime91]

Greetings All...

Setup:

I am providing the enduser (eu) a list of items in a ComboBox on a UserForm. When the eu selects an item from the ComboBox, a ListBox will populate with another list from which the eu can make a selection to open word/pdf docs providing the eu with written instructions about the topic selected in the ListBox.

Everything works great until the eu selects one of the items in the ComboBox list that is a number instead of text. When this happens the code brings back nothing.
I've tested this and if I change 435 to 435C the ListBox will populate with the links to the documents regarding the 435. If I remove the 'C' the code once again brings back nothing.

I have tried to change the format of the list that populates the ComboBox at the sheet level using the Format Cells window - No change.

So I'm assuming I have to fix this at the code level. Is there an easy fix to this?

Not sure what code I can provide to help you, help me...

But please let me know as, I definitely need help

Sincerely,

RT91

 

[Artik]

Error in explicit conversion procedure.
Should be:

Private Sub CmbSortTest_Change()
    Dim v As Variant
    Dim vCmbVal As Variant
    Dim k As Long
    Dim i As Long
    Dim vLst As Variant

    v = Worksheets("I&I").Range("D2:E54").Value

    vCmbVal = Me.CmbSortTest.Value
    If IsNumeric(vCmbVal) Then
        vCmbVal = CDbl(vCmbVal)
    End If

    ReDim vLst(1 To UBound(v))

    Me.LstHowToDocs.Clear

    For i = 2 To UBound(v)
        If vCmbVal = v(i, 1) Then
            k = k + 1
            vLst(k) = v(i, 2)
        End If
    Next i

    If k > 0 Then
        ReDim Preserve vLst(1 To k)
        Me.LstHowToDocs.Column = vLst
    End If
End Sub

Artik