Value from row

[Tariq123]

If a row contain different value. Like. A1=0, B1=3, C1=0 D1=4. Then i need first value which is greater then 0. In another cell.
0 3 0 4
I need first value greater then 0, means 3 in A5 cell.
And 2nd value greater then zero in A6 which is 4.
How its possible through formula

 

[Peter_SSs]

I tried below formula.

What about trying the one from post #8?

 

[Tariq123]

When the values are in single digit then the result is coming correct. But when the values are in double digit i.e
A1 B1 C1 D1 E1
0 15 3 0 5
So the result is comming like this
A5 B5 C5 D5
1 5 3 5

But I need
A5 B5 C5 D5
15 3 5

 

[Peter_SSs]

So the result is comming like this

1 5 3 5

That still sounds like you are not using the formula from post #8.

So the result is comming like this
A5 B5 C5 D5

You originally said that you wanted the results down a column, not across a row.

I need first value greater then 0, means 3 in A5 cell.
And 2nd value greater then zero in A6 which is 4.

Here is my method, either way. The number of digits in each number is irrelevant.

22 11 17.xlsm
	A	B	C	D	E
1	1	238	0	15
2
3
4
5	1	238	15
6
7	1
8	238
9	15
10
11
>0

Cell Formulas
Range	Formula
A5:E5	A5	=IFERROR(INDEX($A1:$E1,AGGREGATE(15,6,COLUMN($A1:$E1)/($A1:$E1>0),COLUMNS($A5:A5))),"")
A7:A11	A7	=IFERROR(INDEX(A$1:E$1,AGGREGATE(15,6,COLUMN(A$1:E$1)/(A$1:E$1>0),ROWS(A$7:A7))),"")

 

[Peter_SSs]

Here is my method, either way.

Actually, my formulas are not robust. If new columns are added at the left, the formulas will return incorrect results. Corrected formulas below.

22 11 17.xlsm
	A	B	C	D	E
1	1	238	0	15
2
3
4
5	1	238	15
6
7	1
8	238
9	15
10
11
>0

Cell Formulas
Range	Formula
A5:E5	A5	=IFERROR(INDEX($A1:$E1,AGGREGATE(15,6,(COLUMN($A1:$E1)-COLUMN($A1)+1)/($A1:$E1>0),COLUMNS($A5:A5))),"")
A7:A11	A7	=IFERROR(INDEX(A$1:E$1,AGGREGATE(15,6,(COLUMN(A$1:E$1)-COLUMN(A$1)+1)/(A$1:E$1>0),ROWS(A$7:A7))),"")

 

[Tariq123]

Hi,
Greeting

Thank you very much. Now my problem is resolved. I appriciate your this act of kindness. This plateform is really very helpfull for the people like me.

 

[Peter_SSs]

You're welcome. Thanks for the follow-up.