Play MP3 files using loops

[YasserKhalil]

I am working on a code that would play MP3 files from a specific directory based on a list of the file names of these mp3 files in column A. The code works fine for about five or six files then excel hangs for some time then resume from another unexpected point. How can I fix the code so as to make it play all the mp3 files in column A?

Public wmp As Object

Sub Test()
    Dim r As Long
    Set wmp = CreateObject("new:6BF52A52-394A-11D3-B153-00C04F79FAA6")
    For r = 1 To Cells(Rows.Count, 1).End(xlUp).Row
        With wmp
            .URL = ThisWorkbook.Path & "\Media\" & Cells(r, 1).Value & ".mp3"
            .Controls.Play
        End With
        DoEvents
        Application.Wait Now + TimeValue("00:00:02")
    Next r
End Sub

I got an answer from this link
Play MP3 files using loops
but this stores all the files then play them all .. I need to set waiting time between each file and at the same time I need to select the cell that is playing ..

 

[Legacy 456155]

I don't know why it's hanging. Try setting a reference to wpm.dll, using events along with OnTime.

Code in Worksheet class:

Option Explicit

Private WithEvents wmp As WindowsMediaPlayer
Private r As Range

Sub StartPlaying()
    Set wmp = CreateObject("new:6BF52A52-394A-11D3-B153-00C04F79FAA6")
    Set r = [a1]
    PauseAndPlay 0
End Sub

Private Sub wmp_PlayStateChange(ByVal NewState As Long)
    If NewState = 1 Then Application.OnTime Now, Name & ".PauseAndPlay"
End Sub

Public Sub PauseAndPlay(Optional PauseSecs As Integer = 2)
    If Len(r) = 0 Then Exit Sub
    Application.Wait Now + TimeSerial(0, 0, PauseSecs)
    wmp.Url = ThisWorkbook.Path & "\Media\" & r & ".m4a"
    wmp.Controls.Play
    Set r = r.Offset(1)
End Sub

 

[YasserKhalil]

Thanks a lot. I am not accustomed to using classes. Can you give me an example of how to use the class in that way?

 

[Legacy 456155]

The example does not refer to a user defined class, but a public worksheet class. The code goes in the worksheet's class module. Understood?

 

[YasserKhalil]

Thanks a lot. What reference of wpm as I didn't find that reference?

 

[YasserKhalil]

Thanks a lot. I have found it References: Windows Media Player (wmp.dll)
And the code works well .. Thank you very much.