Vehicle Maintenance on certain interval

[Advice]

Hello,

I am trying to figure out how to calculate on which month a vehicle maintenance is needed base off the miles per month, service interval, and odometer. For example, Bike 1 odometer is 0, drives 80 miles per month, and maintenance is needed every 300 miles. The first maintenance for Bike 1 will occur in April (80*4=320), the second maintenance will occur in August (80*8=640), and so on. Bike 2 odometer is 300, drives 120 miles per month, and maintenance is needed every 500 miles. The first maintenance for Bike 2 will occur in February since odometer is at 300 and two month of driving is 240 so (300+240=540). The second will occur after odometer will reach 1000 (July). Below in green is the month that maintenance is needed.

"Yes" for the green
"No" for the remaining

I tried multiple IFs but got stuck..

Thanks for any help.

 

[BSALV]

Map1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P
1		service	miles	odometer	1	2	3	4	5	6	7	8	9	10	11	12
2	bike1	300	80	0	80	160	240	320	400	480	560	640	720	800	880	960
3	bike2	500	120	300	420	540	660	780	900	1020	1140	1260	1380	1500	1620	1740
4	bike3	1000	200	900	1100	1300	1500	1700	1900	2100	2300	2500	2700	2900	3100	3300
Blad2

Cell Formulas
Range	Formula
E1:P1	E1	=SEQUENCE(,12)
E2:P4	E2	=+E$1*$C2+$D2
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
F2:P4	Expression	=AFRONDEN.BENEDEN.WISK(E2;$B2)<>AFRONDEN.BENEDEN.WISK(F2;$B2)	text	NO

formula for conditional format in english

=FLOOR.MATH(E2,$B2)<>FLOOR.MATH(F2,$B2)

 

[Fluff]

Another option

+Fluff 1.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1
2		service	miles	odometer		Jan-22	Feb-22	Mar-22	Apr-22	May-22	Jun-22	Jul-22	Aug-22	Sep-22	Oct-22	Nov-22	Dec-22
3	bike1	300	80	0		80	160	240	320	400	480	560	640	720	800	880	960
4	bike2	500	120	300		120	240	360	480	600	720	840	960	1080	1200	1320	1440
5	bike3	1000	200	900		200	400	600	800	1000	1200	1400	1600	1800	2000	2200	2400
Main

Cell Formulas
Range	Formula
F2:Q2	F2	=DATE(2022,SEQUENCE(,12),1)
F3:Q5	F3	=SEQUENCE(,12,C3,C3)
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
F3:Q5	Expression	=INT((F3+$D3)/$B3)>INT((E3+$D3)/$B3)	text	NO

 

[Fluff]

Or if you want Yes & No in the cells

+Fluff 1.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1
2		service	miles	odometer		Jan-22	Feb-22	Mar-22	Apr-22	May-22	Jun-22	Jul-22	Aug-22	Sep-22	Oct-22	Nov-22	Dec-22
6	bike1	300	80	0		No	No	No	Yes	No	No	No	Yes	No	No	No	Yes
7	bike2	500	120	300		No	Yes	No	No	No	Yes	No	No	No	Yes	No	No
8	bike3	1000	200	900		Yes	No	No	No	No	Yes	No	No	No	No	Yes	No
Main

Cell Formulas
Range	Formula
F2:Q2	F2	=DATE(2022,SEQUENCE(,12),1)
F6:Q8	F6	=IF(INT(SEQUENCE(,12,C6+D6,C6)/B6)-INT(SEQUENCE(,12,D6,C6)/B6),"Yes","No")
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
F6:Q8	Expression	=F6="Yes"	text	NO