Quicker VBA needed

[Dimbers]

Evening,

I have a VBA code that works as it should but is a little clunky to use, as in its quite slow.

The code looks in column A and if it finds "Live" it will hide all of those rows. I have the same code running to look for "Complete" and will then hide those rows.

It would be great to have a code that runs quicker if anyone can offer some help?

Below is the code I'm using

Sub HideRowsLive()

Application.ScreenUpdating = False

 Dim cell As Range

  For Each cell In ActiveWorkbook.ActiveSheet.Columns("A").Cells

      If cell.Value = "Complete" Then
      
       cell.EntireRow.Hidden = False
       
       End If
  
  Next cell
  
  For Each cell In ActiveWorkbook.ActiveSheet.Columns("A").Cells

       
       If cell.Value = "Live" Then
      
       cell.EntireRow.Hidden = False
       
       End If

  Next cell
  

  For Each cell In ActiveWorkbook.ActiveSheet.Columns("A").Cells

      If cell.Value = "Live" Then

      cell.EntireRow.Hidden = True
      

    End If

  Next cell

 

[dmt32]

sorry, fell foul of the 10 min rule & neglected to include parameter for the different worksheets

Sub HideRows(ByVal sh As Object, ByVal UserAction As HideLiveComplete)
    Dim c               As Range, HideRange As Range, DataRange As Range
    Dim HideWhat        As String
    
    With sh
        .Unprotect
        'unhide all rows
        .Cells.Rows.Hidden = False
        If UserAction = ShowAll Then Exit Sub
        'set data range
        Set DataRange = .Cells(1, 1).Resize(.Cells(.Rows.Count, "A").End(xlUp).Row)
    End With
    
    HideWhat = Choose(UserAction, "LIVE", "COMPLETE")
    
    For Each c In DataRange.Cells
        'create union
        If UCase(c.Value) = HideWhat Then
            If HideRange Is Nothing Then
                Set HideRange = c
            Else
                Set HideRange = Union(HideRange, c)
            End If
        End If
    Next c
    'hide rows in one go
    If Not HideRange Is Nothing Then HideRange.EntireRow.Hidden = True
End Sub

to call code pass the worksheet object as first argument

HideRows Worksheets("Template1"), HideLive

If using ActiveX commandbuttons on your worksheet you should be able to use the ME keyword in place of Worksheets("Template1")

Dave