Run time error '424'

[wwrightchess]

I recorded the following macro but when I tried to run it again I get the error run time error '424' object required on the third line when it tries to set the axes title.

Sub Macro11()
'
' Macro11 Macro
'

'
Sheets("ff_plot").Select
ActiveChart.SetElement (msoElementPrimaryValueAxisTitleAdjacentToAxis)
ActiveChart.Axes(xlValue, xlPrimary).AxisTitle.Text = "Freezing Fraction"
Selection.Format.TextFrame2.TextRange.Characters.Text = "Freezing Fraction"
With Selection.Format.TextFrame2.TextRange.Characters(1, 17).ParagraphFormat
.TextDirection = msoTextDirectionLeftToRight
.Alignment = msoAlignCenter
End With
With Selection.Format.TextFrame2.TextRange.Characters(1, 17).Font
.BaselineOffset = 0
.Bold = msoFalse
.NameComplexScript = "+mn-cs"
.NameFarEast = "+mn-ea"
.Fill.Visible = msoTrue
.Fill.ForeColor.RGB = RGB(89, 89, 89)
.Fill.Transparency = 0
.Fill.Solid
.Size = 10
.Italic = msoFalse
.Kerning = 12
.name = "+mn-lt"
.UnderlineStyle = msoNoUnderline
.Strike = msoNoStrike
End With
ActiveChart.ChartArea.Select
End Sub

 

[Domenic]

While I don't use the Mac version of Excel, I think this should work. The following code assumes that your chart is located on a chart sheet, and that the sheet is named "ff_plot". If the chart is actually embedded within a worksheet, replace this part of the code . . .

With Sheets("ff_plot").Axes(Type:=xlValue)

with

With Worksheets("ff_plot").ChartObjects("Chart 1").Chart.Axes(Type:=xlValue) 'change the chart name accordingly

Here's the code . . .

    With Sheets("ff_plot").Axes(Type:=xlValue)
        .HasTitle = True
        With .AxisTitle
            .Text = "Freezing Fraction"
            With .Font
                .Name = "Arial"
                .Size = 10
            End With
            With .Format.TextFrame2.TextRange.ParagraphFormat
                .TextDirection = msoTextDirectionLeftToRight
                .Alignment = msoAlignCenter
            End With
        End With
    End With

Hope this helps!

 

[wwrightchess]

on a chart sheet

 

[Domenic]

In that case, the code I posted should work, although you may want to make changes, such as the font name. Have you tried it?