setting cell value to 1 based on 2 conditions

[d3ad3y3]

Hi everyone, i need help regarding the formula i try to use, i use 3 columns, Date, Activity and Validity. Validity should be set to 1 at the end of the last same date if and only if there is atleast 1 Service each date, see example below

date	activity	validity
1-Oct	Deliver
1-Oct	Service
1-Oct	Service	1
2-Oct	Pickup
2-Oct	Deliver
3-Oct	Service	1
4-Oct	Service	1

tried to use countif but if the first activity of the day is not Service, the validity wont be set to 1.

 

[etaf]

Thanks

@Peter_SSs​

I might have missed something in the thread but wouldn't this simpler formula in col E do the same thing?

much better as i said in an earlier post

i think this is overcomplicated a formula - seems to work - but i have not fully tested

I thought i was overcomplicated the formula
Thanks for simplifying - HOPEFULLY the OP will try

*d3ad3y3​

alright, as of now i dont experience any unusual using the last long formula with max(), ill try to replace the formula with this shorten one, i think can shorten it more by replacing the 2nd and 3rd "service" string with B2 instead. thanks for your help again.

I think

Peter_SSs​

would be a better easier solution

 

[d3ad3y3]

I might have missed something in the thread but wouldn't this simpler formula in col E do the same thing?

24 11 05.xlsm
	A	B	C	D	E
1	date	activity	validity	formula reduced	formula reduced
2	1-Oct	Deliver
3	1-Oct	Service
4	1-Oct	Service	1	1	1
5	2-Oct	Pickup
6	2-Oct	Deliver
7	3-Oct	Service	1	1	1
8	4-Oct	Service	1	1	1
9	4-Oct	Deliver
Sheet2 (2)

Cell Formulas
Range	Formula
D2:D9	D2	=IF(AND(B2="service",COUNTIFS($A$2:A2,A2,$B$2:B2,"service") =COUNTIFS($A$2:$A$100,A2,$B$2:$B$100,"service") ),1,"")
E2:E9	E2	=IF(AND(B2="service",COUNTIFS(A2:A$100,A2,B2:B$100,B2)=1),1,"")

hi, thanks for your help too, this is the modified formula i used in my workbook, =IF(AND($B7="Service",COUNTIFS($A7:$A$260,$A7,$B7:$B$260,$B7)=1),1,0)
your formula is interesting since the A2 was not locked so it moves down with the current row, removing the need to use another COUNTIFS, just need to check for =1, thank you also

 

[Peter_SSs]

this is the modified formula i used in my workbook, =IF(AND($B7="Service",COUNTIFS($A7:$A$260,$A7,$B7:$B$260,$B7)=1),1,0)

Originally you had 1 or blank as results in the formula column. Your latest formula now has 1 or 0. If that is what you want the formula can be simplified again slightly.

=--AND($B7="Service",COUNTIFS($A7:$A$260,$A7,$B7:$B$260,$B7)=1)

your formula is interesting since the A2 was not locked so it moves down with the current row

If the current row is "Service" there is no point looking upwards to see if this is the last one.

 

[Peter_SSs]

Originally you had 1 or blank as results in the formula column. Your latest formula now has 1 or 0. If that is what you want the formula can be simplified again slightly.
=--AND($B7="Service",COUNTIFS($A7:$A$260,$A7,$B7:$B$260,$B7)=1)

Oops, since I was simplifying & the formula appears to just be copied down the column, perhaps I should have taken back out the extra $ signs that you added after post 10 as well?

=--AND(B7="Service",COUNTIFS(A7:A$260,A7,B7:B$260,B7)=1)