Lambda and custom sequence with interference of string

[Phantom1]

I need to create a custom sequence of numbers but interfere with custom strings with rules.
To be specific let's say i want a sequence of numbers starting from 5 and go up until the biggest number that is smaller than 60 with step of 4.
The task is that we want to enter one @ symbol after the first two numbers, then two @ symbols after the next three numbers and continue with the same pattern.
I have created the following lambda and added as CustSeq in Name Manager which works for the given example.

=LAMBDA(startnum,maxend,step,breaks,rep,str,
LET(a,SEQUENCE(1,CEILING((maxend-startnum)/step,1),startnum,step),
b,SEQUENCE(1,COLUMNS(a)),
c,MAP(b,LAMBDA(i,IF(MOD(i,BYROW(breaks,SUM))=INDEX(breaks,1),REPT(str,INDEX(rep,1)),IF(MOD(i,BYROW(breaks,SUM))=0,REPT(str,INDEX(rep,2)),"")))),
d,VSTACK(a,c),
out,FILTER(TOROW(d,1,TRUE),TOROW(d,1,TRUE)<>"",),out))

Example of input and output.

The problem with this is that it is fixed to specific row arrays of exact two elements.

What if i wanted
=CustSeq(5,60,3,{1,2,4},{1,2,1},"@") ?

Something i just notice is that we do not want the character or string when repeating to be joined as in cell M3 of the example. We want it to take its own cell.

And what about blanks?
If we want the result to be...

I am sure there is a better ,more dynamic and efficient way.
Did anyone make something like this?
Do not seek for VBA. Just a custom Lambda function to be added in Name Manager.

Thanks in advance.

 

[StephenCrump]

Here's one way you could do it, with a recursive Lambda.

	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF	AG	AH	AI	AJ	AK
1		5
2		60
3		4
4		2	3
5		1	2
6		@	@			5	9	@	13	17	21	@	@	25	29	@	33	37	41	@	@	45	49	@	53	57
7
8		4
9		60
10		3
11		2	3	4
12		3	2	1
13		@		/		4	7	@	@	@	10	13	16			19	22	25	28	/	31	34	@	@	@	37	40	43			46	49	52	55	/	58
Sheet1

Cell Formulas
Range	Formula
B4:C4	B4	={2,3}
B5:C5	B5	={1,2}
B6:C6	B6	={"@","@"}
F6:Z6,F13:AJ13	F6	=CustSeq(B1,B2,B3,B4#,B5#,B6#,1)
B11:D11	B11	={2,3,4}
B12:D12	B12	={3,2,1}
B13:D13	B13	={"@","","/"}
Dynamic array formulas.

Lambda Functions
Name	Formula
CustSeq	=LAMBDA(startnum,maxend,step,breaks,rep,str,col,LET(c,1+MOD(col-1,COLUMNS(breaks)),seq,SEQUENCE(,INDEX(breaks,c),startnum,step),IF(MAX(seq)<maxend-step,HSTACK(seq,IF(SEQUENCE(,INDEX(rep,c)),INDEX(str,c)),CustSeq(startnum+step*INDEX(breaks,c),maxend,step,breaks,rep,str,col+1)),FILTER(seq,seq<=maxend))))

 

[Phantom1]

Excellent solution. Exactly what i was looking for.
Thanks a lot.
Cheers!

 

[StephenCrump]

No problem. I'm glad we could help.