Lock-UnLock VBAProjects Programmatically without SendKeys

[Jaafar Tribak]

Hi all,

I Have recently written this piece of code so I just thought I would post it here for future reference should anyone be looking for vba code to lock\unlock a vbaproject programmatically without needing to use the unreliable SendKeys method.

workbook example

This code requires that the excel macro security setting "Trust access to the vba project object model" be checked... .Also, it is worth mentioning that this code is language-specific as it reads the VBE dialog captions. So this code won't work in Non-English editions of excel but, should be easy to adapt with some small changes.

The code was written and tested in excel 2016-64bit.

Code goes in a Standard Module:

Option Explicit

#If VBA7 Then
    Private Declare PtrSafe Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As LongPtr, ByVal hmod As LongPtr, ByVal dwThreadId As Long) As LongPtr
    Private Declare PtrSafe Function UnhookWindowsHookEx Lib "user32" (ByVal hhk As LongPtr) As Long
    Private Declare PtrSafe Function CallNextHookEx Lib "user32" (ByVal hHook As LongPtr, ByVal nCode As Long, ByVal wParam As LongPtr, lParam As Any) As LongPtr
    Private Declare PtrSafe Function GetCurrentThreadId Lib "kernel32" () As Long
    Private Declare PtrSafe Function GetDlgItem Lib "user32" (ByVal hDlg As LongPtr, ByVal nIDDlgItem As Long) As LongPtr
    Private Declare PtrSafe Function GetActiveWindow Lib "user32" () As LongPtr
    Private Declare PtrSafe Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As LongPtr, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
    Private Declare PtrSafe Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As LongPtr, ByVal lpString As String, ByVal cch As Long) As Long
    Private Declare PtrSafe Function GetNextWindow Lib "user32" Alias "GetWindow" (ByVal hwnd As LongPtr, ByVal wFlag As Long) As LongPtr
    Private Declare PtrSafe Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As LongPtr, ByVal hwnd2 As LongPtr, ByVal lpsz1 As String, ByVal lpsz2 As String) As LongPtr
    Private Declare PtrSafe Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, ByVal lParam As String) As LongPtr
    Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As LongPtr) As LongPtr
    Private Declare PtrSafe Function SetTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As LongPtr, ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As LongPtr
    Private Declare PtrSafe Function KillTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As LongPtr) As Long
    Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As LongPtr, ByVal hWndInsertAfter As LongPtr, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
    Private Declare PtrSafe Function SetActiveWindow Lib "user32" (ByVal hwnd As LongPtr) As LongPtr
    
    Private lHook As LongPtr
#Else
    
    Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) As Long
    Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hhk As Long) As Long
    Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, ByVal nCode As Long, ByVal wParam As Long, lParam As Any) As Long
    Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long
    Private Declare Function GetDlgItem Lib "user32" (ByVal hDlg As Long, ByVal nIDDlgItem As Long) As Long
    Private Declare Function GetActiveWindow Lib "user32" () As Long
    Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
    Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
    Private Declare Function GetNextWindow Lib "user32" Alias "GetWindow" (ByVal hwnd As Long, ByVal wFlag As Long) As Long
    Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hwnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
    Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As String) As Long
    Private Declare Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function SetTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long
    Private Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, ByVal nIDEvent As Long) As Long
    Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
    Private Declare Function SetActiveWindow Lib "user32" (ByVal hwnd As Long) As Long
    
    Private lHook As Long
#End If

Private sWinClassName As String, sWorkbookName As String, sPassword As String



Public Property Let LockVBProject(ByVal WorkbookName As String, ByVal Password As String, ByVal bLock As Boolean)

    #If VBA7 Then
        Dim hwnd As LongPtr
    #Else
        Dim hwnd As Long
    #End If
    
    Const WH_CBT = 5

    On Error GoTo errHandler

    hwnd = GetActiveWindow
    
    With Application.VBE
        Set .ActiveVBProject = Application.Workbooks(WorkbookName).VBProject
        If bLock Then
            If .ActiveVBProject.Protection = 0 Then
                sWinClassName = "VBAProject - Project Properties"
                sWorkbookName = WorkbookName
            Else
                MsgBox "VBProect already locked": Exit Property
            End If
        Else
            If .ActiveVBProject.Protection Then
                sWinClassName = "VBAProject Password"
            Else
                MsgBox "VBProect already unlocked": Exit Property
            End If
        End If
    End With
    
    sPassword = Password
    lHook = SetWindowsHookEx(WH_CBT, AddressOf Catch_DlgBox_Activation, 0, GetCurrentThreadId)
    Application.VBE.CommandBars(1).FindControl(ID:=2578, recursive:=True).Execute
    
    If hwnd = Application.hwnd Then
        SetActiveWindow Application.hwnd
    End If
    
Exit Property

errHandler:
    Call UnHook
    MsgBox "Runtime Error : " & Err.Number & vbCr & vbCr & Err.Description, vbExclamation
    
End Property



#If VBA7 Then
    Private Function Catch_DlgBox_Activation(ByVal idHook As Long, ByVal wParam As LongPtr, ByVal lParam As LongPtr) As LongPtr
        Dim hwnd As LongPtr
#Else
    Private Function Catch_DlgBox_Activation(ByVal idHook As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
        Dim hwnd As Long
#End If

    Const HCBT_ACTIVATE = 5
    Const SWP_HIDEWINDOW = &H80

    Dim sBuff As String * 256, lRet As Long
    
    If idHook = HCBT_ACTIVATE Then
    lRet = GetClassName(wParam, sBuff, 256)
    If Left(sBuff, lRet) = "#32770" Then
        sBuff = ""
        lRet = GetWindowText(wParam, sBuff, 256)
        If Left(sBuff, lRet) = sWinClassName Then
            Call UnHook
            SetWindowPos wParam, 0, 0, 0, 0, 0, SWP_HIDEWINDOW
            Call SetTimer(Application.hwnd, wParam, 0, AddressOf Protect_UnProtect_Routine)
        End If
    End If
    End If
    
    Catch_DlgBox_Activation = CallNextHookEx(lHook, idHook, ByVal wParam, ByVal lParam)
 
End Function


Private Sub UnHook()
    UnhookWindowsHookEx lHook
End Sub


#If VBA7 Then
Private Sub Protect_UnProtect_Routine(ByVal hwnd As LongPtr, ByVal uMsg As Long, ByVal nIDEvent As LongPtr, ByVal dwTimer As Long)
    Dim hCurrentDlg As LongPtr, hwndSysTab As LongPtr
#Else
Private Sub Protect_UnProtect_Routine(ByVal hwnd As Long, ByVal uMsg As Long, ByVal nIDEvent As Long, ByVal dwTimer As Long)
    Dim hCurrentDlg As Long, hwndSysTab As Long
#End If

    Const TCM_FIRST = &H1300
    Const TCM_SETCURSEL = (TCM_FIRST + 12)
    Const TCM_SETCURFOCUS = (TCM_FIRST + 48)
    Const EM_SETMODIFY = &HB9
    Const BM_SETCHECK = &HF1
    Const BST_CHECKED = &H1
    Const BM_GETCHECK = &HF0
    Const BM_CLICK = &HF5
    Const WM_SETTEXT = &HC
    Const WH_CBT = 5
    Const GW_CHILD = 5
    
    On Error GoTo errHandler
    
    Call KillTimer(Application.hwnd, nIDEvent)
    
    hCurrentDlg = nIDEvent
    
    If sWinClassName = "VBAProject - Project Properties" Then
    
        hwndSysTab = FindWindowEx(hCurrentDlg, 0, "SysTabControl32", vbNullString)
        Call SendMessage(hwndSysTab, TCM_SETCURFOCUS, 1, 0)
        Call SendMessage(hwndSysTab, TCM_SETCURSEL, 1, 0)
        
        If SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1557), BM_GETCHECK, 0, 0) = 0 Then
            Call SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1557), BM_SETCHECK, BST_CHECKED, 0)
            Call SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1555), WM_SETTEXT, 0, sPassword)
            Call SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1555), EM_SETMODIFY, True, 0)
            Call SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1556), WM_SETTEXT, 0, sPassword)
            Call SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1556), EM_SETMODIFY, True, 0)
        End If
        
        Call SendMessage(GetDlgItem(hCurrentDlg, &H1), BM_CLICK, 0, 0)
        Call Application.OnTime(Now, "SaveVBProjectChanges")
        
    ElseIf sWinClassName = "VBAProject Password" Then
    
        Call SendMessage(GetDlgItem(hCurrentDlg, &H155E), WM_SETTEXT, 0, sPassword)
        Call SendMessage(GetDlgItem(hCurrentDlg, &H155E), EM_SETMODIFY, True, 0)
        lHook = SetWindowsHookEx(WH_CBT, AddressOf Catch_DlgBox_Creation, 0, GetCurrentThreadId)
        Call SendMessage(GetDlgItem(hCurrentDlg, &H1), BM_CLICK, 0, 0)
        Call Application.OnTime(Now, "UnHook")
        
    End If
    
    Exit Sub
    
errHandler:
    Call UnHook
    MsgBox "Runtime Error : " & Err.Number & vbCr & vbCr & Err.Description, vbExclamation


End Sub


#If VBA7 Then
    Private Function Catch_DlgBox_Creation(ByVal idHook As Long, ByVal wParam As LongPtr, ByVal lParam As LongPtr) As LongPtr
#Else
    Private Function Catch_DlgBox_Creation(ByVal idHook As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
#End If

    Const HCBT_CREATEWND = 3
    Dim sBuff As String * 256, lRet As Long
    
    If idHook = HCBT_CREATEWND Then
        lRet = GetClassName(wParam, sBuff, 256)
        If Left(sBuff, lRet) = "#32770" Then
            Catch_DlgBox_Creation = -1
            Exit Function
        End If
    End If
    
    Catch_DlgBox_Creation = CallNextHookEx(lHook, idHook, ByVal wParam, ByVal lParam)

End Function

Private Sub SaveVBProjectChanges()
    On Error Resume Next
    Application.EnableEvents = False
        Workbooks(sWorkbookName).Save
    Application.EnableEvents = True
End Sub

Code usage examples :

Sub Lock_Example()

    'To lock the vbproject. (change workbook name as required)
        LockVBProject(WorkbookName:="MyTestBook.xls", Password:="1234") = True

End Sub

Sub UnLock_Example()

    'To un-lock the vbproject. (change workbook name as required)
        LockVBProject(WorkbookName:="MyTestBook.xls", Password:="1234") = False

End Sub

 

[danitouffaha]

Hi Jaafar,

Thank you for the quick reply!!

I finally got it to work.

But I had to use a different approach, meaning the new file I am opening programmatically has to be opened in a new excel instance!

I was inspired by a thread I found on a different website, but I am not sure if I am allowed to post the link here or not, (please let me know so I can give the credit)

I had to tweak the code a little bit because initially it would open the properties and not close them

Anyway here is the code I ended up with


Notice I am passing the excel targetInstance because in the calling code, I decide if I should use my current instance or a new excel instance, and if it is a new one when I am done I close it!

Option Explicit

#If VBA7 Then

    Private Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr

    Private Declare PtrSafe Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As LongPtr, ByVal hwnd2 As LongPtr, ByVal lpsz1 As String, ByVal lpsz2 As String) As LongPtr

    Private Declare PtrSafe Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As LongPtr, ByVal lpString As String, ByVal cch As Long) As Long

    Private Declare ptrsafe Function GetWindowTextLength Lib "user32" Alias "GetWindowTextLengthA" (ByVal hwnd As Long) As Longptr

    Private Declare PtrSafe Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, ByVal lParam As String) As LongPtr

#Else

    Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

    Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long

    Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long

    Private Declare Function GetWindowTextLength Lib "user32" Alias "GetWindowTextLengthA" (ByVal hwnd As Long) As Long

    Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

#End If

 

Dim Ret As Long, ChildRet As Long, OpenRet As Long

Dim strBuff As String, ButCap As String

'Dim MyPassword As String


Public gforcedExit As Boolean

Private lastLockTime As Date


Const WM_SETTEXT = &HC

Const BM_CLICK = &HF5


Public Function unlockVBAProject(workbookPath As String, owb As Workbook, targetInstance As Object)

    Call logStartFunctionSub(False, False, "unlockVBAProject")

    If owb Is Nothing Then

        targetInstance.EnableEvents = False

        Set owb = targetInstance.Workbooks.Open(workbookPath)

    End If

    If isVBAProjectLocked(owb) = False Then

        Exit Function

    End If

    '~~> Launch the VBA Project Password window

    '~~> I am assuming that it is protected. If not then

    '~~> put a check here.

    targetInstance.VBE.CommandBars(1).FindControl(ID:=2578, recursive:=True).Execute

    '~~> Get the handle of the "VBAProject Password" Window

    Ret = FindWindow(vbNullString, "VBAProject Password")

    If Ret <> 0 Then

        'MsgBox "VBAProject Password Window Found"

      

        '~~> Get the handle of the TextBox Window where we need to type the password

        ChildRet = FindWindowEx(Ret, ByVal 0&, "Edit", vbNullString)

      

        If ChildRet <> 0 Then

            'MsgBox "TextBox's Window Found"

            '~~> This is where we send the password to the Text Window

            SendMess gadminPassword, ChildRet   'here put ur own PW

      

            DoEvents

      

            '~~> Get the handle of the Button's "Window"

            ChildRet = FindWindowEx(Ret, ByVal 0&, "Button", vbNullString)

          

            '~~> Check if we found it or not

            If ChildRet <> 0 Then

                'MsgBox "Button's Window Found"

  

                '~~> Get the caption of the child window

                strBuff = String(GetWindowTextLength(ChildRet) + 1, Chr$(0))

                GetWindowText ChildRet, strBuff, Len(strBuff)

                ButCap = strBuff

  

                '~~> Loop through all child windows

                Do While ChildRet <> 0

                    '~~> Check if the caption has the word "OK"

                    If InStr(1, ButCap, "OK") Then

                        '~~> If this is the button we are looking for then exit

                        OpenRet = ChildRet

                        Exit Do

                    End If

  

                    '~~> Get the handle of the next child window

                    ChildRet = FindWindowEx(Ret, ChildRet, "Button", vbNullString)

                    '~~> Get the caption of the child window

                    strBuff = String(GetWindowTextLength(ChildRet) + 1, Chr$(0))

                    GetWindowText ChildRet, strBuff, Len(strBuff)

                    ButCap = strBuff

                Loop

  

                '~~> Check if we found it or not

                If OpenRet <> 0 Then

                    '~~> Click the OK Button

                    SendMessage ChildRet, BM_CLICK, 0, vbNullString

                    Application.Wait DateAdd("s", 1, Now)

                  

                    Ret = FindWindow(vbNullString, "VBAProject - Project Properties")

                    ChildRet = FindWindowEx(Ret, ByVal 0&, "Button", vbNullString)

                    If ChildRet <> 0 Then

                        '~~> Get the caption of the child window

                        strBuff = String(GetWindowTextLength(ChildRet) + 1, Chr$(0))

                        GetWindowText ChildRet, strBuff, Len(strBuff)

                        ButCap = strBuff

          

                        '~~> Loop through all child windows

                        Do While ChildRet <> 0

                            '~~> Check if the caption has the word "OK"

                            If InStr(1, ButCap, "OK") Then

                                '~~> If this is the button we are looking for then exit

                                OpenRet = ChildRet

                                Exit Do

                            End If

          

                            '~~> Get the handle of the next child window

                            ChildRet = FindWindowEx(Ret, ChildRet, "Button", vbNullString)

                            '~~> Get the caption of the child window

                            strBuff = String(GetWindowTextLength(ChildRet) + 1, Chr$(0))

                            GetWindowText ChildRet, strBuff, Len(strBuff)

                            ButCap = strBuff

                        Loop

                        If OpenRet <> 0 Then

                            '~~> Click the OK Button

                            SendMessage ChildRet, BM_CLICK, 0, vbNullString

                        End If

                    End If

                Else

                    ecollectMessage = ecollectMessage & "-The OK Button handle was not found!" & newLine

                End If

            Else

                ecollectMessage = ecollectMessage & "-Button's Window Not Found!" & newLine

            End If

        Else

            ecollectMessage = ecollectMessage & "-The Edit Box was not found" & newLine

        End If

    Else

        ecollectMessage = ecollectMessage & "-VBAProject Password Window was not Found!" & newLine

    End If

End Function


Private Function SendMess(Message As String, hwnd As Long)

    Call SendMessage(hwnd, WM_SETTEXT, False, ByVal Message)

End Function


Public Function isVBAProjectLocked(aWorkbook As Workbook) As Boolean

    '1 = VB-Project protected

    '0 = VB-Project not protected

    isVBAProjectLocked = (aWorkbook.VBProject.Protection = 1)

End Function

Calling code, where I have a source workbook open and I open the locked target workbook, unlock, make code changes in it and then close it

    Dim wbTarget As Workbook

    Dim wbSource As Workbook

    Dim targetInstance As Object

    Dim sourceInstance As Object

......


            Set targetInstance = CreateObject("Excel.Application")

            Call unlockVBAProject(targetFileName, wbTarget, targetInstance) ' I pass the path to the workbook, an empty wbTarget, it will be set inside

            If isVBAProjectLocked(wbTarget) = True Then

                ecollectMessage = ecollectMessage & "-Failed to unprotect the Target project!" & vbaNewLine

                GoTo exitFunction

            End If


.....

    wbTarget.Close Savechanges:=True
     targetInstance.Quit
.....

Thanks again for your thread and sharing!!

Dani

 

[SkywardPalm]

The unlocking of the VBA doesn't seem to unlock it completely by unchecking the "Locked for Viewing" checkbox.. only allows you to read the code and it will still be locked the next time the file is opened. I have other macros that break when the code is locked, if there is any guidance towards this.

 

[pmajax]

Hi Jaafar,
I give a breath of life to this excellent thread !
Always seduced by your work and your generosity !

I would like a clarification regarding: Protect_UnProtect_Routine
You give:

... ElseIf sWinClassName = "VBAProject Password" Then  
        Call SendMessage(GetDlgItem(hCurrentDlg, &H155E), WM_SETTEXT, 0, sPassword)
        Call SendMessage(GetDlgItem(hCurrentDlg, &H155E), EM_SETMODIFY, True, 0)
        lHook = SetWindowsHookEx(WH_CBT, AddressOf Catch_DlgBox_Creation, 0, GetCurrentThreadId)
        Call SendMessage(GetDlgItem(hCurrentDlg, &H1), BM_CLICK, 0, ByVal 0&)
        Call Application.OnTime(Now, "UnHook")

Everything works well despite this Windows critical stop beep that we can hear at the end of the procedure.
IF I replace Call Application.OnTime(Now, "UnHook") by Call "UnHook"
I no longer have this awful sound but the properties window of the vba project remains open.
Your solution is the best because it shows no windows, but this beep, how to avoid it ?
Thanks for your help,
Pierre

 

[lordy888]

Thank you.

Jaafar Tribak.
Your code works great. However, I find the code wont work properly if closed the workbook programmatically
xWB.Close savechanges:=True

The code is as follows: May you have any idea fixing it? Thanks again.
​

Public Sub exportWB()
Const sFFPath As String = "D:\A.xlsm"
Dim xWB As Workbook
Set xWB = Workbooks.Add
LockVBProject(WorkbookName:=xWB.name, Password:="password") = True
xWB.SaveAs Filename:=sFFPath, _
FileFormat:=xlOpenXMLWorkbookMacroEnabled, _
ConflictResolution:=Excel.XlSaveConflictResolution.xlLocalSessionChanges
xWB.Close savechanges:=True

End Sub

​

 

[Jaafar Tribak]

@pmajax

Everything works well despite this Windows critical stop beep that we can hear at the end of the procedure.

Yes. That awful beep sound is due to the fact that I am aborting the creation of the "#32770" window.
It is not easy to prevent that sound unless we temporarly mute the system sound\speakers as I did in this thread

I have incorporated some part of that CoreAudio code into this Lock\UnLock project so you should now not hear the annoying beep sound.

I have also improved the original lock\unlock code so it can now :
1- Optionally Notify the user (added third optional argument).
2- Lock\Unloc operations can be performed from the excel UI.
3- Changing the vbproject password is saved and preserved.

@lordy888
Try the new code in this post ... Also, remember that the vbproject will need to have at least one module. So add one module to the newly created workbook before saving and closing.


File Demo [Improved Version]
Lock_Unlock_VBAProject_API _IMPROVED_VERSION.xlsm


Here is the code :

1- In a Standard Module:

Option Explicit

Private Type GUID
    Data1 As Long
    Data2 As Integer
    Data3 As Integer
    Data4(0& To 7&) As Byte
End Type

#If VBA7 Then
    Private Declare PtrSafe Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As LongPtr, ByVal hMod As LongPtr, ByVal dwThreadId As Long) As LongPtr
    Private Declare PtrSafe Function UnhookWindowsHookEx Lib "user32" (ByVal hhk As LongPtr) As Long
    Private Declare PtrSafe Function CallNextHookEx Lib "user32" (ByVal hHook As LongPtr, ByVal ncode As Long, ByVal wParam As LongPtr, lParam As Any) As LongPtr
    Private Declare PtrSafe Function GetCurrentThreadId Lib "kernel32" () As Long
    Private Declare PtrSafe Function GetDlgItem Lib "user32" (ByVal hDlg As LongPtr, ByVal nIDDlgItem As Long) As LongPtr
    Private Declare PtrSafe Function GetActiveWindow Lib "user32" () As LongPtr
    Private Declare PtrSafe Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As LongPtr, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
    Private Declare PtrSafe Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As LongPtr, ByVal lpString As String, ByVal cch As Long) As Long
    Private Declare PtrSafe Function GetNextWindow Lib "user32" Alias "GetWindow" (ByVal hwnd As LongPtr, ByVal wFlag As Long) As LongPtr
    Private Declare PtrSafe Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As LongPtr, ByVal hwnd2 As LongPtr, ByVal lpsz1 As String, ByVal lpsz2 As String) As LongPtr
    Private Declare PtrSafe Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, lParam As Any) As Long
    Private Declare PtrSafe Function SendMessageByString Lib "user32.dll" Alias "SendMessageA" (ByVal hwnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, ByVal lParam As String) As Long
    Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As LongPtr) As LongPtr
    Private Declare PtrSafe Function SetTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As LongPtr, ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As LongPtr
    Private Declare PtrSafe Function KillTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As LongPtr) As Long
    Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As LongPtr, ByVal hWndInsertAfter As LongPtr, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
    Private Declare PtrSafe Function SetActiveWindow Lib "user32" (ByVal hwnd As LongPtr) As LongPtr
    Private Declare PtrSafe Sub SetLastError Lib "Kernel32.dll" (ByVal dwErrCode As Long)
    Private Declare PtrSafe Function DispCallFunc Lib "OleAut32.dll" (ByVal pvInstance As LongPtr, ByVal offsetinVft As LongPtr, ByVal CallConv As Long, ByVal retTYP As Integer, ByVal paCNT As Long, ByRef paTypes As Integer, ByRef paValues As LongPtr, ByRef retVAR As Variant) As Long
    Private Declare PtrSafe Function IIDFromString Lib "ole32.dll" (ByVal lpsz As LongPtr, ByRef lpiid As Any) As Long
    Private Declare PtrSafe Function CoCreateInstance Lib "ole32" (ByRef rclsid As GUID, ByVal pUnkOuter As LongPtr, ByVal dwClsContext As Long, ByRef riid As GUID, ByRef ppv As LongPtr) As Long
    Private Declare PtrSafe Function CLSIDFromString Lib "ole32" (ByVal OleStringCLSID As LongPtr, ByRef cGUID As Any) As Long
#Else
    Private Enum LongPtr
        [_]
    End Enum
    Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" (ByVal idHook As Long, ByVal lpfn As LongPtr, ByVal hMod As LongPtr, ByVal dwThreadId As Long) As LongPtr
    Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hhk As LongPtr) As Long
    Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As LongPtr, ByVal ncode As Long, ByVal wParam As LongPtr, lParam As Any) As LongPtr
    Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long
    Private Declare Function GetDlgItem Lib "user32" (ByVal hDlg As LongPtr, ByVal nIDDlgItem As Long) As LongPtr
    Private Declare Function GetActiveWindow Lib "user32" () As LongPtr
    Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As LongPtr, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
    Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As LongPtr, ByVal lpString As String, ByVal cch As Long) As Long
    Private Declare Function GetNextWindow Lib "user32" Alias "GetWindow" (ByVal hwnd As LongPtr, ByVal wFlag As Long) As LongPtr
    Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As LongPtr, ByVal hwnd2 As LongPtr, ByVal lpsz1 As String, ByVal lpsz2 As String) As LongPtr
    Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As LongPtr, ByVal wMsg As Long, ByVal wParam As LongPtr, lParam As Any) As Long
    Private Declare Function SetFocus Lib "user32" (ByVal hwnd As LongPtr) As LongPtr
    Private Declare Function SetTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As LongPtr, ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As LongPtr
    Private Declare Function KillTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As LongPtr) As Long
    Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As LongPtr, ByVal hWndInsertAfter As LongPtr, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
    Private Declare Function SetActiveWindow Lib "user32" (ByVal hwnd As LongPtr) As LongPtr
    Private Declare Sub SetLastError Lib "Kernel32.dll" (ByVal dwErrCode As Long)
    Private Declare Function DispCallFunc Lib "OleAut32.dll" (ByVal pvInstance As LongPtr, ByVal offsetinVft As LongPtr, ByVal CallConv As Long, ByVal retTYP As Integer, ByVal paCNT As Long, ByRef paTypes As Integer, ByRef paValues As LongPtr, ByRef retVAR As Variant) As Long
    Private Declare Function IIDFromString Lib "ole32.dll" (ByVal lpsz As LongPtr, ByRef lpiid As Any) As Long
    Private Declare Function CoCreateInstance Lib "ole32" (ByRef rclsid As GUID, ByVal pUnkOuter As LongPtr, ByVal dwClsContext As Long, ByRef riid As GUID, ByRef ppv As LongPtr) As Long
    Private Declare Function CLSIDFromString Lib "ole32" (ByVal OleStringCLSID As LongPtr, ByRef cGUID As Any) As Long
#End If

Private lHook As LongPtr, oProject As Object, sWinClassName As String, _
        sWorkbookName As String, sPassword As String, bNotify As Boolean, bHooked As Boolean


Public Property Let LockVBProject( _
    ByVal WorkbookName As String, _
    ByVal Password As String, _
    Optional ByVal NotifyUser As Boolean, _
    ByVal bLock As Boolean _
)
    Const WH_CBT = 5&
    Dim hwnd As LongPtr
 
    If bHooked Then Exit Property
 
    hwnd = GetActiveWindow: bNotify = NotifyUser:  bHooked = True
 
    On Error GoTo ErrHandler
    With Application.VBE
        Set .ActiveVBProject = Application.Workbooks(WorkbookName).VBProject
        Set oProject = .ActiveVBProject
        If bLock Then
            If .ActiveVBProject.Protection = 0 Then
                sWinClassName = "VBAProject - Project Properties"
                sWorkbookName = WorkbookName
            Else
                MsgBox "VBProect already locked.": Exit Property
            End If
        Else
            If .ActiveVBProject.Protection Then
                sWinClassName = "VBAProject Password"
            Else
                MsgBox "VBProect already unlocked.": Exit Property
            End If
        End If
    End With
    sPassword = Password
    lHook = SetWindowsHookEx(WH_CBT, AddressOf Catch_DlgBox_Activation, 0, GetCurrentThreadId)
    Application.VBE.CommandBars(1&).FindControl(ID:=2578, recursive:=True).Execute
    bHooked = False
Exit Property

ErrHandler:
    Call UnHook
    bHooked = False
    MuteSpeakers False
    If Err.Number = 9 Then
        MsgBox "Error : " & Err.Number & vbNewLine & vbNewLine & "Invalid Project Name.", vbExclamation
    Else
        MsgBox "Runtime Error : " & Err.Number & vbCr & vbCr & Err.Description, vbExclamation
    End If
End Property

Private Function Catch_DlgBox_Activation( _
    ByVal idHook As Long, _
    ByVal wParam As LongPtr, _
    ByVal lParam As LongPtr _
) As LongPtr
  
    Const HCBT_ACTIVATE = 5, SWP_HIDEWINDOW = &H80
    Dim sBuff As String * 256, lRet As Long
    Dim hwnd As LongPtr

    If idHook = HCBT_ACTIVATE Then
        lRet = GetClassName(wParam, sBuff, 256&)
        If Left(sBuff, lRet) = "#32770" Then
            sBuff = ""
            lRet = GetWindowText(wParam, sBuff, 256&)
            If Left(sBuff, lRet) = sWinClassName Then
                Call UnHook
                SetWindowPos wParam, 0, 0&, 0&, 0&, 0&, SWP_HIDEWINDOW
                Call SetTimer(Application.hwnd, wParam, 0, AddressOf Protect_UnProtect_Routine)
            End If
        End If
    End If
    Catch_DlgBox_Activation = CallNextHookEx(lHook, idHook, ByVal wParam, ByVal lParam)
 
End Function

Private Sub UnHook()
    Call UnhookWindowsHookEx(lHook)
End Sub

Private Sub UnHook2()
    Call UnHook
    MuteSpeakers False
    If bNotify Then
        If IsProjectUnLocked Then
            MsgBox "Project successfully unlocked!", vbInformation
        Else
            MsgBox "Failed to unlock the VBProject!" & vbNewLine & vbNewLine & _
                   "Passwords are Case-Sensitive ... Make sure the provided Password is correct.", vbExclamation
        End If
    End If
End Sub

Private Function IsProjectUnLocked() As Boolean
    IsProjectUnLocked = CBool(oProject.Protection = 0)
End Function

Private Sub Protect_UnProtect_Routine( _
    ByVal hwnd As LongPtr, _
    ByVal uMsg As Long, _
    ByVal nIDEvent As LongPtr, _
    ByVal dwTimer As Long _
)
    Const TCM_FIRST = &H1300
    Const TCM_SETCURSEL = (TCM_FIRST + 12&)
    Const TCM_SETCURFOCUS = (TCM_FIRST + 48&)
    Const EM_SETMODIFY = &HB9
    Const BM_SETCHECK = &HF1
    Const BST_CHECKED = &H1
    Const BM_GETCHECK = &HF0
    Const BM_CLICK = &HF5
    Const WM_SETTEXT = &HC
    Const WH_CBT = 5&
    Const GW_CHILD = 5&
    Dim hCurrentDlg As LongPtr, hwndSysTab As LongPtr
    Dim sBuff As String * 256, lRet As Long
 
    On Error GoTo ErrHandler
    Call KillTimer(Application.hwnd, nIDEvent)
    hCurrentDlg = nIDEvent
    If sWinClassName = "VBAProject - Project Properties" Then
        hwndSysTab = FindWindowEx(hCurrentDlg, 0, "SysTabControl32", vbNullString)
        Call SendMessage(hwndSysTab, TCM_SETCURFOCUS, 1, ByVal 0&)
        Call SendMessage(hwndSysTab, TCM_SETCURSEL, 1, ByVal 0&)
        Call SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1557), BM_SETCHECK, BST_CHECKED, ByVal 0&)
        Call SendMessageByString(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1555), WM_SETTEXT, 0, sPassword)
        Call SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1555), EM_SETMODIFY, True, ByVal 0&)
        Call SendMessageByString(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1556), WM_SETTEXT, 0, sPassword)
        Call SendMessage(GetDlgItem(GetNextWindow(hCurrentDlg, GW_CHILD), &H1556), EM_SETMODIFY, True, ByVal 0&)
        Call SendMessage(GetDlgItem(hCurrentDlg, &H1), BM_CLICK, 0, ByVal 0&)
        Call Application.OnTime(Now, "SaveVBProjectChanges")
    ElseIf sWinClassName = "VBAProject Password" Then
        MuteSpeakers True 'temporarly mute the system sounds\speakers to avoid awful sound when running Catch_DlgBox_Creation
        If SendMessageByString(GetDlgItem(hCurrentDlg, &H155E), WM_SETTEXT, 0, sPassword) Then
            Call SendMessage(GetDlgItem(hCurrentDlg, &H155E), EM_SETMODIFY, True, ByVal 0&)
            lHook = SetWindowsHookEx(WH_CBT, AddressOf Catch_DlgBox_Creation, 0, GetCurrentThreadId)
            lRet = GetWindowText(GetActiveWindow, sBuff, 256&)
            If Left(sBuff, lRet) = "VBAProject Password" Then
                Call SendMessage(GetDlgItem(hCurrentDlg, &H1), BM_CLICK, 0, ByVal 0&)
                Call SendMessage(GetDlgItem(GetActiveWindow, &H2), BM_CLICK, 0, ByVal 0&)
            Else
                Call SendMessage(GetDlgItem(hCurrentDlg, &H1), BM_CLICK, 0, ByVal 0&)
            End If
            Call Application.OnTime(Now + TimeSerial(0, 0, 3), "UnHook2")  'wait 3 secs before unmuting the speakers.
        End If
    End If
    Exit Sub
ErrHandler:
    Call UnHook2
    MsgBox "Runtime Error : " & Err.Number & vbCr & vbCr & Err.Description, vbExclamation
End Sub

Private Function Catch_DlgBox_Creation( _
    ByVal idHook As Long, _
    ByVal wParam As LongPtr, _
    ByVal lParam As LongPtr _
) As LongPtr

    Const HCBT_CREATEWND = 3&
    Dim sBuff As String * 256, lRet As Long
 
    If idHook = HCBT_CREATEWND Then
        lRet = GetClassName(wParam, sBuff, 256)
        If Left(sBuff, lRet) = "#32770" Then
            Catch_DlgBox_Creation = -1
            Exit Function
        End If
    End If
    Catch_DlgBox_Creation = CallNextHookEx(lHook, idHook, ByVal wParam, ByVal lParam)
End Function

Private Sub SaveVBProjectChanges()
    On Error Resume Next
    Application.EnableEvents = False
        Workbooks(sWorkbookName).Save
    Application.EnableEvents = True
End Sub

Private Sub MuteSpeakers(Optional ByVal bMute As Boolean = True)

    Const CLSID_MMDeviceEnumerator = "{BCDE0395-E52F-467C-8E3D-C4579291692E}"
    Const IID_IMMDeviceEnumerator = "{A95664D2-9614-4F35-A746-DE8DB63617E6}"
    Const IID_IAudioEndpointVolume = "{5CDF2C82-841E-4546-9722-0CF74078229A}"
    Const IID_NULL = "{00000000-0000-0000-0000-000000000000}"
    Const CLSCTX_INPROC_SERVER = 1&
    Const CC_STDCALL = 4&
 
    #If Win64 Then
        Const NULL_PTR = 0^
        Const PTR_SIZE = 8&
    #Else
        Const NULL_PTR = 0&
        Const PTR_SIZE = 4&
    #End If
 
    Dim tClsID As GUID, tIID As GUID
    Dim pDeviceEnumerator As LongPtr, pdefaultDevice As LongPtr, pIAudioEndpointVolume As LongPtr
    Dim eRender As Long, eMultimedia As Long
    Dim lRet As Long

    lRet = CLSIDFromString(StrPtr(CLSID_MMDeviceEnumerator), tClsID)
    lRet = IIDFromString(StrPtr(IID_IMMDeviceEnumerator), tIID)

    'Create an enumerator for the audio endpoint devices
    lRet = CoCreateInstance(tClsID, NULL_PTR, CLSCTX_INPROC_SERVER, tIID, pDeviceEnumerator)
    If lRet Then MsgBox "Failed to get IMMDeviceEnumerator.": Exit Sub
 
    eRender = 0&: eMultimedia = 1&
    'IMMDeviceEnumerator::GetDefaultAudioEndpoint Method.
    lRet = vtblCall(pDeviceEnumerator, 4& * PTR_SIZE, vbLong, CC_STDCALL, eRender, eMultimedia, VarPtr(pdefaultDevice))
    If lRet Then MsgBox "Failed to get IMMDevice.": Exit Sub
 
    lRet = IIDFromString(StrPtr(IID_IAudioEndpointVolume), tIID)
    'IMMDevice::Activate Method.
    lRet = vtblCall(pdefaultDevice, 3& * PTR_SIZE, vbLong, CC_STDCALL, VarPtr(tIID), CLSCTX_INPROC_SERVER, 0&, VarPtr(pIAudioEndpointVolume))
    If lRet Then MsgBox "Failed to get IAudioEndpointVolume.": Exit Sub

    lRet = IIDFromString(StrPtr(IID_NULL), tIID)
    lRet = vtblCall(pIAudioEndpointVolume, 14& * PTR_SIZE, vbLong, CC_STDCALL, CLng(Abs(bMute)), VarPtr(tIID))
 
    'Release Interfaces.
    lRet = vtblCall(pIAudioEndpointVolume, 2& * PTR_SIZE, vbLong, CC_STDCALL)
    lRet = vtblCall(pdefaultDevice, 2& * PTR_SIZE, vbLong, CC_STDCALL)
    lRet = vtblCall(pDeviceEnumerator, 2& * PTR_SIZE, vbLong, CC_STDCALL)

End Sub


Private Function vtblCall( _
    ByVal InterfacePointer As LongPtr, _
    ByVal VTableOffset As Long, _
    ByVal FunctionReturnType As Long, _
    ByVal CallConvention As Long, _
    ParamArray FunctionParameters() As Variant _
) As Variant

    Dim vParamPtr() As LongPtr

    If InterfacePointer = 0& Or VTableOffset < 0& Then Exit Function
    If Not (FunctionReturnType And &HFFFF0000) = 0& Then Exit Function

    Dim pIndex As Long, pCount As Long
    Dim vParamType() As Integer
    Dim vRtn As Variant, vParams() As Variant

    vParams() = FunctionParameters()
    pCount = Abs(UBound(vParams) - LBound(vParams) + 1&)
    If pCount = 0& Then
        ReDim vParamPtr(0& To 0&)
        ReDim vParamType(0& To 0&)
    Else
        ReDim vParamPtr(0& To pCount - 1&)
        ReDim vParamType(0& To pCount - 1&)
        For pIndex = 0& To pCount - 1&
            vParamPtr(pIndex) = VarPtr(vParams(pIndex))
            vParamType(pIndex) = VarType(vParams(pIndex))
        Next
    End If

    pIndex = DispCallFunc(InterfacePointer, VTableOffset, CallConvention, FunctionReturnType, pCount, _
    vParamType(0&), vParamPtr(0&), vRtn)
    If pIndex = 0& Then
        vtblCall = vRtn
    Else
        SetLastError pIndex
    End If
End Function

2- Usage Example:

Option Explicit

Sub Lock_Example()

    ' To lock the vbproject. [change workbook name as required]
        LockVBProject(WorkbookName:="MyTestBook.xlsm", Password:="1234") = True

End Sub

Sub UnLock_Example()

    ' To un-lock the vbproject. [change workbook name as required]
    ' Operation may take about 3 seconds.
        LockVBProject(WorkbookName:="MyTestBook.xlsm", Password:="1234", NotifyUser:=True) = False
End Sub

Note: Due to the fact that the code waits for the beep sound(s) to finish , the unlocking may take about 3 seconds.
This is done in the following line:
Call Application.OnTime(Now + TimeSerial(0, 0, 3), "UnHook2") 'wait 3 secs before unmuting the speakers
You may need to play a bit with the timing and adjust it to your specific needs.

Also, just like before, this code is language-dependant as it reads the VBE dialog captions but it can be easily adapted from English to other languages.

 

[lordy888]

Hi. @Jaafar Tribak. I try your new code. Also, I also have add one module to the newly workbook. The issues remained. That is:
1. Without the line closing the workbook, the password will be saved in newly added workbook. No password will be saved in the existing workbook.
2. However, with the line closing the workbook, the password will not be saved in newly added workbook. The password will be saved in the existing workbook instead.

With quoting your post, I also asked if anyone know why the issues here if it concerns you. How to password protect vbaproject newly added workbook and close the workbook

Thank you to your code again. It works well if not closing the workbook.

 

[Jaafar Tribak]

Hi. @Jaafar Tribak. I try your new code. Also, I also have add one module to the newly workbook. The issues remained. That is:
1. Without the line closing the workbook, the password will be saved in newly added workbook. No password will be saved in the existing workbook.
2. However, with the line closing the workbook, the password will not be saved in newly added workbook. The password will be saved in the existing workbook instead.

With quoting your post, I also asked if anyone know why the issues here if it concerns you. How to password protect vbaproject newly added workbook and close the workbook

Thank you to your code again. It works well if not closing the workbook.

I guess it is a timing issue. Adding a DoEvents statement should work but it is unreliable. Brievely delaying the saving and closing operation should be a better & more reliable workaround.

Try this variation:

Sub exportWB()
    Const sFFPath As String = "D:\A.xlsm"
    Dim xWB As Workbook
    Set xWB = Workbooks.Add
    LockVBProject(WorkbookName:=xWB.Name, Password:="password") = True
    xWB.VBProject.VBComponents.Add (1) 'vbext_ct_StdModule
    xWB.SaveAs Filename:=sFFPath, _
    FileFormat:=xlOpenXMLWorkbookMacroEnabled, _
    ConflictResolution:=Excel.XlSaveConflictResolution.xlLocalSessionChanges
    Application.OnTime Now, "'SaveNow """ & xWB.Name & "'"
    Set xWB = Nothing
End Sub

Sub SaveNow(ByVal sWbkName As String)
    Workbooks(sWbkName).Close savechanges:=True
End Sub

Notice how I added in your exportWB routine a line that programmatically adds an empty standard module to the project of the newly created workbook. This step is necessary for the password protection to take effect and be preserved after closing and reopening.

Also, I see that in your StackOverflow post you used my first LockVBProject code. Please, DO NOT USE IT ... Use my latest improved version in post#25 instead.

 

[lordy888]

Thank you. @Jaafar Tribak Application.OnTime method do the trick and your code works all fine.
I did try using Application.Wait DateAdd("s", 1, Now) before, but this line would not do the trick.
Please note that I amended the question and quoted your post 25 too.

 

[lordy888]

Adding a few points.
1. I also posted your workaround to my question asked.
2. I tried modified your code as below and would not work as good as your code. Just for sharing. Your code works only as same as how you structured it. It is amazing.

Sub exportWB()
Const sFFPath As String = "D:\A.xlsm"
Dim xWB As Workbook
Set xWB = Workbooks.Add
LockVBProject(WorkbookName:=xWB.name, Password:="password") = True
xWB.VBProject.VBComponents.Add (1) 'vbext_ct_StdModule
xWB.SaveAs Filename:=sFFPath, _
FileFormat:=xlOpenXMLWorkbookMacroEnabled, _
ConflictResolution:=Excel.XlSaveConflictResolution.xlLocalSessionChanges
doEvent3
xWB.Close savechanges:=True
Set xWB = Nothing
End Sub
Sub doEvent3()
Application.OnTime Now, "'WaitASec'"
End Sub
Sub WaitASec()
Debug.Print "Waited A Sec"
End Sub

 

[Jaafar Tribak]

Adding a few points.
1. I also posted your workaround to my question asked.
2. I tried modified your code as below and would not work as good as your code. Just for sharing. Your code works only as same as how you structured it. It is amazing.

Glad you got this working