Text to excel

[Ewright8]

I have 240 text files (dxdiag reports from 240 different computers) that I would like to put into an excel spreadsheet. I do not need all of the file but would like to have about nine different lines from the file placed in cells with one row representing each file (computer). Is this possible or does anyone have any suggestions how I may go about this without having to type all the data in manually.

 

[Norie]

This works for me.

Sub ListDX()
Dim rng As Range
Dim fs, f, f1, fc, s
Dim LastRow As Long
Dim strPath As String
    strPath = "C:\DX\" 'This is the Directory the files are located in
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(strPath)
    Set fc = f.Files
    Set rng = Worksheets(1).Range("A2")
    
    rng.Offset(-1).Resize(, 7).Value = Array("Machine name", "Operating System", "Processor", "Memory", _
                                                               "Card name", "Description", "FileName")
    
    For Each f1 In fc
    
        Open strPath & f1.Name For Input As #1
        
            Do Until InStr(info, "Description:")
            
                Line Input #1, info
                
                If info <> "" Then ' check for blank lines
                
                    x = Split(info, ":")
                    
                    If Trim(x(0)) = "Machine name" Then
                        rng.Value = Trim(x(1))
                    End If
                    If Trim(x(0)) = "Operating System" Then
                        rng.Offset(, 1).Value = Trim(x(1))
                    End If
                    If Trim(x(0)) = "Processor" Then
                        rng.Offset(, 2).Value = Trim(x(1))
                    End If
                    If Trim(x(0)) = "Memory" Then
                        rng.Offset(, 3).Value = Trim(x(1))
                    End If
                    If Trim(x(0)) = "Card name" Then
                        rng.Offset(, 4).Value = Trim(x(1))
                    End If
                    If Trim(x(0)) = "Description" Then
                        rng.Offset(, 5).Value = Trim(x(1))
                    End If
                    
                End If
                
            Loop
                
            rng.Offset(, 6).Value = f1.Name
            
        Close #1
        
        info = ""
    
        Set rng = rng.Offset(1)
    
    Next
End Sub

The latest problem was due to blank lines, my method of extracting the data (Split) would fall down when encountering one, so I added an If.

If you were to use InStr then that might not be needed.

Anyways the code seems to work for me, mind you I did only test it on 5 files which were all the same but I added the filenames.

By the way, you do realise there is more than one item called Description?

The above code only picks up the first one.

 

[Ewright8]

This works great. Thank you very much. I am trying to pull the name of the sound card and this is what it seems to be pulling so any other "Description" fields seem to be getting overlooked for some reason but that works for me. Again thank you very much for your expertise and professionalism.

 

[Norie]

Well my files seem to be returning the description for some sort of speaker(s) rather than a sound card.

Mind you I'm pretty sure my machine will have bog-standard audio.