Pass Cell Address into Formula

[nalij_bond]

Thanks all in advance for your time and help.

My Issue: I am trying to define a variable and use that value to append to a formula within a cell

Current Code:

Sub test3()
'In the PoC Doc Template, use the address function to find the cell reference column in row 10.
'for the term "VHI PMO/GTM". Then in the Sheet 'Key Stakeholders' in cell H6, use the cell
'reference found and append to the formula'

    Dim VHI_Ref
    
    VHI_Ref = "ADDRESS(12,MATCH(""VHI PMO/GTM"",'PoC Doc Template'!R10,0))"

    Sheets("Key Stakeholders").Range("H6").Formula = "='PoC Doc Template'!" & VHI_Ref

End Sub

Expected Result: What I would like to happen is in the 'Key Stakeholders' worksheet, in cell H6 - a formula like "='PoC Doc Template'!L12" is created.

Current Result: As of now, I keep receiving a Debug Error on the Sheets("Key Stakeholders").Range("H6").Formula = "='PoC Doc Template'!" & VHI_Ref line of code.

Any help would be greatly appreciated!

 

[Peter_SSs]

Another option, sticking more to native vba methods might be

Sub Test4()
  Dim VHI_Ref As Range
  
  Set VHI_Ref = Sheets("PoC Doc Template").Rows(10).Find(What:="VHI PMO/GTM", LookIn:=xlValues, LookAt:=xlWhole)
  Sheets("Key Stakeholders").Range("H6").FormulaR1C1 = "='PoC Doc Template'!R12C" & VHI_Ref.Column
End Sub

 

[nalij_bond]

Thanks. Try making this change

VHI_Ref = "ADDRESS(12,MATCH(""VHI PMO/GTM"",'PoC Doc Template'!R10,0))"
VHI_Ref = Evaluate("ADDRESS(12,MATCH(""VHI PMO/GTM"",'PoC Doc Template'!10:10,0))")

Thank you again for your assistance.

Using the following code,

Dim VHI_Ref
    
    VHI_Ref = Evaluate("ADDRESS(12,MATCH(""VHI PMO/GTM"",'PoC Doc Template'!10:10,0))")

    Sheets("Key Stakeholders").Range("H6").Formula = "=PoC Doc Template!" & VHI_Ref & """"

I receive the following error

When debugging the code the last line continues to be highlighted, but I can see that the VHI_Ref is now referencing the correct cell!

So I've tried the following last line variations without success...

Sheets("Key Stakeholders").Range("H6").Formula = "=PoC Doc Template!" & VHI_Ref

This opens the following dialogue box

    Sheets("Key Stakeholders").Range("H6").Formula = "="PoC Doc Template!" & VHI_Ref"

This gives me

    Sheets("Key Stakeholders").Range("H6").Formula = "=""PoC Doc Template!"" & VHI_Ref"

This puts the below text in H6

 

[nalij_bond]

Another option, sticking more to native vba methods might be

Sub Test4()
  Dim VHI_Ref As Range
 
  Set VHI_Ref = Sheets("PoC Doc Template").Rows(10).Find(What:="VHI PMO/GTM", LookIn:=xlValues, LookAt:=xlWhole)
  Sheets("Key Stakeholders").Range("H6").FormulaR1C1 = "='PoC Doc Template'!R12C" & VHI_Ref.Column
End Sub

Not all heroes wear capes!!! Thank you sincerely!!!

 

[Peter_SSs]

Glad the last one worked for you. Thanks for the confirmation.

Just to be complete, the previous 'Evaluate' code should work too. However, there should be single quotes around the worksheet name in that error line. You had the single quotes in your original code, which was correct. The suggestion to remove them was incorrect. Try this

Sub test5()
  'In the PoC Doc Template, use the address function to find the cell reference column in row 10.
  'for the term "VHI PMO/GTM". Then in the Sheet 'Key Stakeholders' in cell H6, use the cell
  'reference found and append to the formula'
  
  Dim VHI_Ref
  
  VHI_Ref = Evaluate("ADDRESS(12,MATCH(""VHI PMO/GTM"",'PoC Doc Template'!10:10,0))")

  Sheets("Key Stakeholders").Range("H6").Formula = "='PoC Doc Template'!" & VHI_Ref

End Sub