Return minimum values from matrix

[cs56lioy]

I have this matrix (not data in cells), like so:

{3,5,1;2,2,4}

3	5	1
2	2	4

The MIN may or may not be in the same column

I need to return the MIN of each row in a column, meaning {1;2}

1

2

Any help would be appreciated

 

[hagia_sofia]

Hello, this might be rather too complicated but you can give it a try:

=LET(
a,{3,5,1;2,2,4},
b,FILTERXML("<x><y>"&SUBSTITUTE(TEXTJOIN(",",,a),",","</y><y>")&"</y></x>","//y"),
c,FILTERXML("<x><y>"&SUBSTITUTE(TEXTJOIN(",",,IF(SEQUENCE(1,COLUMNS(a),1,1),SEQUENCE(ROWS(a)))),",","</y><y>")&"</y></x>","//y"),
d,SORTBY(b,c,1,b,1),
INDEX(d,SEQUENCE(ROWS(a),,1,COLUMNS(a)),0))

 

[kvsrinivasamurthy]

Data A2:C3

=LET(a,A2:C3,MAKEARRAY(ROWS(a),1,LAMBDA(r,c,MIN(INDEX(a,r,)))))

 

[Fluff]

How about

=LET(d,{3,5,1;2,2,4},r,ROWS(d),MOD(SMALL(d+SEQUENCE(r,,100,100),SEQUENCE(r,,,COLUMNS(d))),100))

@kvsrinivasamurthy 2021 does not have the Lambda functions and if it did you could just use

=BYROW({3,5,1;2,2,4},MIN)

 

[Rick Rothstein]

You could always put this in a cell and copy it down one row...

=MIN(INDEX({9,5,4;5,3,4},ROWS($1:1)))

 

[cs56lioy]

Thank to all for the great answers.
I do have Excel 2024, so I could use BYROW

As a side note, just checked again the Excel Version in Account Details in this forum, and 2024 is not an option (yet), that's why my profile says 2021

 

[Fluff]

Glad we could help & thanks for the feedback.

2024 is not an option

I have asked Suat to change that & will let you know when it's done.

 

[Fluff]

@cs56lioy, the Xl version options has been updated, so you can now show 2024.

 

[Peter_SSs]

I do have Excel 2024, so I could use BYROW

Does that mean the MS help for BYROW is incorrect, as it does not show 2024 as an applicable version?

 

[Rick Rothstein]

Does that mean the MS help for BYROW is incorrect, as it does not show 2024 as an applicable version?

View attachment 120344

This site shows it, and many other functions, are in that version...
Excel Functions 2024 New Functions