Userform shows up on the wrong monitor

[smkyle]

I have two userforms that I use. Recently, they have started showing up on the left monitor even though Excel is open on the right monitor. Any ideas?

 

[Jerry Sullivan]

Mike,

Here's two ways to approach this. Neither one is ideal.

You can pass the Userform as an Object type argument. This will allow you to Show the passed Userform, but it throw a Type Mismatch error when control is passed to the calling procedure.

'---in Project.xlsm
Sub Test()
    Call LaunchIT(UserForm1) '--throws error after call.
End Sub

'---In the .xlam file
Public Sub LaunchIT(frm As Object)
    With frm
        .StartUpPosition = 0
        .Left = Application.Left + (0.5 * Application.Width) - (0.5 * .Width)
        .Top = Application.Top + (0.5 * Application.Height) - (0.5 * .Height)
        .Show
    End With
End Sub

One option would be to use an error handler to supress that error.
I hesitate to recommend this though since I don't completely understand the reason for the error and there could be some other effect.

'---in Project.xlsm
Sub Test()
    On Error Resume Next
    Call LaunchIT(UserForm1)
    On Error GoTo 0
End Sub

This thread explains a cleaner, but more complex approach
http://www.mrexcel.com/forum/excel-questions/326834-referencing-userform-another-open-workbook.html

Here's an example that applies that approach...

'---in Project.xlsm
Sub Test1()
    Call LaunchIT(ThisWorkbook.Name, "GetForm1")
End Sub
Sub Test2()
    Call LaunchIT(ThisWorkbook.Name, "GetForm2")
End Sub

Function GetForm1() As UserForm1
    Set GetForm1 = UserForm1
End Function

Function GetForm2() As UserForm2
    Set GetForm2 = UserForm2
End Function

'---In the .xlam file
Public Sub LaunchIT(sWBName As String, sFunctionName As String)
    Dim frm As Object
    Set frm = Application.Run(sWBName & "!" & sFunctionName)
    With frm
        .StartUpPosition = 0
        .Left = Application.Left + (0.5 * Application.Width) - (0.5 * .Width)
        .Top = Application.Top + (0.5 * Application.Height) - (0.5 * .Height)
        .Show
    End With
End Sub

This makes me question whether placing LaunchIT in an Add-In where it is separated from the Userforms is good idea. Typically a primary benefit of putting code in an Add-In is that you can call it from any workbook. In the two examples above, special setup is required in the calling workbook. Rather than doing that special setup, it would seem simpler to just place the LaunchIT code shown in Post #7 of this thread in the calling workbook.