How to remove Parenthesis with numbers and text without removing the remaining text after

[Dith2228]

I have been trying to find answer on how to remove a parenthesis with number and text inside withou the remaining words after being removed. In example

I have reviewed T09_535 (243 pages), N4057.005 (3 documents).

Result must be

I have reviewed T09_535, N4057.005.

I have tried the Find and Replace using find (*pages) and replces with space but it did not worked. Please help

 

[Peter_SSs]

How do i change the condition say if my cell contains (9:30am to 2:30pm) within the parenthesis but the time varies and i also need to remove that parenthesis with time inside?

Once again one example is not much to go on but this small change in the 'Pattern' line should work on that one example at least

Sub RemoveSomeParentheses()
  Dim RX As Object
  Dim a As Variant
  Dim i As Long
 
  Set RX = CreateObject("VBScript.RegExp")
  RX.Global = True
  RX.Pattern = " *\(\d+ *(page|document|:)[^\)]*\)"
  With Range("a2", Range("A" & Rows.Count).End(xlUp))
    a = .Value
    For i = 1 To UBound(a)
      a(i, 1) = Application.Trim(RX.Replace(a(i, 1), ""))
    Next i
    .Offset(, 1).Value = a
  End With
End Sub

 

[Dith2228]

Once again one example is not much to go on but this small change in the 'Pattern' line should work on that one example at least

Sub RemoveSomeParentheses()
  Dim RX As Object
  Dim a As Variant
  Dim i As Long
 
  Set RX = CreateObject("VBScript.RegExp")
  RX.Global = True
  RX.Pattern = " *\(\d+ *(page|document|:)[^\)]*\)"
  With Range("a2", Range("A" & Rows.Count).End(xlUp))
    a = .Value
    For i = 1 To UBound(a)
      a(i, 1) = Application.Trim(RX.Replace(a(i, 1), ""))
    Next i
    .Offset(, 1).Value = a
  End With
End Sub

Many many thanks to you for your help. This worked perfectly. Appreciate your kindness.

 

[Peter_SSs]

You are welcome. Thanks for the follow-up.

(For future questions though, please provide enough sample data that we can see what sort of variety there might be. )