Removing Consecutive Duplicates

[Cubist]

I'm looking for a formula solution that removes the consecutive duplicate characters - keeping only one instance. Note that the characters are case-sensitive. See examples.

Book2
	A	B
1	From	To
2	Mississipi	Misisipi
3	Roller	Roler
4	Excellent	Excelent
5	Mamma Mia	Mama Mia
6	Mmmmhm	Mmhm
7	BelLair	BelLair
Sheet4

 

[hagia_sofia]

This came to my mind (but I guess it is really complicated - but you are brilliant at making things easier):

=LET(split,CODE(MID(A2,SEQUENCE(LEN(A2)),1)),duplicates,IFERROR(split-(--(INDEX(split,SEQUENCE(ROWS(split)))=INDEX(split,SEQUENCE(ROWS(split),,2)))*split),CODE(RIGHT(A2,1))),filter,FILTER(duplicates,duplicates<>0),CONCAT(CHAR(filter)))

 

[shaowu459]

工作簿1.xlsx
	A	B	C	D	E
1	From	To
2	Mississipi	Misisipi	Misisipi	TRUE
3	Roller	Roler	Roler	TRUE
4	Excellent	Excelent	Excelent	TRUE
5	Mamma Mia	Mama Mia	Mama Mia	TRUE
6	Mmmmhm	Mmhm	Mmhm	TRUE
7	BelLair	BelLair	BelLair	TRUE
8
Sheet4

Cell Formulas
Range	Formula
C2:C7	C2	=REDUCE(,MID(A2,ROW($1:99),1),LAMBDA(x,y,x&IF(EXACT(y,RIGHT(x)),,y)))
D2:D7	D2	=B2=C2

 

[hagia_sofia]

One more option:

MAP(A2:A7,LAMBDA(c,LET(a,CODE(MID(c,SEQUENCE(LEN(c)),1)),b,a=DROP(VSTACK(a,""),1),CONCAT(CHAR(FILTER(a,b=FALSE))))))

 

[Cubist]

This came to my mind (but I guess it is really complicated - but you are brilliant at making things easier):

I appreciate the sentiment. I mostly learn from people on here and experiment with Excel. I can't claim to be brilliant.

 

[Cubist]

@shaowu459
Great solution. I'm making a minor change ROW() to SEQUENCE(LEN()) for more robust but works great.

=REDUCE(,MID(A2,SEQUENCE(LEN(A2)),1),LAMBDA(x,y,x&IF(EXACT(y,RIGHT(x)),,y)))