Sort Columns low to high but im told cells are merged

[ipbr21054]

Hi,

I have two columns A & B of which i need each sorted separatley from low to high numbers.
This worked fine.

Private Sub SortFrameNumbers_Click()
Range("A2:A150").Sort Key1:=Range("A2"), Order1:=xlAscending, Header:=xlNo
Range("B2:B50").Sort Key1:=Range("B2"), Order1:=xlAscending, Header:=xlNo
End Sub

It sorted column A from 1-100 perfect then it sorted column B 1-22 perfect.

So i then added it to my code which populates these two columns but i then get a RTE 1004 please see screenshot.

This is the code i added it to.

Private Sub GoldWingCountry_Click()
    Dim Cell As Range
    Dim wsMC As Worksheet
    Dim wsCountry As Worksheet
    
    Set wsMC = Sheets("MCLIST")
    Set wsCountry = Sheets("COUNTRYLIST")
    
    With Sheets("COUNTRYLIST")
        .Range("A2:B1000").ClearContents
    End With
    
    wsCountry.Range("A1") = "GOLD WING UK"
    wsCountry.Range("B1") = "GOLD WING USA"
    
    With wsMC
        For Each Cell In .Range("D8:D" & .Cells(.Rows.Count, "D").End(xlUp).Row)
            If Cell.Value = "GOLD WING UK" Then
                wsCountry.Range("A" & Rows.Count).End(xlUp).Offset(1) = Cell.Offset(, -2)
            ElseIf Cell.Value = "GOLD WING USA" Then
               wsCountry.Range("B" & Rows.Count).End(xlUp).Offset(1) = Cell.Offset(, -2)
            End If
        Next Cell
    End With
    Sheets("COUNTRYLIST").Select
    Range("A2:A150").Sort Key1:=Range("A2"), Order1:=xlAscending, Header:=xlNo
    Range("B2:B50").Sort Key1:=Range("B2"), Order1:=xlAscending, Header:=xlNo
End Sub

I run the code & columns A & B are populated.

The code sorts column A2 & down the page from 1-100 etc & at this point column B is untouched.
Once done the code sorts column B2 & down the page from 1 -50 etc & at this point column A is untouched.

Please advise as none of the cells are merged

 

[MARK858]

Can you upload a copy of your workbook to a free file hosting site like www.box.com or www.dropbox.com, mark the file file for sharing and paste the link it provides in the thread.

Please sanitize any sensitive data before uploading (you can delete any of the sheets other than "COUNTRYLIST")

 

[ipbr21054]

Here we go try this.

DOWNLOAD FILE HERE

 

[MARK858]

Afraid that I won't download from that site as it is forcing me to allow some cookies that I don't want to allow.
Hopefully someone else will be willing to look at it for you.

 

[ipbr21054]

Let me see dropbox for you

 

[ipbr21054]

Try this but i dont use it often.

download file

 

[MARK858]

Can you see if you have the same issue if you change the code to

    With Sheets("COUNTRYLIST")
        .Range("A2:A150").Sort Key1:=.Range("A2"), Order1:=xlAscending, Header:=xlNo
        .Range("B2:B50").Sort Key1:=.Range("B2"), Order1:=xlAscending, Header:=xlNo
    End With

 

[ipbr21054]

That worked fine.

What was the issue please ?

 

[MARK858]

I think when you used

Sheets("COUNTRYLIST").Select

It wasn't making "COUNTRYLIST" active and so "MCLIST" was still Active and the code was acting on that which does have merged cells.

Probably changing

Sheets("COUNTRYLIST").Select

to

Sheets("COUNTRYLIST").Activate

would also work but I don't like using either Select or Activate unless I have to.

 

[ipbr21054]

Ok many thanks for your time

 

[MARK858]

You're welcome