Primes

[Juggler_IN]

I want to generate prime nonprime series 2, 7, 19, 29, 53, 71, 97, 103, 137, 173, 193, 233, ... from the initial primes 2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31, 37, 41, 43, 47, 53, 59, 61, 67, 71, 73, 79, 83, 89, 97, 101, 103, 107, 109, 113, 127, 131, 137, 139, 149, 151, 157, 163, 167, 173, 179, 181, 191, 193, 197, 199, 211, 223, 227, 229.

A “prime nonprime” prime number is a prime number that occupies a prime-numbered position in the list of all non-prime numbers.

The PARI code below ...

(PARI) c(n) = {for(k=0, PrimePi(n), IsPrime(n++)&&k--); n};
t(n) = if(n<3, n-1, c(n-2));
vector(50, n, Primes(t(Primes(n))))

... is essentially picking from primes ... 2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31, 37, 41, 43, 47, 53, 59, 61, 67, 71, 73, 79, 83, 89, 97, 101, 103, 107, 109, 113, 127, 131, 137, 139, 149, 151, 157, 163, 167, 173, 179, 181, 191, 193, 197, 199, 211, 223, 227, 229

to output 2, , , 7, , , , 19, , 29, , , , , , 53, , , , 71, , , , , 97, , 103, , , , , , 137, , , , , , , 173, , , , 193, , , , , ,

I have coded PrimePi and IsPrime... But I am unable to implement the PARI code in VBA ...

Function PrimePi(n As Variant) As Integer

    Dim i As Integer, j As Integer
    Dim IsPrime As Boolean
    Dim Count As Integer

    Count = 0&

    For i = 2& To n
        IsPrime = True
        For j = 2& To Sqr(i)
            If i Mod j = 0& Then
                IsPrime = False
                Exit For
            End If
        Next j
        If IsPrime Then Count = Count + 1&
    Next i

    PrimePi = Count

End Function
Function IsPrime(n As Variant) As Boolean

    Dim i As Variant

    If n < 2 Then IsPrime = False: Exit Function

    For i = 2 To Sqr(n)
        If n Mod i = 0 Then IsPrime = False: Exit Function
    Next i

    IsPrime = True

End Function

 

[duggie33]

I am not familiar with the "&" after numbers like I see in your code. That doesn't mean it is not acceptable, it only means that I do not recall seeing it used in VBA.

Out of curiosity, how are you using the prime nonprime numbers?

I threw this together to see if I understood how to determine the correct numbers...

Book1
	A	B	C
1	Primes	Nonprimes	Prime nonprime
2	2	0
3	3	1	2
4	5	4	7
5	7	6	13
6	11	8	19
7	13	9	23
8	17	10	29
9	19	12	37
10	23	14	43
11	29	15	47
12	31	16	53
13	37	18	61
14	41	20	71
15	43	21	73
16	47	22	79
17	53	24	89
18	59	25	97
19	61	26	101
20	67	27	103
21	71	28	107
22	73	30	113
23	79	32	131
24	83	33	137
25	89	34	139
26	97	35	149
27	101	36	151
28	103	38	163
29	107	39	167
30	109	40	173
31	113	42	181
32	127	44	193
33	131	45	197
34	137	46	199
35	139	48	223
36	149	49	227
37	151	50	229
38	157	51
39	163	52
40	167	54
41	173	55
42	179	56
43	181	57
44	191	58
45	193	60
46	197	62
47	199	63
48	211	64
49	223	65
50	227	66
51	229	68
Sheet8

Cell Formulas
Range	Formula
B2:B51	B2	=LET(seq,SEQUENCE(69,,0,1),FILTER(seq,NOT(ISNUMBER(MATCH(seq,$A$2:$A$51,0)))))
C3:C37	C3	=INDEX($A$2:$A$51,B3)
Dynamic array formulas.

Doug

 

[Juggler_IN]

@duggie13; My requirement is the OEIS sequence A144589 OEIS.

 

[duggie33]

Was my interpretation incorrect? Six is a non-prime number and the sixth prime number is 13, but it is not on the list. My thought is that if we can get it working on the worksheet, it should be able to be coded.

Doug

 

[StephenCrump]

Once you have your primes and non-primes, it's relatively simple to generate A144589:

	A	B	C	D	E	F	G	H	I	J
1	N	50
2							VBA:
3	A000027	A000040	A141468	A144570	A144589		A000040	A141468	A144570	A144589
4	1	2	0	1	2		2	0	1	2
5	2	3	1	4	7		3	1	4	7
6	3	5	4	8	19		5	4	8	19
7	4	7	6	10	29		7	6	10	29
8	5	11	8	16			11	8	16
9	6	13	9	20			13	9	20
10	7	17	10	25			17	10	25
11	8	19	12	27			19	12	27
12	9	23	14	33			23	14	33
13	10	29	15	40			29	15	40
14	11	31	16	44			31	16	44
15	12	37	18				37	18
16	13	41	20				41	20
17	14	43	21				43	21
18	15	47	22				47	22
19	16		24					24
20	17		25					25
21	18		26					26
22	19		27					27
23	20		28					28
24	21		30					30
25	22		32					32
26	23		33					33
27	24		34					34
28	25		35					35
29	26		36					36
30	27		38					38
31	28		39					39
32	29		40					40
33	30		42					42
34	31		44					44
35	32		45					45
36	33		46					46
37	34		48					48
38	35		49					49
39	36		50					50
40	37
41	38
42	39
43	40
44	41
45	42
46	43
47	44
48	45
49	46
50	47
51	48
52	49
53	50
54
Sheet1

Cell Formulas
Range	Formula
A4:A53	A4	=SEQUENCE(N)
B4:B18	B4	=DROP(FILTER(A4#,BYROW(A4#,LAMBDA(r,SUM(--(MOD(r,SEQUENCE(,SQRT(r)))=0))))=1),1)
C4:C39	C4	=LET(seq,SEQUENCE(N+1,,0),FILTER(seq,NOT(ISNUMBER(MATCH(seq,B4#,)))))
D4:D18	D4	=IFERROR(INDEX(C4#,B4#),"")
E4:E18	E4	=IFERROR(INDEX(B4#,D4#),"")
Dynamic array formulas.

Named Ranges
Name	Refers To	Cells
N	=Sheet3!$B$1	C4, A4

Sub Test()

    '1: A000040, 2: A141468, 3: A144570, 4: A144589
    Dim N As Long, Result() As Variant, Count(1 To 2) As Long, i As Long, j As Long
    Dim Prime As Boolean
    
    N = Range("N").Value
    ReDim Result(1 To N + 1, 1 To 4)
    Result(1, 2) = 0
    Result(2, 2) = 1
    Count(2) = 2
    
    On Error Resume Next
    Range("MyResults").ClearContents
    On Error GoTo 0
    
    For i = 2 To N
        Prime = True
        For j = 2 To Sqr(i)
            If i Mod j = 0 Then
                Prime = False
                Count(2) = Count(2) + 1
                Result(Count(2), 2) = i
                Exit For
            End If
        Next j
        If Prime Then
            Count(1) = Count(1) + 1
            Result(Count(1), 1) = i
        End If
    Next i
    
    'Get A144570
    i = 1
    Do Until Result(i, 1) > Count(2)
        Result(i, 3) = Result(Result(i, 1), 2)
        i = i + 1
    Loop
    
    'Get A144589
    i = 1
    Do Until Result(i, 3) > Count(1)
        Result(i, 4) = Result(Result(i, 3), 1)
        i = i + 1
    Loop
    
    With Range("G4:J4").Resize(N + 1)
        .Value = Result
        .Name = "MyResults"
    End With
    
End Sub

 

[Juggler_IN]

@StephenCrump; Thanks ... Can it be implemented as a pure VBA solution, not involving a sheet?

 

[StephenCrump]

The Excel formulae and the VBA code are two different possible solutions. The VBA code involves a worksheet only to:

a) Get the value of N, and
b) Output the results.

Neither of these VBA/Excel interactions is essential.

When you say "VBA solution", what is the question? For example, perhaps you want VBA to generate the first M values of A144589?

 

[Juggler_IN]

@StephenCrump; By VBA solution I mean without using Excel Cells ... essentially an independent VBA function that generates the first n elements.

 

[Juggler_IN]

Ok, I got it ... instead of writing to a sheet ... I created an array to store. Thanks!

 

[StephenCrump]

Ok, I got it ... instead of writing to a sheet ... I created an array to store. Thanks!

That's great!

You might find this a bit faster:

Sub Test()

    Dim MySequence() As Long, m As Long
   
    m = 1000
    MySequence = GenerateA144589(m)
    Range("A1").Resize(UBound(MySequence)).Value = Application.Transpose(MySequence)

End Sub
Function GenerateA144589(m As Long) As Long()

    '1: A000040, 2: A141468, 3: A144570, 4: A144589
    Dim N As Long, Result() As Long, Count(1 To 2) As Long, i As Long, j As Long, Output() As Long
    Dim Prime As Boolean
   
    N = 100000
    ReDim Result(1 To N + 1, 1 To 3)
    ReDim Output(1 To m)
    Result(1, 2) = 0
    Result(2, 2) = 1
    Count(2) = 2
       
    For i = 2 To N
        Prime = True
        For j = 2 To Sqr(i)
            If i Mod j = 0 Then
                Prime = False
                Count(2) = Count(2) + 1
                Result(Count(2), 2) = i
                Exit For
            End If
        Next j
        If Prime Then
            Count(1) = Count(1) + 1
            Result(Count(1), 1) = i
        End If
    Next i
   
    'Get A144570
    i = 1
    Do Until Result(i, 1) > Count(2)
        Result(i, 3) = Result(Result(i, 1), 2)
        i = i + 1
    Loop
   
    'Get A144589
    For i = 1 To m
        If Result(i, 3) <= Count(1) Then
            Output(i) = Result(Result(i, 3), 1)
        Else
            ReDim Preserve Output(1 To i - 1)
            Exit For
        End If
    Next i
       
    GenerateA144589 = Output
       
End Function

Have a play with the values m and N highlighted in red above. I'm guessing that given the prime number theorem, the distribution of the sequence A144589 can also be predicted. In which case you could make an estimate for N sufficient to get m results.

Instead, I have just experimented with some big values, e.g. m =30,000, N=5,000,000, which on my machine takes only a few seconds to print the first 27,493 values of the sequence.

If you want materially more results than this, you'll run into either memory problems or slow computation, and a smarter approach would be necessary.