VBA Macro For Already Open IE Window

[RL101]

Hi all,

I'm looking to create a VBA macro which will be ran from Excel (2003 or 2010) & which works with Internet Explorer. I have added 'Microsoft Internet Controls' to VBA References, and have looked at plenty of VBA code on the forum which opens & then navigates to specific websites.

However, what I need is for this macro to affect an already open IE window.

Does anyone have an idea of the syntax / command to have excel "select" a specific IE window already open?

Many thanks!

 

[skybound7]

Wanted to thank you for your post. It came in very helpful today.

 

[ZVI]

Wanted to thank you for your post. It came in very helpful today.

Welcome to MrExcel, Skybound!
And thank you for the response. I also learn here a lot every time

 

[jonaskp]

Hi,

I have a similar problem and have tried using the code in this thread, but cannot get it to work. I

I want to switch (from my userform) to a specific open Internet Explorer window. I know the title of the window (like on this thread the title is "VBA Macro for already open IE Window... etc."). Can I use that combined with your code to always switch to this open window?

Thanks in advance.

 

[ZVI]

Hi,

I have a similar problem and have tried using the code in this thread, but cannot get it to work. I

I want to switch (from my userform) to a specific open Internet Explorer window. I know the title of the window (like on this thread the title is "VBA Macro for already open IE Window... etc."). Can I use that combined with your code to always switch to this open window?

Thanks in advance.

Hi and welcome to MrExcel!
Try this:

' ZVI:2012-12-19 Activating of IE window by its title
' Arguments:
'   Title     -  title of the searchied IE window
'   [IsLike]  -  False/True = exact/partial searching, default is False
Sub ActivateIeByTitle(Title, Optional IsLike As Boolean)
  Dim w As Object
  For Each w In CreateObject("Shell.Application").Windows
    With w
      If .Name = "Windows Internet Explorer" Then
        If IsLike Then
          If InStr(1, .LocationName & " - " & .Name, Title, vbTextCompare) > 0 Then
            ' Partial title of window is found - activate IE window
            w.Visible = False
            w.Visible = True
            Exit For
          End If
        Else
          If StrComp(.LocationName & " - " & .Name, Title) = 0 Then
            ' Title of window is found - activate IE window
            w.Visible = False
            w.Visible = True
            Exit For
          End If
        End If
      End If
    End With
  Next
  Set w = Nothing
End Sub
 
Sub Test1()
  ' Activate IE's window by exact searching in titles
  ActivateIeByTitle "VBA Macro For Already Open IE Window#post3345848 - Windows Internet Explorer"
End Sub
 
Sub Test2()
  ' Activate IE's window by partial searching in titles
  ActivateIeByTitle "VBA Macro For Already Open IE Window", True
End Sub

Regards,

 

[ericm76903]

Hello,
Like with every one else, I am a new member. But this thread seems to be the area I am looking for.

Here is what I have.

I have an IE window opened. And I know the name of the window.

I need the marco to be able to access that object, so I can do something like set a value within the IE window. The setting of this value will trigger an action on the page, like a script that does an alert or something. Can a combination of the previous macros do that?

Thank you in advance,
Eric

 

[ZVI]

I have an IE window opened. And I know the name of the window.
I need the marco to be able to access that object, so I can do something like set a value within the IE window. The setting of this value will trigger an action on the page, like a script that does an alert or something.

Hi Eric,
Welcome to MrExcel !
Function GetIeByTitle finds IE window by window title and returns IE object.
See example of the usage in Test1 subroutine.

' ZVI:2013-03-19 Get IE object of already open window by its title
' Arguments:
'   Title     -  title of the searchied IE window
'   [IsLike]  -  False/True = exact/partial searching, default is False
'   [IsFocus] -  False/True = don't_activate/activate IE window, default is False
Function GetIeByTitle(Title, Optional IsLike As Boolean, Optional IsFocus As Boolean) As Object
  Dim w As Object
  For Each w In CreateObject("Shell.Application").Windows
    With w
      If .Name = "Windows Internet Explorer" Then
        If IsLike Then
          If InStr(1, .LocationName & " - " & .Name, Title, vbTextCompare) > 0 Then
            ' Partial title of window is found - activate IE window
            If IsFocus Then
              w.Visible = False
              w.Visible = True
            End If
            Set GetIeByTitle = w
            Exit For
          End If
        Else
          If StrComp(.LocationName & " - " & .Name, Title) = 0 Then
            ' Title of window is found - activate IE window
            If IsFocus Then
              w.Visible = False
              w.Visible = True
            End If
            Set GetIeByTitle = w
            Exit For
          End If
        End If
      End If
    End With
  Next
  Set w = Nothing
End Function
 
Sub Test1()
  Dim IE As Object
  Set IE = GetIeByTitle("VBA Macro For Already Open IE Window", True, True)
  IE.Navigate "http://www.mrexcel.com/forum/excel-questions/553580-visual-basic-applications-macro-already-open-ie-window-2.html#post3423470"
End Sub

Regards

 

[ZVI]

Another version of Test1 with error trapping:

Sub Test1()
  Dim IE As Object
  Const Title = "VBA Macro For Already Open IE Window"
  Const URL = "http://www.mrexcel.com/forum/excel-questions/553580-visual-basic-applications-macro-already-open-ie-window-2.html#post3423470"
  Set IE = GetIeByTitle(Title, True, True)
  If IE Is Nothing Then
    MsgBox "Window is not found:" & vbLf & Title, vbCritical, "Error"
  Else
    IE.Navigate URL
  End If
End Sub

 

[jonaskp]

I can see that I somehow completely forgot about this thread.

Thank you very much ZVI for your solution to my problem a while back. It is working perfectly.

 

[ZVI]

I can see that I somehow completely forgot about this thread.

Thank you very much ZVI for your solution to my problem a while back. It is working perfectly.

I'm happy to know it has helped
Thank you for the feedback!

 

[bkclaw113]

The responses in this thread have been great, so here is hoping that ZVI is still monitoring.

I used your late binding code as a basis to create this simple tester sub:

Sub ActivateIeByTitle(Title)
  Dim w As Object
  For Each w In CreateObject("Shell.Application").Windows
      If w.Name = "Windows Internet Explorer" Then
            Debug.Print w.locationname
            If w.locationname Like (Title & "*") Then
                w.Visible = False
                w.Visible = True
                Debug.Print "IE Page located"
                GoTo exit_sub
                
            End If
      End If
  Next
    Debug.Print "IE Page Not located"
exit_sub:
  Set w = Nothing
End Sub

The code runs fine on the two computers that I use (Windows XP with Excel 2007 SP3, and Windows 7 with Excel 2007 SP3), however it does not run on a colleagues comptuer who is also running Windows 7 with Excel 2007 SP3.


The Error "Method 'Windows' of object 'IShellDispatch5' Failed" is thrown on the line

For Each w In CreateObject("Shell.Application").Windows

.

Any suggestions on what might be the issue or how to resolve it?