WR

[Xlambda]

WR: Word maze Results challenge. Please do see latest (26-Oct-21) YT video of MrExcel Solving Word Search With Excel (FMWC) - 2439
This is a compact set of functions that can solve all lookup scenarios.
Defined names: ar, sample array ( A1:T15 ) ; rw, nr. rows of sample array (15) (width is fixed to 20) ; cs, constant array values for "snake" lookup {-1,1, 20,-20} ; cd, constant array values for "diagonal" lookup {-21,-19,19,21}

WL(l)=LAMBDA(l,LET(x,IF(ar=l,1),y,IF(ar="?",1),z,IF(x+y,1),v,IF(z,SEQUENCE(rw,20)),SMALL(v,SEQUENCE(COUNT(v)))))
WA(a,c)=LAMBDA(a,c,LET(x,a-c,y,IF(x>0,x),UNIQUE(SMALL(y,SEQUENCE(COUNT(y ))))))
WB(a,b)=LAMBDA(a,b,FILTER(a,IFNA(XMATCH(a,b,,2),0)))
WR(w,c,[r],[i ])=LAMBDA(w,c,[r],[i ],LET(n,IF(i,i,LEN(w)),x,MID(w,n,1),y,MID(w,n-1,1),z,IF(AND(r=0),WA(WL(x),c),WA(r,c)),IF(n=1,r,WR(w,c,WB(z,WL(y )),n-1))))
Last one WR is !! recursive !! Define the names, then the functions and we are good to go. (Gaps in [i ] are to keep the text no to turn italics)
Will come back with the "concept" explanation asap.

=LAMBDA(w,c,[r],[i ],LET(n,IF(i,i,LEN(w)),x,MID(w,n,1),y,MID(w,n-1,1),z,
     IF(AND(r=0),WA(WL(x),c),WA(r,c)),IF(n=1,r,WR(w,c,WB(z,WL(y)),n-1))
    )
)

WORD MAZE.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF	AG	AH	AI	AJ	AK
1	Z	1	S	G	P	E	2	T	H	E	D	I	Z	B	A	N	T	S	N	S			defined names
2	S	P	?	A	K	I	W	K	1	F	H	V	Z	G	2	I	E	K	A	X			ar: A1:T15 (sample array)
3	?	I	T	Q	E	?	L	A	S	I	X	Q	J	N	S	X	4	T	J	K			rw: 15 (width is always 20)
4	L	E	N	J	F	X	A	4	T	I	K	N	S	B	X	1	D	J	C	P			cs: {-1,1,20,-20} (constant array for "snake" type lookup
5	G	D	L	3	3	D	M	V	L	T	G	K	?	C	U	3	O	Q	O	O			cd: {-21,-19,19,21} (constant array for "diagonal" type lookup
6	I	A	I	U	V	G	Y	L	U	?	I	E	P	3	W	G	K	B	T	P
7	4	A	P	A	U	4	C	Z	V	F	F	F	A	F	I	P	A	X	T	T			"snake" lookup						"diagonal" lookup
8	H	N	?	4	G	C	K	S	4	I	D	R	H	N	N	A	J	D	N	S
9	E	C	3	X	C	O	D	B	V	Q	O	Y	J	E	R	G	S	K	A	H			=WR("snake",cs)						=WR("diagonal",cd)
10	E	X	1	Z	?	P	N	I	3	O	W	C	C	N	2	U	R	E	G	J			3						82
11	E	O	N	M	E	V	K	A	B	E	P	F	L	Q	N	Z	?	E	W	3			18
12	K	A	N	?	A	I	B	K	L	G	2	4	?	N	?	Z	B	N	Q	E			20						=WR("advance",cd)
13	S	M	O	4	Y	F	B	B	R	E	?	D	N	E	1	A	D	J	M	4			160						67
14	C	F	X	4	3	T	Y	1	Z	J	N	I	W	U	Z	3	O	W	H	M			224
15	T	Y	D	2	Y	Z	S	U	D	V	V	F	4	O	Z	E	K	A	?	S			300
16
17	=SEQUENCE(rw,20)																						=WR("difficult",cs)
18	1	2	3	4	5	6	7	8	9	10	11	12	13	14	15	16	17	18	19	20			151
19	21	22	23	24	25	26	27	28	29	30	31	32	33	34	35	36	37	38	39	40
20	41	42	43	44	45	46	47	48	49	50	51	52	53	54	55	56	57	58	59	60			=WR("winner",cs)
21	61	62	63	64	65	66	67	68	69	70	71	72	73	74	75	76	77	78	79	80			115
22	81	82	83	84	85	86	87	88	89	90	91	92	93	94	95	96	97	98	99	100			273
23	101	102	103	104	105	106	107	108	109	110	111	112	113	114	115	116	117	118	119	120
24	121	122	123	124	125	126	127	128	129	130	131	132	133	134	135	136	137	138	139	140
25	141	142	143	144	145	146	147	148	149	150	151	152	153	154	155	156	157	158	159	160		Note: I left the results in "sequence numbers" representation on purpose,
26	161	162	163	164	165	166	167	168	169	170	171	172	173	174	175	176	177	178	179	180		to be much easier to visualize the results.
27	181	182	183	184	185	186	187	188	189	190	191	192	193	194	195	196	197	198	199	200		To get them to "range" representation we can use PR(a) (print results)
28	201	202	203	204	205	206	207	208	209	210	211	212	213	214	215	216	217	218	219	220		PR(a)=LAMBDA(a,LET(x,QUOTIENT(a-1,20)+1,y,MOD(a-1,20)+1,ADDRESS(x,y,4)))
29	221	222	223	224	225	226	227	228	229	230	231	232	233	234	235	236	237	238	239	240
30	241	242	243	244	245	246	247	248	249	250	251	252	253	254	255	256	257	258	259	260
31	261	262	263	264	265	266	267	268	269	270	271	272	273	274	275	276	277	278	279	280			C1						B5
32	281	282	283	284	285	286	287	288	289	290	291	292	293	294	295	296	297	298	299	300			R1
33																							T1						G4
34	Important Note: Covered here only snake and diagonal search, for being the more complicated ones.																						T8
35	Anyhow, to cover the rest of them the only thing we have to do is defining new constant arrays																						D12
36	cs (constant snake) {-1,1,20,-20}																						T15
37	cd (constant diagonal) {-21,-19,19,21}
38	For example, for horizontal lookup we have to define																						K8
39	ch {-1,1} and for vertical cv: {-20,20}
40																							O6
41																							M14
42
43
WM snake diagonal

Cell Formulas
Range	Formula
W9,W20,W17,A17,AC12,AC9	W9	=FORMULATEXT(W10)
W10:W15	W10	=WR("snake",cs)
AC10	AC10	=WR("diagonal",cd)
AC13	AC13	=WR("advance",cd)
A18:T32	A18	=SEQUENCE(rw,20)
W18	W18	=WR("difficult",cs)
W21:W22	W21	=WR("winner",cs)
W31:W36	W31	=PR(W10#)
AC31	AC31	=PR(AC10)
AC33,W38	AC33	=PR(AC13)
W40:W41	W40	=PR(W21#)
Dynamic array formulas.

Named Ranges
Name	Refers To	Cells
ar	='WM snake diagonal'!$A$1:$T$15	AC13, AC10, W21, W18, W10

 

[Xlambda]

One of the approaches for solving the diagonal lookup was to "level" the diagonals in rows format.
In case that extracting diagonals could be useful for other tasks also, I thought it deserves a look.

Book1.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA
1	Extracting diagonals horizontally.
2	There are 2 "inclinations" of diagonals, let's call them left and right.
3	Left one has first element top left corner of an array
4	Right one has first element, top right corner of an array
5
6	1	2	3		3	2	1
7	2	3	4		4	3	2
8	3	4	5		5	4	3
9	4	5	6		6	5	4
10	left				right
11	for an array r x c nr. of diagonals d, left or right will be d=r+c-1, so for 4x3 d=4+3-1=6 diagonals
12	Concept left diagonal
13									To get diagonals by row let's lower each column
14	row indexes for an array 5x4								with this column pattern:										pattern row indexes for diagonal array 8x4
15	=QUOTIENT(SEQUENCE(5,4)-1,4)+1								0	1	2	3							=SEQUENCE(8)-(SEQUENCE(,4)-1)
16	1	1	1	1					1					pattern formula:					1	0	-1	-2
17	2	2	2	2					2	1				=SEQUENCE(,4)-1					2	1	0	-1
18	3	3	3	3					3	2	1			0	1	2	3		3	2	1	0
19	4	4	4	4					4	3	2	1							4	3	2	1
20	5	5	5	5					5	4	3	2							5	4	3	2
21										5	4	3							6	5	4	3
22	d=5+4-1=8										5	4							7	6	5	4
23												5							8	7	6	5
24
25	we have to exclude values<=0
26	and vales >5 initial nr. of rows								sample array 5x4						Note: clms index unchanged
27	=(S16#>0)*(S16#<=5)*S16#								=SEQUENCE(5,4)						=IF(A28#,INDEX($I$28#,A28#,SEQUENCE(,4)),"")
28	1	0	0	0					1	2	3	4			1
29	2	1	0	0					5	6	7	8			5	2
30	3	2	1	0					9	10	11	12			9	6	3
31	4	3	2	1					13	14	15	16			13	10	7	4
32	5	4	3	2					17	18	19	20			17	14	11	8
33	0	5	4	3												18	15	12
34	0	0	5	4													19	16
35	0	0	0	5														20
36
37	Concept right diagonal.
38	the only thing we have to change is the column pattern from 0,1,2,3 to 3,2,1,0																		pattern row indexes
39								=SORT(I15:L15,,-1,1)											=SEQUENCE(8)-H40#
40								3	2	1	0								-2	-1	0	1
41																			-1	0	1	2
42	=(S40#>0)*(S40#<=5)*S40#							=IF(A43#,INDEX($I$28#,A43#,SEQUENCE(,4)),"")											0	1	2	3
43	0	0	0	1							4								1	2	3	4
44	0	0	1	2						3	8								2	3	4	5
45	0	1	2	3					2	7	12								3	4	5	6
46	1	2	3	4				1	6	11	16								4	5	6	7
47	2	3	4	5				5	10	15	20								5	6	7	8
48	3	4	5	0				9	14	19
49	4	5	0	0				13	18
50	5	0	0	0				17
51
Sheet2

Cell Formulas
Range	Formula
A15,H42,A42,S39,H39,O27,I27,A27,N17,S15	A15	=FORMULATEXT(A16)
A16:D20	A16	=QUOTIENT(SEQUENCE(5,4)-1,4)+1
S16:V23	S16	=SEQUENCE(8)-(SEQUENCE(,4)-1)
N18:Q18	N18	=SEQUENCE(,4)-1
A28:D35	A28	=(S16#>0)*(S16#<=5)*S16#
I28:L32	I28	=SEQUENCE(5,4)
O28:R35	O28	=IF(A28#,INDEX($I$28#,A28#,SEQUENCE(,4)),"")
H40:K40	H40	=SORT(I15:L15,,-1,1)
S40:V47	S40	=SEQUENCE(8)-H40#
A43:D50	A43	=(S40#>0)*(S40#<=5)*S40#
H43:K50	H43	=IF(A43#,INDEX($I$28#,A43#,SEQUENCE(,4)),"")
Dynamic array formulas.

 

[Xlambda]

The function ADG Array DiaGonal ADG(a,[lr])
a: array
[lr}: left/right argument; 0 or omitted "left" extraction, 1 or <>0 , "right" extraction

=LAMBDA(a,[lr],LET(r,ROWS(a),c,COLUMNS(a),sc,SEQUENCE(,c),d,r+c-1,s,SEQUENCE(d),
    pl,sc-1,pr,SORT(pl,,-1,1),x,IF(lr,s-pr,s-pl),y,(x>=0)*(x<=r)*x,
    IF(y,INDEX(IF(a="","",a),y,sc),"")
    )
)

Book1.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1	Function ADG(a,[lr]) Array Diagonal
2	a: array
3	[lr}: left/right argument; 0 or omitted "left" extraction, 1 or <>0 , "right" extraction
4
5							lr,omitted					lr,1
6				a			=ADG(A7#)					=ADG(A7#,1)
7	1	2	3	4			1								4
8	5	6	7	8			5	2						3	8
9	9	10	11	12			9	6	3				2	7	12
10	13	14	15	16			13	10	7	4		1	6	11	16
11	17	18	19	20			17	14	11	8		5	10	15	20
12								18	15	12		9	14	19
13									19	16		13	18
14										20		17
15
16						lr,1											lr,1
17	a		=ADG(A18#)			=ADG(A18#,1)					a		=ADG(I18#)				=ADG(I18#,1)
18	1		1			1			1	2	3		1						3
19	2		2			2								2				2
20	3		3			3									3		1
21
22													lr,1
23					a		=ADG(A24:E31)						=ADG(A24:E31,1)
24	a	c	f	j	5		a										5
25	b	e	i	4	10		b	c								j	10
26	d	h	3	9	15		d	e	f						f	4	15
27	g	2	8	14	o		g	h	i	j				c	i	9	o
28	1	7	13	n	s		1	2	3	4	5		a	e	3	14	s
29	6	12	m	r	v		6	7	8	9	10		b	h	8	n	v
30	11	l	q	u	y		11	12	13	14	15		d	2	13	r	y
31	k	p	t	x	z		k	l	m	n	o		g	7	m	u	z
32								p	q	r	s		1	12	q	x
33									t	u	v		6	l	t
34										x	y		11	p
35											z		k
36
37	Note: The function can hanlde blanks												lr,1
38					a		=ADG(A39:E46)						=ADG(A39:E46,1)
39	a	c	f		5		a										5
40	b	e	i	4	10		b	c									10
41	d		3	9	15		d	e	f						f	4	15
42	g	2	8	14	o		g		i					c	i	9	o
43	1	7	13	n	s		1	2	3	4	5		a	e	3	14	s
44	6	12	m		v		6	7	8	9	10		b		8	n	v
45	11	l	q	u	y		11	12	13	14	15		d	2	13		y
46	k		t	x	z		k	l	m	n	o		g	7	m	u	z
47									q		s		1	12	q	x
48									t	u	v		6	l	t
49										x	y		11
50											z		k
51
Sheet3

Cell Formulas
Range	Formula
G6,M38,G38,M23,G23,Q17,M17,C17,F17,L6	G6	=FORMULATEXT(G7)
A7:D11	A7	=SEQUENCE(5,4)
G7:J14	G7	=ADG(A7#)
L7:O14	L7	=ADG(A7#,1)
A18:A20	A18	=SEQUENCE(3)
C18:C20	C18	=ADG(A18#)
F18:F20	F18	=ADG(A18#,1)
I18:K18	I18	=SEQUENCE(,3)
M18:O20	M18	=ADG(I18#)
Q18:S20	Q18	=ADG(I18#,1)
G24:K35,G39:K50	G24	=ADG(A24:E31)
M24:Q35,M39:Q50	M24	=ADG(A24:E31,1)
Dynamic array formulas.

 

[Xlambda]

Book1.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1	If we want the extraction array to be aligned to left, excluding blanks,														other functions
2	or we want to extract only "full" diagonals, we already have functions for that.														AFUSBYROW
3	By "full" arrays I mean, diagonals with maximum nr. of elements.														AHCLEAN
4	width of ADG=MIN(ROWS(a),COLUMNS(a))=MIN(8,5)=5=>max elem=width ADG
5
6					a		=ADG(A7:E14)						=ADG(A7:E14,1)
7	a	c	f	j	5		a										5
8	b	e	i	4	10		b	c								j	10
9	d	h	3	9	15		d	e	f						f	4	15
10	g	2	8	14	o		g	h	i	j				c	i	9	o
11	1	7	13	n	s		1	2	3	4	5		a	e	3	14	s
12	6	12	m	r	v		6	7	8	9	10		b	h	8	n	v
13	11	l	q	u	y		11	12	13	14	15		d	2	13	r	y
14	k	p	t	x	z		k	l	m	n	o		g	7	m	u	z
15								p	q	r	s		1	12	q	x
16									t	u	v		6	l	t
17										x	y		11	p
18											z		k
19
20							=AFUSBYROW(G7#)						=AFUSBYROW(M7#)
21	align diagonal array. to the left						a						5
22							b	c					j	10
23							d	e	f				f	4	15
24							g	h	i	j			c	i	9	o
25							1	2	3	4	5		a	e	3	14	s
26							6	7	8	9	10		b	h	8	n	v
27							11	12	13	14	15		d	2	13	r	y
28							k	l	m	n	o		g	7	m	u	z
29							p	q	r	s			1	12	q	x
30							t	u	v				6	l	t
31							x	y					11	p
32							z						k
33
34							=AHCLEAN(G7#)						=AHCLEAN(M7#)
35	extracting "full" diagonals						1	2	3	4	5		a	e	3	14	s
36							6	7	8	9	10		b	h	8	n	v
37							11	12	13	14	15		d	2	13	r	y
38							k	l	m	n	o		g	7	m	u	z
39
40							AHCLEAN applied to the arrays before alignment, or after alignment, since is
41							designed to filter rows by their nr. of blanks "n", will return same arrays
42							when we filter only for "full" rows
43							n,omitted						n,omitted
44							=AHCLEAN(G21#)						=AHCLEAN(M21#)
45	with "n" argument						1	2	3	4	5		a	e	3	14	s
46	of AHCLEAN we can						6	7	8	9	10		b	h	8	n	v
47	vary what diagonals to						11	12	13	14	15		d	2	13	r	y
48	extract						k	l	m	n	o		g	7	m	u	z
49
50													n,2
51							=AHCLEAN(G21#,COLUMNS(G21#)-3)						=AHCLEAN(M21#,2)
52	extracting diag. with						d	e	f				f	4	15
53	at least 3 elements						g	h	i	j			c	i	9	o
54							1	2	3	4	5		a	e	3	14	s
55	max diag elements=						6	7	8	9	10		b	h	8	n	v
56	=width ADG=clms(ADG)=5						11	12	13	14	15		d	2	13	r	y
57							k	l	m	n	o		g	7	m	u	z
58	n argument in AHCLEAN						p	q	r	s			1	12	q	x
59	n=5-3=2						t	u	v				6	l	t
60
Sheet4

Cell Formulas
Range	Formula
G6,G51,M51,M44,G44,M34,G34,M20,G20,M6	G6	=FORMULATEXT(G7)
G7:K18	G7	=ADG(A7:E14)
M7:Q18	M7	=ADG(A7:E14,1)
G21:K32,M21:Q32	G21	=AFUSBYROW(G7#)
G35:K38,M35:Q38	G35	=AHCLEAN(G7#)
G45:K48,M45:Q48	G45	=AHCLEAN(G21#)
G52:K59	G52	=AHCLEAN(G21#,COLUMNS(G21#)-3)
M52:Q59	M52	=AHCLEAN(M21#,2)
Dynamic array formulas.

 

[Xlambda]

Another amazing challenge with words, today's (23-Jan-22) MrExcel YT: WORDLE Helper In Excel - Solve Wordle Faster! - Episode 2462 (has link to download the workbook to get entire Word array: WordleHelperFromMrExcel.xlsx )
Came out with a function:
WORDLE(wa,[b ],[g],[gi],[y],[yi])
wa: words array range
[b ]: "black" letters string (ex: "audo")
[g]: "green" letters string (ex: "ice")
[gi]: "green" indexes, numbers, each digit (1-5) len(gi)=len(g) (ex: 245)
[y]: "yellow" letters (ex: "ien")
[yi]: "yellow" indexes, numbers, each digit (1-5) len(yi)=len( y) (ex: 441)

=LAMBDA(wa,[b],[g],[gi],[y],[yi],
    LET(s,SEQUENCE(,5),w,MID(wa,s,1),
       k,IF(ISOMITTED(b),1,BYROW(IFERROR(SEARCH(w,b),0),LAMBDA(x,SUM(x)=0))),
       l,IF(ISOMITTED(g),1,REDUCE(1,SEQUENCE(LEN(g)),LAMBDA(v,i,v*BYROW(IFERROR(SEARCH(w,MID(g,i,1)),0)*s=--MID(gi,i,1),LAMBDA(x,SUM(--x)))))),
       m,IF(ISOMITTED(y),1,REDUCE(1,SEQUENCE(LEN(y)),LAMBDA(v,i,v*BYROW(IFERROR(SEARCH(w,MID(y,i,1))*s<>--MID(yi,i,1),0),LAMBDA(x,SUM(--x)))))),
      FILTER(wa,k*l*m)
    )
)

WordleHelperFromMrExcel.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R
1	Word								single cell
2	aahed		A	U	D	I	O		=WORDLE(A2:A8939,"audotrs","ice",245,"ien",441)
3	aalii		T	I	R	E	S		mince
4	aargh		N	I	E	C	E		wince		different cells, successive steps
5	abaca		W	I	N	C	E		yince		=WORDLE(A2:A8939,"audo",,,"i",4)
6	abaci										beige
7	aback										beigy		=WORDLE(K6#,"trs","i",2,"e",4)
8	abaft										being		bible
9	abaka										benni		bikie		=WORDLE(M8#,,"ice",245,"n",1)
10	abamp										bibbs		bilge		mince
11	abase										bible		binge		wince
12	abash										bicep		civie		yince
13	abate										bices		fiche
14	abaya										biers		fille
15	abbas										biffs		gighe
16	abbes										biffy		gimme
17	abbey										biggy		hinge
18	abbot										bight		kibbe
19	abeam										bigly		liege
20	abele										biker		lieve
21	abets										bikes		miche
22	abhor										bikie		mille
23	abide										bilby		mince
24	abled										biles		minke
25	abler										bilge		niche
26	ables										bilgy		niece
27	abmho										bilks		nieve
28	abode										bills		nixie
29	abohm										billy		piece
30	aboil										biner		pixie
31	aboma										bines		viewy
32	aboon										binge		wince
33	abort										binit		winze
34	about										bints		yince
35	above										birch
36	abris										birks
Sheet3

Cell Formulas
Range	Formula
I2,O9,M7,K5	I2	=FORMULATEXT(I3)
I3:I5	I3	=WORDLE(A2:A8939,"audotrs","ice",245,"ien",441)
K6:K968	K6	=WORDLE(A2:A8939,"audo",,,"i",4)
M8:M34	M8	=WORDLE(K6#,"trs","i",2,"e",4)
O10:O12	O10	=WORDLE(M8#,,"ice",245,"n",1)
Dynamic array formulas.

 

[Xlambda]

Went to the web site: Wordle - A daily word game
Super fun to play!!!!! Took 20s to finish!!! Is this cheating?? For me, it was important to check if WORDLE function works. And it does!! ?(Screen capture attached)

WORDLE function WordleHelperFromMrExcel.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1	Word
2	aahed		H	I	N	G	E		=WORDLE(A2:A8939,"hngealbk","ir",32,"ipc",214)
3	aalii		A	L	I	B	I		crimp
4	aargh		P	R	I	C	K		crisp
5	abaca		C	R	I	S	P				successive entering of arguments (same cell I3)
6	abaci		C	R	I	M	P				first word hinge
7	aback									1.	=WORDLE(A2:A8939,"hnge",,,"i",2)
8	abaft										chose from list alibi
9	abaka									2.	=WORDLE(A2:A8939,"hngealb","i",3,"i",2)
10	abamp										chose from list *****
11	abase									3.	=WORDLE(A2:A8939,"hngealbk","ir",32,"ipc",214)
12	abash										2 results only
13	abate										chose crisp
14	abaya										only one left, crimp, was the answer
15	abbas
16	abbes
17	abbey
18	abbot
19	abeam
20	abele
21	abets
22	abhor
23	abide
24	abled
25	abler
26	ables
27	abmho
28	abode
29	abohm
30	aboil
31	aboma
Sheet4

Cell Formulas
Range	Formula
I2	I2	=FORMULATEXT(I3)
I3:I4	I3	=WORDLE(A2:A8939,"hngealbk","ir",32,"ipc",214)
Dynamic array formulas.

 

[Xlambda]

WORDLE function WordleHelperFromMrExcel.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S
1	Word		SPOILER ALERT !!!!! This will reveal today's wordle.
2	aahed		¡¡¡ Scroll down only if you want to see the result !!!
3	aalii		Used different "tactics" for this one: If we find a letter on its position, do not choose next word
4	aargh		from filtered list. The list will reveal only the words with that letter in that position.
5	abaca		It will be a waste of that space to choose a word from the list, so I chose a word with a different letter
6	abaci		in that position, and the tactics paid off.
7	aback		Called WORDLE after introducing the first 2 words, and got a unique result. After 2 tries only.
8	abaft		So, if you ask me now, yes, I think using the function is cheating. At least was fun to find out.?✌️
9	abaka		We can play the game without the function and use it only to see how we could have performed better.
10	abamp
11	abase
12	abash
13	abate
14	abaya
15	abbas
16	abbes
17	abbey
18	abbot
19	abeam
20	abele
21	abets
22	abhor
23	abide
24	abled
25	abler
26	ables
27	abmho
28	abode
29	abohm
30	aboil
31	aboma
32	aboon
33	abort
34	about
35	above
36	abris
37	abuse
38	abuts
39	abuzz
40	abyes
41	abysm
42	abyss
43	acari
44	acerb
45	aceta		A	M	O	U	R
46	ached		B	E	A	N	S		=WORDLE(A2:A8939,"moben","r",5,"aaus",1345)
47	aches		S	U	G	A	R		sugar
48	achoo
WORDLE 25Jan22

Cell Formulas
Range	Formula
I46	I46	=FORMULATEXT(I47)
I47	I47	=WORDLE(A2:A8939,"moben","r",5,"aaus",1345)

 

[Xlambda]

Tired of waiting another 24h for the next WORDLE game?
Let's build our own WORDLE game board in a few simple steps with Conditional Formatting.

WORDLE function WordleHelperFromMrExcel.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V
1	Word					1	2	3	4	5					function waiting for "arguments"
2	aahed		spin	n									DV list		=WORDLE(A2:A8939)
3	aalii			oread	1						no word				aahed
4	aargh				2						no word				aalii
5	abaca				3						no word				aargh
6	abaci				4						no word				abaca
7	aback				5						no word				abaci
8	abaft				6						no word				aback
9	abaka														abaft
10	abamp			Setup											abaka
11	abase			Formatting D3:											abamp		Playing the game
12	abash			-letters color white (invisible)											abase		D3, "y", ENTER
13	abate			Fornula D3:											abash		D3, "n", ENTER (to block the selection for consistent results)
14	abaya			=IF(D2="n",D3,INDEX(A2:A8939,RANDBETWEEN(1,8938)))											abate		Choose first word from DV in M3
15	abbas														abaya		(latest excel update does search on dropdown list)
16	abbes			Formatting F3:J8											abbas		Fill out 1st word (CF will show the matches)
17	abbey			-letters white color, bold, centered, inner grid lines white color											abbes		Fill out 2nd word and so on
18	abbot														abbey
19	abeam			Conditional Formatting formulas F3:J8 (fill colors)											abbot		Use the WORDLE function or not
20	abele			black CF											abeam		filling out the arguments, according with color codes
21	abets			=ISERR(SEARCH(F3,$D$3))											abele
22	abhor			yellow CF											abets		Play again?
23	abide			=LET(x,SEARCH(F3,$D$3),AND(F3<>"",ISNUMBER(x),x<>F$1))											abhor		Delete F3:J8, and do another "spin"
24	abled			green CF											abide
25	abler			=AND(F3<>"",SEARCH(F3,$D$3)=F$1)											abled
26	ables														abler
27	abmho			Formula K3, drag and drop K3:K8											ables
28	abode			=IF(ISNA(XMATCH(TEXTJOIN("",,F3:J3),$A$2:$A$8939)),"no word","")											abmho
29	abohm														abode
30	aboil			Data Validation M3											abohm
31	aboma			=$A$2:$A$8939											aboil
32	aboon														aboma
33	abort														aboon
SETUP My WORDLE

Cell Formulas
Range	Formula
O2	O2	=FORMULATEXT(O3)
D3	D3	=IF(D2="n",D3,INDEX(A2:A8939,RANDBETWEEN(1,8938)))
O3:O8940	O3	=WORDLE(A2:A8939)
K3:K8	K3	=IF(ISNA(XMATCH(TEXTJOIN("",,F3:J3),$A$2:$A$8939)),"no word","")
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
F3:J8	Expression	=AND(F3<>"",SEARCH(F3,$D$3)=F$1)	text	NO
F3:J8	Expression	=LET(x,SEARCH(F3,$D$3),AND(F3<>"",ISNUMBER(x),x<>F$1))	text	NO
F3:J8	Expression	=ISERR(SEARCH(F3,$D$3))	text	NO

Cells with Data Validation
Cell	Allow	Criteria
M3	List	=$A$2:$A$8939

 

[Xlambda]

Playing...

WORDLE function WordleHelperFromMrExcel.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S
1	Word					1	2	3	4	5					function waiting for "arguments"
2	aahed		spin	n									DV list		=WORDLE(A2:A8939,"mxergtfl","ina",234,"an",34)
3	aalii			pinas	1	m	i	x	e	r			mixer		kinas
4	aargh				2	g	i	a	n	t					pinas
5	abaca				3	f	i	n	a	l					vinas
6	abaci				4	p	i	n	a	s
7	aback				5						no word			Fun note: ?
8	abaft				6						no word			I presume that pinas means:
9	abaka													PiNAS: Raspberry Pi Based Network Attached Storage
10	abamp													or
11	abase													pineapple (piña in spanish)
12	abash
13	abate
14	abaya
My WORDLE

Cell Formulas
Range	Formula
O2	O2	=FORMULATEXT(O3)
D3	D3	=IF(D2="n",D3,INDEX(A2:A8939,RANDBETWEEN(1,8938)))
O3:O5	O3	=WORDLE(A2:A8939,"mxergtfl","ina",234,"an",34)
K3:K8	K3	=IF(ISNA(XMATCH(TEXTJOIN("",,F3:J3),$A$2:$A$8939)),"no word","")
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
F3:J8	Expression	=AND(F3<>"",SEARCH(F3,$D$3)=F$1)	text	NO
F3:J8	Expression	=LET(x,SEARCH(F3,$D$3),AND(F3<>"",ISNUMBER(x),x<>F$1))	text	NO
F3:J8	Expression	=ISERR(SEARCH(F3,$D$3))	text	NO

Cells with Data Validation
Cell	Allow	Criteria
M3	List	=$A$2:$A$8939

 

[Xlambda]

A little bit about tactics.

WORDLE function WordleHelperFromMrExcel.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1	Word					1	2	3	4	5					function waiting for "arguments"
2	aahed		spin	n									DV list		=WORDLE(A2:A8939,"bortchfusgd","ai",14,"illl",3452)
3	aalii			aalii	1	a	b	o	r	t			abort		aalii
4	aargh				2	c	h	i	l	e
5	abaca				3	f	u	s	i	l
6	abaci				4	a	l	g	i	d
7	aback				5	a	a	l	i	i		←←	!!! Something wrong with CF !!!
8	abaft				6						no word		(CF SEARCH relative to G2 cell finds 1st occurrence of "a")
9	abaka
10	abamp					Tactics
11	abase					Choose as 1st word a word that has no duplicate letters
12	abash				1	abort
13	abate					When we have a "green", exclude that letter on purpose
14	abaya					(since we already know where "a" is will use its
15	abbas					space for other letter)
16	abbes					1st argument:
17	abbey					(…"borta") and chose from results "chile"
18	abbot				2	chile
19	abeam					still keep "a" out
20	abele					2nd argument:
21	abets					(..."bortache",,,"il",34) and chose from results "fusil"
22	abhor				3	fusil
23	abide					now introduce all arguments correctly
24	abled					3rd argument:
25	abler					(..."bortchfus","ai",14,"ill",345) => only 4 words possible
26	ables
27	abmho			=WORDLE(A2:A8939,"bortchfus","ai",14,"ill",345)
28	abode			aalii
29	abohm			algid		chose "algid"
30	aboil			algin
31	aboma			alkie
32	aboon
33	abort				4	algid
34	about					4th argument:
35	above					(..."bortchfusgd","ai",14,"illl",3452)
36	abris
37	abuse			=WORDLE(A2:A8939,"bortchfusgd","ai",14,"illl",3452)
38	abuts			aalii
39	abuzz			final result!!!
40	abyes
My WORDLE

Cell Formulas
Range	Formula
O2,D37,D27	O2	=FORMULATEXT(O3)
D3	D3	=IF(D2="n",D3,INDEX(A2:A8939,RANDBETWEEN(1,8938)))
O3	O3	=WORDLE(A2:A8939,"bortchfusgd","ai",14,"illl",3452)
K3:K8	K3	=IF(ISNA(XMATCH(TEXTJOIN("",,F3:J3),$A$2:$A$8939)),"no word","")
D28:D31	D28	=WORDLE(A2:A8939,"bortchfus","ai",14,"ill",345)
D38	D38	=WORDLE(A2:A8939,"bortchfusgd","ai",14,"illl",3452)
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
F3:J8	Expression	=ISERR(SEARCH(F3,$D$3))	text	NO
F3:J8	Expression	=AND(F3<>"",SEARCH(F3,$D$3)=F$1)	text	NO
F3:J8	Expression	=LET(x,SEARCH(F3,$D$3),AND(F3<>"",ISNUMBER(x),x<>F$1))	text	NO

Cells with Data Validation
Cell	Allow	Criteria
M3	List	=$A$2:$A$8939

 

[Xlambda]

Modified CF formula for "green CF" =F3=MID($D$3,F$1,1) , should be top condition, "yello CF" second.
Setup page:

WORDLE function WordleHelperFromMrExcel.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V
1	Word					1	2	3	4	5					function waiting for "arguments"
2	aahed		spin	n									DV list		=WORDLE(A2:A8939)
3	aalii			oread	1						no word				aahed
4	aargh				2						no word				aalii
5	abaca				3						no word				aargh
6	abaci				4						no word				abaca
7	aback				5						no word				abaci
8	abaft				6						no word				aback
9	abaka														abaft
10	abamp			Setup											abaka
11	abase			Formatting D3:											abamp		Playing the game
12	abash			-letters color white (invisible)											abase		D3, "y", ENTER
13	abate			Fornula D3:											abash		D3, "n", ENTER (to block the selection for consistent results)
14	abaya			=IF(D2="n",D3,INDEX(A2:A8939,RANDBETWEEN(1,8938)))											abate		Choose first word from DV in M3
15	abbas														abaya		(latest excel update does search on dropdown list)
16	abbes			Formatting F3:J8											abbas		Fill out 1st word (CF will show the matches)
17	abbey			-letters white color, bold, centered, inner grid lines white color											abbes		Fill out 2nd word and so on
18	abbot														abbey
19	abeam			Conditional Formatting formulas F3:J8 (fill colors)											abbot		Use the WORDLE function or not
20	abele			black CF											abeam		filling out the arguments, according with color codes
21	abets			=ISERR(SEARCH(F3,$D$3))											abele
22	abhor			yellow CF											abets		Play again?
23	abide			=LET(x,SEARCH(F3,$D$3),AND(F3<>"",ISNUMBER(x),x<>F$1))											abhor		Delete F3:J8, and do another "spin"
24	abled			green CF		top in the CF list									abide
25	abler			=F3=MID($D$3,F$1,1)											abled
26	ables														abler
27	abmho			Formula K3, drag and drop K3:K8											ables
28	abode			=IF(ISNA(XMATCH(TEXTJOIN("",,F3:J3),$A$2:$A$8939)),"no word","")											abmho
29	abohm														abode
30	aboil			Data Validation M3											abohm
31	aboma			=$A$2:$A$8939											aboil
32	aboon														aboma
SETUP My WORDLE

Cell Formulas
Range	Formula
O2	O2	=FORMULATEXT(O3)
D3	D3	=IF(D2="n",D3,INDEX(A2:A8939,RANDBETWEEN(1,8938)))
O3:O8940	O3	=WORDLE(A2:A8939)
K3:K8	K3	=IF(ISNA(XMATCH(TEXTJOIN("",,F3:J3),$A$2:$A$8939)),"no word","")
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
F3:J8	Expression	=F3=MID($D$3,F$1,1)	text	NO
F3:J8	Expression	=LET(x,SEARCH(F3,$D$3),AND(F3<>"",ISNUMBER(x),x<>F$1))	text	NO
F3:J8	Expression	=ISERR(SEARCH(F3,$D$3))	text	NO

Cells with Data Validation
Cell	Allow	Criteria
M3	List	=$A$2:$A$8939