Search by textbox and criteria combobox and show in listbox

[mredvard]

Hello, good day everyone, I want to search based on the combobox as (search column) and textbox in sheet 1.
How is this possible?

search by combo box.xlsm
	A	B	C	D	E	F	G	H
1	no.	Name	id	sex	age	date of birth	IQ Test	Meaning of Name
2	14	Ani	4935426663	female	22	31/10/1999	98	Ornament, Beautiful, Variant of Anne / Ane
3	15	Anna	4037366181	female	20	26/10/2001	126	‘Grace’. Also used as a nickname for Annabelle
4	16	Anya	9330871997	female	25	12/04/1997	109	Inexhaustible, Gracious, Graceful
5	17	Ariel	3660975387	female	25	27/01/1997	127	‘Lion of God’. It is also spelt as Arielle.
6	18	Arya	9935838857	female	23	17/07/1999	108	‘Lioness, Noble’. It is frequently spelt as Aria.
7	19	Ash	3882405562	female	25	14/12/1996	96	Form of Ashley, Ash Tree Meadow
8	20	Ashley	7564224317	female	26	03/03/1996	99	‘One who lives in the ash tree grove’. It is one of the modern English baby girl names.
9	21	Audrey	4121552927	female	18	04/11/2003	111	Strength
10	22	Ava	6560141181	female	19	29/10/2002	124	‘Bird’ or ‘the living one’ or ‘life’. It may also be spelt as Eva.
11	23	Badra	8004003618	female	27	10/05/1995	114	Full Moon, Pretty, Goddess Durga
12	24	Beatrice	6870820925	female	20	11/02/2002	91	‘She who makes you happy’. It is also spelt Beatrix.
13	25	Belinda	3658130608	female	24	09/06/1998	119	‘Beautiful’. One of its other variants is ‘Bella’. ‘Bright linden tree’ or ‘bright serpent’.
14	26	Bella	2725479507	female	18	20/09/2003	122	‘Beautiful’. It is often used as a nickname for other names ending in –bella, like Annabella, Arabella, etc.
15	27	Bency	5191837585	female	26	06/04/1996	111	Right Hand of Jesus Christ, A Talkative Girl who is Very Scared
16	28	Berey	4061161891	female	20	12/05/2002	107	Exalted One, Bearer of Victory, True Image, To Help, Berry
17	29	Bery	1556003492	female	22	14/12/1999	129	True Image, Bearer of Victory, Berry, To Help, Exalted One
18	30	Bety	2871809184	female	20	01/09/2002	119	God is My Oath, God is Perfection
19	31	Bitsy	2218154671	female	22	17/11/1999	109	God is Perfection, God is My Oath
20	32	Brianna	5026781508	female	21	20/08/2001	123	‘Strong’
sheet1

 

[DanteAmor]

it will be in the whole columns

Try this:

Option Explicit

Dim a As Variant

Private Sub Combobox1_change()
  Call FilterData
End Sub

Private Sub TextBox1_Change()
  Call FilterData
End Sub

Sub FilterData()
  Dim cmb As String, txt As String
  Dim b As Variant
  Dim i As Long, j As Long, k As Long, col As Long, m As Long
 
  ReDim b(1 To UBound(a, 1), 1 To UBound(a, 2))
  ListBox1.Clear
  
  If ComboBox1.ListIndex = -1 Then
    col = 0
  Else
    col = ComboBox1.ListIndex + 1
  End If
  
  If TextBox1.Value = "" Then Exit Sub
  
  
  For i = 1 To UBound(a)
    
    If col = 0 Then
      For m = 1 To UBound(a, 2)
        If LCase(a(i, m)) Like "*" & LCase(TextBox1.Value) & "*" Then
          k = k + 1
          For j = 1 To 8
            b(k, j) = a(i, j)
          Next
          Exit For
        End If
      Next
  
    Else
    
      txt = TextBox1.Value
      If LCase(a(i, col)) Like "*" & LCase(TextBox1.Value) & "*" Then
        k = k + 1
        For j = 1 To 8
          b(k, j) = a(i, j)
        Next
      End If
    
    End If
  Next i
  If k > 0 Then ListBox1.List = b
End Sub

Private Sub userform_initialize()
  Dim ws As Worksheet
  
  Set ws = ThisWorkbook.Sheets("sheet1")
  ComboBox1.List = Application.Transpose(ws.Range("A1:H1").Value)
  ListBox1.ColumnCount = 8
  a = ws.Range("A2:H" & ws.Range("A" & Rows.Count).End(xlUp).Row).Value
End Sub