Transpose several two-column groups of information into a single vertical two-column list

[Tiv]

I was sent a spreadsheet, but reading the information is difficult in a horizontal format. It needs to be vertical. I need to be able to transpose it, but I need it to be in a two-column formation.

The information came to me like this:

	Part	Qty	Part	Qty	Part	Qty	Part	Qty
Aisle 1	Bananas	1​	Oranges	2​	Apples	9​	Raspberries	50​
Aisle 2	Blueberries	16​	Mangos	7​	Potatoes	10​	Carrots	12​
Aisle 3	Green beans	72​	Lima beans	100​	Onions	37​	Celery	9​

I need it to look like this:

Aisle 1
Bananas	1​
Oranges	2​
Apples	9​
Raspberries	50​
Aisle 2
Blueberries	16​
Mangos	7​
Potatoes	10​
Carrots	12​
Aisle 3
Green beans	72​
Lima beans	100​
Onions	37​
Celery	9​

​

I'm not having any luck with the Transpose function unless there's more to the formula.

How do I turn several two-column-bits of information in a horizontal format into a vertical two-column list?

 

[Fluff]

We've upgraded to Office 365 now.

Thanks for that.
A couple of formula solutions

Fluff.xlsm
	A	B	C	D	E	F	G	H	I
1		Part	Qty	Part	Qty	Part	Qty	Part	Qty
2	Aisle 1	Bananas	1	Oranges	2	Apples	9	Raspberries	50
3	Aisle 2	Blueberries	16	Mangos	7	Potatoes	10	Carrots	12
4	Aisle 3	Green beans	72	Lima beans	100	Onions	37	Celery	9
5
6
7	Aisle 1			Aisle 1	Bananas	1
8	Bananas	1		Aisle 1	Oranges	2
9	Oranges	2		Aisle 1	Apples	9
10	Apples	9		Aisle 1	Raspberries	50
11	Raspberries	50		Aisle 2	Blueberries	16
12	Aisle 2			Aisle 2	Mangos	7
13	Blueberries	16		Aisle 2	Potatoes	10
14	Mangos	7		Aisle 2	Carrots	12
15	Potatoes	10		Aisle 3	Green beans	72
16	Carrots	12		Aisle 3	Lima beans	100
17	Aisle 3			Aisle 3	Onions	37
18	Green beans	72		Aisle 3	Celery	9
19	Lima beans	100
20	Onions	37
21	Celery	9
Main

Cell Formulas
Range	Formula
A7:B21	A7	=LET(a,WRAPROWS(TOCOL(B2:I4),2),SORTBY(VSTACK(a,EXPAND(A2:A4,,2,"")),VSTACK(SEQUENCE(ROWS(a)),SEQUENCE(ROWS(A2:A4),,0.2,4))))
D7:F18	D7	=HSTACK(TOCOL(IF(ISTEXT(B2:I4),A2:A4,x),3),WRAPROWS(TOCOL(B2:I4),2))
Dynamic array formulas.

 

[alansidman]

this is not VBA but Power Query which is part of your version but is called Get and Transform Data and found on the Data Tab