Word VBA Macro Assistance

[Steve001]

Hello All,

I wish to modify the macro that is in this post

Word VBA Macro

Hello, I am not familiar with macros in word but have used them in excel quite a bit... Is it possible to look through a word document for hyper links these are mainly from 'insert cross reference' then do the following .... Some of these can be inside tables from 'insert table function'...

www.mrexcel.com

Sub RefColorizer()
Application.ScreenUpdating = False
Dim Fld As Field, StrTxt As String
With ActiveDocument
For Each Fld In .Fields
With Fld
If .Type = wdFieldRef Then
StrTxt = Trim(.Code.Text)
If InStr(StrTxt, "\h") > 0 Then
StrTxt = "REF " & Split(StrTxt, " ")(1) & " \* Charformat \h"
.Code.Text = StrTxt: .Code.Font.Underline = True: .Code.Font.ColorIndex = wdBlue
End If
End If
End With
Next
.Fields.Update
End With
Application.ScreenUpdating = True
End Sub

This code works fantastic, i have come across an older document that is set as follows:

Reference Type: Numbered Item
Insert Reference to: Paragraph Number

The above code changes these to

Reference Type: Heading
Insert Reference to: Heading Text

Can you please advise what to change

I am using office 363 & office 2021

Regards

Steve

 

[Macropod]

The code you posted is incapable of changing the actual references to something else; all it can do is display the reference as underlined blue text.

PS: When posting VBA code, kindly post formatted code using the VBA code tags - on the posting menu.

 

[Steve001]

The code you posted is incapable of changing the actual references to something else; all it can do is display the reference as underlined blue text.

PS: When posting VBA code, kindly post formatted code using the VBA code tags - on the posting menu.

Hi Macropod,

first - apologies for not posing code correctly, i see the VBA Icon now.

When i run the code, i was horrified to find it did change the numbered references to headings of the numbered item.
Thank god for snapshots on the server.


is it possible to make up a macro like you did before for me, but instead of the headings, it changes the paragraph number to blue and underline if they are not set.


Regards

Steve

 

[Macropod]

Try:

Sub RefColorizer()
Application.ScreenUpdating = False
Dim Fld As Field, StrTxt As String
With ActiveDocument
For Each Fld In .Fields
  With Fld
    If .Type = wdFieldRef Then
      StrTxt = Trim(Split(Split(Split(.Code.Text, "\h")(0), "\* Mergeformat")(0), "\* Charformat")(0)) & " \* Charformat \h"
      .Code.Text = StrTxt: .Code.Font.Underline = True: .Code.Font.ColorIndex = wdBlue
    End If
  End With
Next
.Fields.Update
End With
Application.ScreenUpdating = True
End Sub

It is not possible to change the character formatting of only part of the field.

 

[Steve001]

Hi Macropad,

Thank you, this worked a treat

Steve