Two timestamps in one sheet

[Dscalf1]

Hello All,

I am trying to get two timestamps in one sheet. I have one range of cells (R6:AF6) and when someone types in any information in any of this range of cells I want a time stamp to show up in cell BH6. Now exactly the same I have this range of cells (AJ6:AX6) and when anyone types on any of these cells I want a timestamp to show up in cell BJ6.

I have this code and it works great for the first part if any cells are entered it shows a timestamp in cell BH 6, however I tried to copy and paste this code to do the second set and it wont work.... Any ideas?

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Column = 18 Or Target.Column > 35 Then Exit Sub
    Application.EnableEvents = False
    Cells(Target.Row, 61) = Now
    Application.EnableEvents = True
End Sub

 

[Dscalf1]

Changed it to this... Worked for two rows then it gave me an error and stopped working

Private Sub Worksheet_Change(ByVal Target As Range)





   If Not Intersect(Target, Range("J6:X75")) Is Nothing Then
   ActiveSheet.Unprotect "Bakery"
      Application.EnableEvents = False
      Cells(Target.Row, 52) = Now
      Application.EnableEvents = True
   ElseIf Not Intersect(Target, Range("AB6:AP75")) Is Nothing Then
      Application.EnableEvents = False
      Cells(Target.Row, 54) = Now
      Application.EnableEvents = True
       
      ActiveSheet.Protect "Bakery", True, True
       
   End If
   
End Sub

 

[Joe4]

You only have two different IF statements, and you are unprotecting it in one, and re-protecting in the other, but neither one has both, so both are incomplete.

Try:

Private Sub Worksheet_Change(ByVal Target As Range)

   If Not Intersect(Target, Range("J6:X75")) Is Nothing Then
      ActiveSheet.Unprotect "Bakery"
      Application.EnableEvents = False
      Cells(Target.Row, 52) = Now
      Application.EnableEvents = True
      ActiveSheet.Protect "Bakery", True, True
   ElseIf Not Intersect(Target, Range("AB6:AP75")) Is Nothing Then
      ActiveSheet.Unprotect "Bakery"
      Application.EnableEvents = False
      Cells(Target.Row, 54) = Now
      Application.EnableEvents = True
      ActiveSheet.Protect "Bakery", True, True
   End If
   
End Sub