RE: Formula help

[Bazola]

RE: Formula help

Hi All

I need some help with something if you dont mind..

Basically I have a cell that if it contains the text "Yes" it will enter todays date in the cell next to it. I also need it to copy data from one cell into another at the same time but take the values only, not the formula.

Thanks in advance.

Baz

 

[Bazola]

Re: Formula help

Hi All

I need some help with the Macro side if you dont mind, I have a Cell H3, which when I type Yes, it automatically fills in the cell next to it I3 with todays date "=IF(H3="Yes",TODAY(),"")" - this isnt a macro. However I need when I type "Yes" into H3 for it to automatically copy the content from G3 and paste it to cell J3 but with values only. Once this works, I need this for a range H3:H59 and the same for J3:J59.

I really hope you can help as this is the final piece I need to sort

 

[FormR]

Re: Formula help

Hi, you could try this event code - to use, right click the sheet where you want these actions to occur and choose "View Code" and paste the code below into the window that opens up and save the workbook as a macro enabled workbook (.XLSM)

Private Sub Worksheet_Change(ByVal Target As Range)
Dim R As Range, C As Range
Set R = Intersect(Range("H3:H59"), Target)
    If Not R Is Nothing Then
        Application.EnableEvents = False
        For Each C In R
            If UCase(C.Value) = "YES" Then
                C.Offset(, 1).Value = Date
                C.Offset(, 2).Value = C.Offset(, -1).Value
            End If
        Next C
        Application.EnableEvents = True
    End If
End Sub

 

[Bazola]

Re: Formula help

Awesome, thanks man!

 

[Bazola]

Re: Formula help

How would I combine the following into the code you provided above? Basically, once i've entered "Yes" in H3, I want to fill in the info as per what you've already provided but then lock the cell and the spreadsheet as I have put in the code below. Just not sure how to combine them,

Private Sub Worksheet_Change(ByVal Target As Range)
Dim MyRange As Range

Set MyRange = Intersect(Range("H3:H999"), Target)
If Not MyRange Is Nothing Then
Sheets("Sheet1").Unprotect password:="hello"
MyRange.Locked = True
Sheets("Sheet1").Protect password:="hello"
End If
End Sub

 

[FormR]

Re: Formula help

Hi, something like this maybe..

Private Sub Worksheet_Change(ByVal Target As Range)
Dim R As Range, C As Range
Set R = Intersect(Range("H3:H59"), Target)
    If Not R Is Nothing Then
        Application.EnableEvents = False
        Me.Unprotect Password:="hello"
        For Each C In R
            If UCase(C.Value) = "YES" Then
                C.Offset(, 1).Value = Date
                C.Offset(, 2).Value = C.Offset(, -1).Value
                C.Locked = True
            End If
        Next C
        Me.Protect Password:="hello"
        Application.EnableEvents = True
    End If
End Sub