Unload userform and show other userform but cleared

[uk747]

Have 2 userforms called userform1 and userform2

When I have userform1 opened I sometimes need to work on userform2 so Use

Userform1.Hide
Userform2.Show

However when finished with userform2 I want to be able to click a command button to unload userform2 and reshow userform

I've used

Unload userform2
Userform1.show

But when userform1 is shown, I want it to be cleared

Also can same be done when I click the cross on userform2, which will unload userform2 and show userform1 but cleared

 

[dmt32]

So I tested by opening userform2 again. That is when I got the error

My apologies having one of my senior days

Delete the QueryClose event completely in UserForm2

And update the CommandButton code In UserForm1 with following

Private Sub CommandButton1_Click()
    UserForm1.Hide
    UserForm2.Show
    UserForm1.Show
End Sub

and see if this does what you want

Dave

 

[uk747]

Thanks Dave

I did get similar in a different thread
But with the clear code you posted above that seems to do everything I need although to close userform 1 I have to click the X twice

Ps what does hiding and showing userform1 do?
Does it hide1, show2 and show1 just in memory for when 2 closes

Post in thread 'Userform show / hide' Userform show / hide

Private Sub CommandButton1_Click()
    Me.Hide
    UserForm2.Show
    Me.Show
End Sub

 

[GWteB]

... although to close userform 1 I have to click the X twice

If you wanted to prevent this behaviour, then you might consider not using the default instance of a UserForm class module, rather New-ing them up.
That way you're able to destroy the object within the same procedure were the object was created.
In addition, give your first UserForm a custom Show function, returning a value which indicates whether the form should be displayed on screen again.
Your code then could look like this:

This goes in a standard module:

Public Sub LaunchForm1()

    Dim FormOne As UserForm1
    Set FormOne = New UserForm1

    Do While FormOne.ShowDialogAgain    ' <<< use custom function
    Loop

    Unload FormOne
    Set FormOne = Nothing
End Sub

Public Sub LaunchForm2()

    Dim FormTwo As UserForm2
    Set FormTwo = New UserForm2

    FormTwo.Show                        ' <<< use built-in method

    Unload FormTwo
    Set FormTwo = Nothing
End Sub

This goes in the module of UserForm1:

Option Explicit

Private Type TLocals
    ShowAgain   As Boolean
End Type
Private this As TLocals

Private Sub ButtonShowForm2_Click()
    this.ShowAgain = True
    Me.Hide
    LaunchForm2
End Sub

Public Function ShowDialogAgain() As Boolean         '<<< custom function responsible for displaying the form
    Me.Show
    ShowDialogAgain = this.ShowAgain
End Function

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = VBA.vbFormControlMenu Then
        this.ShowAgain = False
        Cancel = True
        Me.Hide
    End If
End Sub

This goes in the module of UserForm2:

Option Explicit

Private Sub ButtonClose_Click()
    Me.Hide
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = VBA.vbFormControlMenu Then
        Cancel = True
        Me.Hide
    End If
End Sub

 

[dmt32]

Thanks Dave

Ps what does hiding and showing userform1 do?

Hi,
sorry about that I tend to have funny days

Hides an object but doesn't unload it - Have a look here in the helpfile: Hide method (Visual Basic for Applications)
for more detail.

Dave

 

[uk747]

Thanks guys ??