VBA Classes - Functions overload

[saboh12617]

Hello,

According to my research, what I'm trying to do is not possible, but I've noticed that many people here have a more advanced knowledge of VBA than I do, so I'm relying on you.

1. I know that unfortunately VBA is rather strange in terms of its OOP function, but on the subject of classes, can we redefine some basic operators for our objects? I'm thinking in particular of “=” or printing to String.

2. Otherwise, how do you deal with overloading in general, at the level of functions with identical names but taking different arguments? Is the only way to define the arguments as Variants and then check the TypeName?

Thanks for your advice.

Example

Sub mySub()
  Dim myClassInstance As New MyClass
  Dim str As String

  display myClassInstance
  display str
End Sub

Function display(var As Variant)
  Select Case TypeName(var)
  Case “MyClass”
    Debug.Print var.toStr
  Case “String”
    Debug.Print var
  Case Else
    '
  End Select
End Function

 

[Jaafar Tribak]

Welcome to the forum.

There is no such thing as function overloading in VBx. AFAIK, the only way to achieve a similar functionality is what you did. ie: To define the function param(s) as Variant and then act accordingly, based on the variable type of the passed argument(s)

Using Optional parameter(s) and/or the ParamArray keyword can, in some scenarios and to a certain extent, make functions somewhat fexible and hence mimic function overloading. In other words, it can make a function run *different* code without doing a var type check of the passed arguments.

Function Opt(Optional bBool As Boolean) As Boolean
    Opt = bBool
End Function

Sub Test()
    Debug.Print Opt        '<== Ret= False
    Debug.Print Opt(True)  '<== Ret= True
End Sub

Function Sum(ParamArray Numbers() As Variant) As Double
    Dim i As Integer
    For i = LBound(Numbers) To UBound(Numbers)
        Sum = Sum + Numbers(i)
    Next i
End Function

Sub Test()
    Debug.Print Sum(10)                     '<== Ret= 10
    Debug.Print Sum(1, 1.5, 2, 100, -5, 8)  '<== Ret= 107.5
    Debug.Print Sum(2, 2)                   '<== Ret= 4
End Sub

When working with classes, it is *technically* possible to run diff code using functions with identical names if the function is defined in an interface class.

Interface class IPet

Public Sub Sound()
    '
End Sub

Class C_Cat

Implements IPet
Private Sub IPet_Sound()
    Debug.Print "meowww"
End Sub

Class C_Dog:

Implements IPet
Private Sub IPet_Sound()
    Debug.Print "bark bark"
End Sub

Usage:

Sub Test()

    Dim oCat As IPet, oDog As IPet
 
    Set oCat = New C_Cat
    Set oDog = New C_Dog
 
    oCat.Sound
    oDog.Sound

End Sub

Output:
meowww
bark bark

 

[Domenic]

In addition to @Jaafar Tribak 's excellent post, I might add that you could also declare a parameter as an optional Variant. This would allow you to use the IsMissing fuction to check whether the argument has been passed to the procedure, in addition to checking for the data type using TypeName. Then, based on the data being passed to the procedure, you could execute the appropriate code or call another procedure, passing it the relevant variables.

Sub test()

    Dim a As Integer
    Dim b As Double
    Dim c As String
   
    a = 200
    b = 12.5
    c = "red"
   
    foo a, b, c
   
    foo a, b
   
    foo a
   
    foo a, , c
   
End Sub

Sub foo(v1 As Variant, Optional v2 As Variant, Optional v3 As Variant)

    Debug.Print TypeName(v1), IsMissing(v2), IsMissing(v3)
   
End Sub

Here's the output...

Integer       False         False
Integer       False         True
Integer       True          True
Integer       True          False

Hope this helps!

 

[saboh12617]

Hello,

Thank you both for your answers!

Jaafar, very precise message with clear examples, it answers my interrogations. Also i was not aware of the ParamArray for which i already have many uses, as i was simply defining my arrays parameters as variants. For the moment i hadn't touch the Implementations as i had no use for it and it looked a bit clumsy, but you gave me a good example on how it is done in VBA.

Domenic thank you too, i was actually already aware of this "trick" with the isMissing keyword only working with variant types, but very practical. I used it for an RGB picker/randomizer.

I consider the topic solved, thanks again!