Print all unique integer partitions given an integer as input CODE

[Juggler_IN]

I am trying to replicate the following code in VBA:
IntPartitions

The equivalent VBA UDF, which is not giving output, is:

Function printPartitions(target As Integer, maxValue As Integer, suffix As String)

    If target = 0 Then
        printPartitions = suffix
    Else
        If (maxValue > 1) Then
            printPartitions = printPartitions(target, maxValue - 1, suffix)
            Debug.Print printPartitions
        Else
            If (maxValue <= target) Then
                printPartitions = printPartitions(target - maxValue, maxValue, maxValue & ";" & suffix)
                Debug.Print printPartitions
            End If
        End If
    End If

End Function

Any reason it is only giving the following output =printPartitions(4,4,"") = 1;1;1;1; and not the full set?

 

[shg]

Sub demo()
  printPartitions 4, 4, ""
End Sub

Function printPartitions(tgt As Long, max As Long, sfx As String) As String
  If tgt = 0 Then
    Debug.Print sfx
  Else
    If max > 1 Then printPartitions tgt, max - 1, sfx
    If max <= tgt Then printPartitions tgt - max, max, max & " " & sfx
  End If
End Function

Nice code by the OP on SO.

 

[shg]

And the other,

Function printPartitions(tgt As Long, max As Long, sfx As String) As String
  ' shg 2020
  ' adapted from https://stackoverflow.com/a/17723022
  Dim i             As Long

  If tgt = 0 Then
    Debug.Print sfx
  Else
    For i = 1 To IIf(max < tgt, max, tgt)
      printPartitions tgt - i, i, i & " " & sfx
    Next i
  End If
End Function

 

[Juggler_IN]

@shg ... this works. While on the same topic, this function returns the unique integer partitions of the integer n with at most k parts. How can this UDF be modified to return the number of partitions of n into k parts. Attaching a reference link, page 11. Combinatorics.