Opening Google Maps In Street View Instead of Layers View

[BrianExcel]

I have the following code which opens Google Maps and navigates to the latitude & longitude specified:

Sub CommandButton1_Click()
Dim chromePath As String

chromePath = """C:\Program Files\Google\Chrome\Application\chrome.exe"""
      
Shell (chromePath & " -url http://www.google.com/maps/place/" & UserForm1.txtLatitude & "," & UserForm1.txtLongitude), vbMaximizedFocus
  
End Sub

This code is working fine, except that it's opening in the generic "layers" view instead of "Satellite" view where you can see trees, buildings, etc. Actual textures.

Does anyone know of a way to open Google Maps in Satellite view?

Bonus Points: I would actually rather grab a screen shot of the map (in satellite view) and paste it into a frame in a userform if possible rather than opening a Chrome Window and finding the location, but I'll take what I can get....

Thanks!

 

[Jimmypop]

I got something very close to work....

Instead of using the image control, I am using the web browser control with the following code:

.WebBrowserMap.Navigate2 "https://www.google.com/maps/@" & .txtLatitude & "," & .txtLongitude & ",17z"

It's not quite a screen shot but it's close enough...

Please share with us the entire code up to now... thanks

 

[Georgiboy]

@BrianExcel

I have been looking into this and it has given me reason to investigate further:

It works fine on my 2016 version of Excel however' it is not working in my 365 version and throwing the same error as you have described.

Are you on a MAC by any chance?

 

[Georgiboy]

I have created a work around if you would like to try, part of the issue was down to the fact that Google produces PNG files and they are not supported.

The idea is, load the png result into a chart, export the chart as jpg, load the exported file to the UF image box, delete the temp file we created.

The workaround is:
Create a sheet named "tmp"
Add a blank chart to that sheet named "Chart 1"
Hide the sheet we just created (optional)

See the below code that I have cobbled together to make the above happen:

Private Sub CommandButton1_Click()
    GoogleStaticMap Me.gPic, Me.TextBox1.Value & "," & Me.TextBox2.Value
End Sub


Sub GoogleStaticMap(oShape, sAddress As String)
    Dim sURL As String
    Dim wsTmp As Worksheet
    Dim oCht As ChartObject
    Dim tmpImage As String
    
    Set wsTmp = Sheets("tmp")
    Set oCht = wsTmp.ChartObjects("Chart 1")
    tmpImage = Environ("temp") & "\tmp.jpg"
    
    sURL = _
    "http://maps.googleapis.com/maps/api/staticmap?center=" & _
    sAddress & _
    "&maptype=hybrid" & _
    "&zoom=" & 10 & _
    "&size=" & 500 & "x" & 500 & _
    "&scale=1" & _
    "&key=API-KEY-HERE"

    With wsTmp
        With oCht.Chart
            .ChartArea.Format.Fill.UserPicture (sURL)
            .Export Filename:=tmpImage, FilterName:="JPG"
        End With
    End With
            
    oShape.Picture = LoadPicture(tmpImage)
    Kill (tmpImage)
End Sub

Couple of notes about the code above:
Me.gPic is the image box on the UF named: gPic
Me.TextBox1.Value is the lat
Me.TextBox2.Value is the long

Hope this helps

 

[Georgiboy]

I got something very close to work....

Instead of using the image control, I am using the web browser control with the following code:

.WebBrowserMap.Navigate2 "https://www.google.com/maps/@" & .txtLatitude & "," & .txtLongitude & ",17z"

It's not quite a screen shot but it's close enough...

That may also work with the static maps url?

I am not able to use active x where i am set up at the moment as it has been blocked by IT