Target.Address

[mulholm]

I found this code on the internet which works when dealing with one individual cell however stops working when values are pasted in to multiple cells at once. Can anyone help?


Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Address = "$I$3" Then
'disable events
Application.EnableEvents = False
Range("I3").Value = Range("I3").Value / 86400

End If

'reenable events
Application.EnableEvents = True
Exit Sub
'error handler
ErrHnd:
Err.Clear
'reenable events
Application.EnableEvents = True

End Sub

 

[Joe4]

Welcome to the Board!

What range do you want to apply it to?
If all of column I, then you can do something like this:

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rng As Range
    Dim cell As Range
    
'   Check for cells pasted in column I
    Set rng = Intersect(Target, Columns("I:I"))
    
'   Exit if no cells in column I updated
    If rng Is Nothing Then Exit Sub
    
'   Disable events
    Application.EnableEvents = False
    
'   Loop through all updated cells in column I
    For Each cell In rng
        cell = cell.Value / 86400
    Next cell

'   Reenable events
    Application.EnableEvents = True

    Exit Sub

'error handler
ErrHnd:
    Err.Clear
'   Reenable events
    Application.EnableEvents = True

End Sub

Note: I also see that you have error handling code, but are not calling it anywhere in your code. So it won't do much in that case.

 

[mulholm]

Welcome to the Board!

What range do you want to apply it to?
If all of column I, then you can do something like this:

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rng As Range
    Dim cell As Range
    
'   Check for cells pasted in column I
    Set rng = Intersect(Target, Columns("I:I"))
    
'   Exit if no cells in column I updated
    If rng Is Nothing Then Exit Sub
    
'   Disable events
    Application.EnableEvents = False
    
'   Loop through all updated cells in column I
    For Each cell In rng
        cell = cell.Value / 86400
    Next cell

'   Reenable events
    Application.EnableEvents = True

    Exit Sub

'error handler
ErrHnd:
    Err.Clear
'   Reenable events
    Application.EnableEvents = True

End Sub

Note: I also see that you have error handling code, but are not calling it anywhere in your code. So it won't do much in that case.

It would be for range I3:I26

 

[Joe4]

It would be for range I3:I26

Then simply change this line to suit your range.

    Set rng = Intersect(Target, Columns("I:I"))

Change to this:

    Set rng = Intersect(Target, [COLOR=#ff0000]Range("I3:I26")[/COLOR])

 

[mulholm]

Then simply change this line to suit your range.

    Set rng = Intersect(Target, Columns("I:I"))

Change to this:

    Set rng = Intersect(Target, [COLOR=#ff0000]Range("I3:I26")[/COLOR])

thank you so much, appreciate your help

 

[Joe4]

You are welcome!