Word VBA Macro

[Steve001]

Hello,

I am not familiar with macros in word but have used them in excel quite a bit...
Is it possible to look through a word document for hyper links these are mainly from 'insert cross reference' then do the following ....

Some of these can be inside tables from 'insert table function'

check if it has an underline
underline if not

check the colour
set to dark blue if not

PS. Please put comments in the code so i can understand

I am using office 363 & office 2021

Regards
Steve

 

[Macropod]

For example:

Sub Demo()
Application.ScreenUpdating = False
Dim HLnk As Hyperlink
For Each HLnk In ActiveDocument.Hyperlinks
  HLnk.Range.Style = wdStyleHyperlink
Next
Application.ScreenUpdating = True
End Sub

 

[Steve001]

I will try this at work tommrow, thank you and let you know

 

[Steve001]

For example:

Sub Demo()
Application.ScreenUpdating = False
Dim HLnk As Hyperlink
For Each HLnk In ActiveDocument.Hyperlinks
  HLnk.Range.Style = wdStyleHyperlink
Next
Application.ScreenUpdating = True
End Sub

Hello Macropod,

tried this today at work and it didnt work, we use office 365

The document does have multiple sections in it. 3 or 4 i think and a different front page
The colour change was more than likley done with CTRL+A then font "automatic" or a highlighted section then font "automatic" on a document review

Regards

Steve

 

[Macropod]

In which case, they probably aren't actual hyperlinks, but just url text strings.

That could be rectified with code like:

Sub Demo()
ActiveDocument.AutoFormat
End Sub

but that tends to be too aggressive.

Try:

Sub MakeLinks()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .Format = False
    .Wrap = wdFindStop
    .MatchWildcards = True
    .Replacement.Text = ""
    ' hyperlinks
    .Text = "htt[ps]{1,2}://[!^13^t^l ]{1,}"
  End With
  Do While .Find.Execute
    .Hyperlinks.Add .Duplicate, .Text, , , .Text
    .Start = .Hyperlinks(1).Range.End
  Loop
End With
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .Format = False
    .Wrap = wdFindStop
    .MatchWildcards = True
    .Replacement.Text = ""
    ' email addresses
    .Text = "<[0-9A-ÿ.\-]{1,}\@[0-9A-ÿ\-.]{1,}"
  End With
  Do While .Find.Execute
    .Hyperlinks.Add .Duplicate, .Text, , , .Text
    .Start = .Hyperlinks(1).Range.End
  Loop
End With
Application.ScreenUpdating = True
End Sub

The above code activates all email addresses and hyperlinks in the document body.