Not able to pass variable between Modules

[jakeman]

Hi guys - I'm trying to store a variable in one module that is created by a user input box and retrieve that variable in another module, but it is not working properly. I've verified that my module is global, not specific to a sheet.

The findString variable is not passing for some reason, it keeps showing up as empty when I run Sub FindNextString.
Here is my code:

Option Explicit
Public findString, findString2 As String
Public Sub FindFirstString()
Dim findString, findString2 As String
Dim rng As Range
    
findString = InputBox("Enter the prefix of the part # you're looking for: AA or BB")
findString2 = findString & "*"

    If Trim(findString2) <> "" Then
        With Sheets("Parts").Range("A2:G500")
            Set rng = .Find(What:=findString2, _
                            After:=.Cells(.Cells.Count), _
                            LookIn:=xlValues, _
                            LookAt:=xlWhole, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlNext, _
                            MatchCase:=False)
            If Not rng Is Nothing Then
                Application.Goto rng, True
                MsgBox "Value has been found in cell: " & ActiveCell.Address
                
            Else
                MsgBox "Nothing found"
            End If
        End With
    End If

End Sub
Sub FindNextString()
Dim rng As Range

findString2 = findString & "*"

    If findString2 <> "" Then
        With Sheets("Parts").Range("A2:G500")
            Set rng = .Find(What:=findString2, _
                            After:=.Cells(.Cells.Count), _
                            LookIn:=xlValues, _
                            LookAt:=xlWhole, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlNext, _
                            MatchCase:=False)
            If Not rng Is Nothing Then
                Application.Goto rng, True
                MsgBox "Value has been found in cell: " & ActiveCell.Address
                
            Else
                MsgBox "Nothing found"
            End If
        End With
    End If

End Sub

 

[wideboydixon]

You've defined them twice; once as global and once local:

Option Explicit
Public findString, findString2 As String ' - this is global
Public Sub FindFirstString()
Dim findString, findString2 As String ' - this is local

Suggest you remove the Dim of those variables.

WBD

 

[Fluff]

Try removing

Dim findString, findString2 As String

Also on both your declarations findString is variant not string, as you have not assigned it.
Make your public like this

Public findString as String, findString2 As String

 

[Kenneth Hobson]

It "worked" for me.

1. Variable types are set each, not by the last one set in a Dim line.

Public findString$, findString2$

2. You Dimmed the two variables twice. It is redundant.
3. FindNext does not find the next one. As coded, it finds the first one.