Opciones para cerrar

[ColdGeorge]

Hola amigos

Estoy buscando ofrecer al usuario opciones para 1) cancelar el proceso, 2) cerrar su archivo y conservar Excel abierto, y 3) cerrar su archivo y Excel, por alguna razón no logro conseguirlo, esto es lo que llevo, cualquier ayuda se agradecerá.

Private Sub Workbook_BeforeClose(Cancel As Boolean)
If MsgBox("¿Quieres cerrar el archivo?", vbYesNo, "Por favor confirma") = vbNo Then
    Cancel = True
    Exit Sub
        ElseIf MsgBox("¿Quieres cerrar Excel?", vbYesNo, "Confirma") = vbNo Then
            Cancel = True
            Exit Sub
            Application.ThisWorkbook.Close
                Else
                Application.Quit
End If
End Sub

Saludos, ColdGeorge

 

[ColdGeorge]

Sólo para estar seguro, usted tiene el código exacto del mensaje # 5? Y cuando presiona "sí" o "no" a la segunda pregunta, sucede lo mismo, o recibe las dos acciones correctas, sólo por la respuesta equivocada?


Si es sólo para la respuesta equivocada, puede cambiar a vbYes a vbNo y debería funcionar.

Hola Eric
Edité el código y ahora probé el siguiente:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
If MsgBox("¿Quieres cerrar el archivo?", vbYesNo, "Por favor confirma") = vbNo Then
    Cancel = True
    Exit Sub
End If
   
ThisWorkbook.Saved = True
    If MsgBox("¿Quieres cerrar Excel?", vbYesNo, "Confirma") = vbNo Then Application.Quit
End Sub

Resumiendo, al presionar el botón cerrar, aparece la primera pregunta, ¿quieres cerrar el archivo?, al presionar NO, no sucede nada, al presionar SÍ, aparece la segunda pregunta, ¿quieres cerrar Excel?, al presionar NO, se cierra Excel y consecuentemente el archivo, al presionar SÍ, se cierra Excel y consecuentemente el archivo.

Ya no sé que hacer, ColdGeorge.

 

[Eric W]

Creo que finalmente me di cuenta de lo que está pasando. Al cerrar el archivo, usted está usando la X roja en la esquina superior derecha de la ventana. Eso es en realidad el botón "cerrar la aplicación", no el botón "Cerrar archivo". Excel intenta cerrar primero el archivo, por lo que el código se ejecuta BeforeClose, pero después de que se ejecuta, a continuación, la aplicación se cerrará. Las versiones anteriores de Excel tenían 2 botones X, una para el archivo, uno para la aplicación.

En primer lugar, cambiar la vbNo de nuevo a vbYes (el código de puesto 4 #). Ahora cuando se cierra el archivo, si hace clic en Archivo> Cerrar en la barra de menús, el código debería funcionar como se esperaba.

También puede agregar "Archivo> Cerrar" para la "barra de acceso rápido" (QAT), por lo que tiene una forma de cerrar el archivo con un solo clic.

Voy a experimentar con el código para ver si hay una manera para que funcione como usted desee utilizando la X superior derecha, pero no soy demasiado optimista.

 

[ColdGeorge]

Creo que finalmente me di cuenta de lo que está pasando. Al cerrar el archivo, usted está usando la X roja en la esquina superior derecha de la ventana. Eso es en realidad el botón "cerrar la aplicación", no el botón "Cerrar archivo". Excel intenta cerrar primero el archivo, por lo que el código se ejecuta BeforeClose, pero después de que se ejecuta, a continuación, la aplicación se cerrará. Las versiones anteriores de Excel tenían 2 botones X, una para el archivo, uno para la aplicación.

En primer lugar, cambiar la vbNo de nuevo a vbYes (el código de puesto 4 #). Ahora cuando se cierra el archivo, si hace clic en Archivo> Cerrar en la barra de menús, el código debería funcionar como se esperaba.

También puede agregar "Archivo> Cerrar" para la "barra de acceso rápido" (QAT), por lo que tiene una forma de cerrar el archivo con un solo clic.

Voy a experimentar con el código para ver si hay una manera para que funcione como usted desee utilizando la X superior derecha, pero no soy demasiado optimista.

Hola de nuevo Eric

Probé el código siguiente, sin hacer ningún cambio.

Private Sub Workbook_BeforeClose(Cancel As Boolean)


If MsgBox("¿Quieres cerrar el archivo?", vbYesNo, "Por favor confirma") = [B][COLOR=#ff0000]vbNo [/COLOR][/B]Then
    Cancel = True
    Exit Sub
End If
   
ThisWorkbook.Saved = True
    If MsgBox("¿Quieres cerrar Excel?", vbYesNo, "Confirma") = [B][COLOR=#ff0000]vbYes [/COLOR][/B]Then Application.Quit
End Sub

Los resultados los describo a continuación, esta vez voy a Archivo, Cerrar, y se muestra la primera pregunta, al presionar NO, lo de costumbre no sucede nada, al presionar SÍ, se muestra la segunda pregunta, ¿quieres cerrar Excel? al presionar NO, se cierra el archivo (tal y como lo deseo), al presionar SÍ, se cierra el archivo y Excel.

Por un momento pensé que mi computadora estaba poseída por alguna maligna fuerza extra terrestre, ahora bien, generalmente, como yo lo hice, el usuario va a presionar la X arriba a la derecha para salir, ¿cómo deshabilito la función cerrar de la X?

Gracias Eric, saludos, ColdGeorge.

 

[Greg Truby]

Si usted está usando el código mostrado arriba, la equis roja ya debe de estar deshabilitado. Cuando un especifica vbYesNo, ese [X] está deshabilitado. Para que esté habilitado uno tiene que usar vbYesNoCancel.

 

[ColdGeorge]

Si usted está usando el código mostrado arriba, la equis roja ya debe de estar deshabilitado. Cuando un especifica vbYesNo, ese [X] está deshabilitado. Para que esté habilitado uno tiene que usar vbYesNoCancel.

Hola Greg

Gracias por tu comentario, pero entonces, mi equipo está hechizado, ya que al presionar la X, se activa el código y no debiera ser así, ahora vendría bien un aviso al presionar la X para forzar ir a Archivo, Cerrar, saludos.

ColdGeorge

 

[Greg Truby]

¡Uy! No entendí bien. Creía que usted estaba diciendo que los mensajes de sí o no estaban mostrando las equis rojas. Pues, sí, el evento de _BeforeClose se levanta al cerrar el archivo; no importa cómo.

 

[Eric W]

Greg, el problema es la diferencia entre el cierre de un archivo con el comando Archivo> Cerrar opción, o mediante el uso de la equis roja en la esquina superior derecha de Excel. Si alguien utiliza la equis roja para cerrar el archivo, a continuación, Excel se cerrará también. Eso no es lo que quiere ColdGeorge.

No sé si hay una manera de desactivar la equis, o si hay una manera en el código BeforeClose desactivar el código Application.Exit pasado de la equis.

 

[ColdGeorge]

Hola Eric y Greg

Voy a estar muy atento a sus comentarios para que me ayuden a lograr el objetivo, gracias.

ColdGeorge

 

[Greg Truby]

Gracias, Eric. Eso sí me hizo reír. Se me había olvidado por completo que Excel hace eso porque nunca cierro un cuaderno así, con tal equis, sino siempre uso Ctrl+W. Bueno, pruebe el siguiente. Me funciona, pero admito que aunque Excel permanece abierto, tengo que usar {tecla de Windows}+{flecha izquierda (o derecho)} para ajustar la ventana principal de Excel porque sale desplegado de manera muy rara.

Private Sub Workbook_BeforeClose(Cancel As Boolean)


    Static s_intCloseCount As Integer


    If s_intCloseCount <> 0 Then Exit Sub


    If MsgBox("¿Quieres cerrar el archivo?", vbYesNo, "Por favor confirma") = vbNo Then
        Cancel = True
        Exit Sub
    End If


    ThisWorkbook.Saved = True
    If MsgBox("¿Quieres cerrar Excel?", vbYesNo, "Confirma") = vbYes Then
        Application.Quit
    Else
        Cancel = True
        Let s_intCloseCount = s_intCloseCount + 1
        ActiveWindow.Close
    End If


End Sub

 

[Greg Truby]

Un poco más elegante.

Private Sub Workbook_BeforeClose(Cancel As Boolean)


    Static s_intCloseCount As Integer


    If s_intCloseCount <> 0 Then Exit Sub


    If MsgBox("¿Quieres cerrar el archivo?", vbYesNo + vbQuestion, "Por favor confirma") = vbNo Then
        Cancel = True
        Exit Sub
    End If
   
    ThisWorkbook.Saved = True
    If fnVisibleWindowCount = 1 Then
   
        If MsgBox("¿Quieres cerrar Excel?", vbYesNo + vbQuestion + vbDefaultButton2, "Confirma") = vbYes Then
            Application.Quit
        Else
            Cancel = True
            Let s_intCloseCount = s_intCloseCount + 1
            ActiveWindow.Close
        End If
    
    End If


End Sub


' _____________________________________________________________________________
' fn VISIBLE WINDOW COUNT
' ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
' Descrip:  Pretty simple - the # of visible windows
'
' Args:    [wbToCount]· · · · · count visible windows for one workbook instead
'                               of for application as a whole.
'          [booCountHidden] · · toggle to return the # of hidden windows instead
'
' Returns:  Integer · · · · · · # of visible windows
'
' Date          Developer   Comments
' ¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨¨
' 01 Nov 2009   G. Truby    • initial version very old, moved here on this date
' 15 Nov 2011   G. Truby    • added toggle
' _____________________________________________________________________________
' ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
  Function fnVisibleWindowCount(Optional ByRef wbToCount As Excel.Workbook, _
                                Optional ByVal booCountHidden As Boolean = False) _
                                As Integer
' _____________________________________________________________________________


    Dim o As Object, _
        w As Excel.Window, _
        v%
    
    If wbToCount Is Nothing Then
        Set o = Application
    Else
        Set o = wbToCount
    End If
    
    For Each w In o.Windows
        Let v = v - w.Visible           '// TRUE is (-1) in VBA
    Next w
    
    Let fnVisibleWindowCount = IIf(booCountHidden, _
                                   o.Windows.Count - v, _
                                   v)


End Function