Multi pictures insert in square shape with macro

[Programmer24]

I want to create a macro that look a specific cell and find the picture with the same name in one particular folder and insert it into a specific shape.

For exemple, I want the macro to insert the picture that is called PIC1 from the dedicated folder in the first square, the picture that is called PIC2 from the same dedicated folder in the second square and so on for as many picture as needed.

Also, I would like the macro to find them and insert them all in only one click.

Can someone help me ?

Juste give me the right structure and I'll insert my value where they belong.

 

[tonyyy]

You might consider the following...

Sub InsertPics()
Dim r As Range
Dim shp As Shape
Dim pth As String, fName As String, NotFound As String
Application.ScreenUpdating = False
pth = "C:\Docs 2021\2021 Miscellaneous\" 'Change to your folder path

For Each r In Range("A1:A" & Cells(Rows.Count, 1).End(xlUp).Row)
    If r.Value <> "" Then
        fName = Dir(pth & r.Value)
        If fName <> "" Then
            Set shp = ActiveSheet.Shapes.AddPicture(Filename:=pth & r.Value, linktofile:=msoFalse, _
                savewithdocument:=msoTrue, Left:=Cells(r.Row, 2).Left, Top:=Cells(r.Row, 2).Top, _
                    Width:=-1, Height:=-1)
            With shp
                .LockAspectRatio = msoTrue
                .Width = Columns(2).Width
                Rows(r.Row).RowHeight = .Height
            End With
        Else
            NotFound = NotFound & vbCrLf & r.Value
        End If
    End If
Next r
Application.ScreenUpdating = True
MsgBox "These pictures were not found: " & vbCrLf & NotFound
End Sub

Cheers,

Tony