Macro Recorder into VBA, Copy Paste Data Filled Cells

[beginvbaanalyst]

Hi Everyone,

I have a macro recorder file that takes a selection of data, copies, then pastes into a new sheet on ("A2:B2")
The issue is my range will always differ for my data that I copy.
I have data sets in every 4 columns ("A:D"), ("E:H") and so on but I just want the data from ("A:B"), ("E:F") to copy into my new sheet ("A2:B2") without overwriting data.
My Macro recorder code is provided below:
Sub Testcopypaste()
'
' Testcopypaste Macro
'

'
Range("A2:B27").Select 'Selection of range ("A2:B27")
Selection.Copy 'Copy Selection Above ^
Sheets("PV LIST").Select 'Make "PV LIST" Active
Range("A2").Select 'Select Cell A2 on Tab PV LIST
ActiveSheet.Paste 'Paste selection ("A2:B27") into ("A2")
Sheets("LIST").Select 'Make Sheet "LIST" active
Range("E2:F24").Select 'Select Range ("E2:F24")
Selection.Copy 'Copy Selected Range ^
Sheets("PV LIST").Select 'Make Sheet "PV LIST" Active
Range("A28").Select 'Select Cell ("A28")
ActiveSheet.Paste 'Paste Range ("E2:F24") into cell ("A28")
Sheets("LIST").Select 'Make Sheet "LIST" active
Range("I2:J30").Select 'Select Range ("I2:J30")
Selection.Copy 'Copy Selected Range ^
Sheets("PV LIST").Select 'Make Sheet "PV LIST" active
Range("A51").Select 'Select Cell ("A51")
ActiveSheet.Paste 'Paste selected Range ("I2:J30")
Sheets("LIST").Select 'Make Sheet "LIST" Active
Range("M2:N21").Select 'Select Range[Cells] ("M2:N21")
Selection.Copy 'Copy Selected Range[Cells] above ^
Sheets("PV LIST").Select 'Make Sheet "PV LIST" Active
Range("A80").Select 'Select Cell ("A80")
ActiveSheet.Paste 'Paste Selected Range ("M2:N21")
End Sub

 

[beginvbaanalyst]

How about

Sub Beginvba()
   Dim ws As Worksheet
   Dim i As Long
  
   Set ws = Sheets("PV list")
   With Sheets("List")
      For i = 1 To .Cells(2, Columns.Count).End(xlToLeft).Column Step 4
         .Range(.Cells(2, i), .Cells(Rows.Count, i).End(xlUp).Offset(, 1)).Select '.Copy ws.Range("A" & Rows.Count).End(xlUp).Offset(1)
      Next i
   End With
End Sub

Everything looks it was selecting the cells but didn't want to paste anything into the PV LISTING sheet

 

[beginvbaanalyst]

You have no headings in row 1?
Then try the following:

Sub Testcopypaste()
  Dim sh1 As Worksheet, sh2 As Worksheet
  Dim i As Long, lr1 As Long, lr2 As Long
 
  Set sh1 = Sheets("List")
  Set sh2 = Sheets("PV LIST")
  For i = 1 To sh1.Cells(2, Columns.Count).End(xlToLeft).Column Step 4
    lr1 = sh1.Range(sh1.Cells(2, i), sh1.Cells(Rows.Count, i + 1)).Find("*", , xlValues, , xlByRows, xlPrevious).Row
    lr2 = sh2.UsedRange.Rows(sh2.UsedRange.Rows.Count).Row + 1
    sh1.Range(sh1.Cells(2, i), sh1.Cells(lr1, i + 1)).Copy sh2.Range("A" & lr2)
  Next
End Sub

It looks like it's running through but nothing is pasting into the my PV LIST sheet.

 

[Fluff]

Oops, it should be

Sub Beginvba()
   Dim ws As Worksheet
   Dim i As Long
   
   Set ws = Sheets("PV list")
   With Sheets("List")
      For i = 1 To .Cells(2, Columns.Count).End(xlToLeft).Column Step 4
         .Range(.Cells(2, i), .Cells(Rows.Count, i).End(xlUp).Offset(, 1)).Copy ws.Range("A" & Rows.Count).End(xlUp).Offset(1)
      Next i
   End With
End Sub

I just had the Select for testing & forgot to remove it.

 

[beginvbaanalyst]

Oops, it should be

Sub Beginvba()
   Dim ws As Worksheet
   Dim i As Long
  
   Set ws = Sheets("PV list")
   With Sheets("List")
      For i = 1 To .Cells(2, Columns.Count).End(xlToLeft).Column Step 4
         .Range(.Cells(2, i), .Cells(Rows.Count, i).End(xlUp).Offset(, 1)).Copy ws.Range("A" & Rows.Count).End(xlUp).Offset(1)
      Next i
   End With
End Sub

I just had the Select for testing & forgot to remove it.

Now it's not selecting or copying anything. What could be the issue?
Thank you for the help!

 

[Fluff]

Do you have any data in row 2?

 

[DanteAmor]

It looks like it's running through but nothing is pasting into the my PV LIST sheet.

You can put two images, one of each sheet, where we can see the rows and columns of the sheet and the data you have on the sheets.

 

[beginvbaanalyst]

Do you have any data in row 2?

Here is a screenshot of my script:

Here is what my PV LIST looks like:

 

[Fluff]

If you select A2 on the PV List sheet & do Ctrl & down arrow, where do you endup?

 

[DanteAmor]

Sure of the name of the sheets?

 

[beginvbaanalyst]

If you select A2 on the PV List sheet & do Ctrl & down arrow, where do you endup?

oh wow,
It looks like it's pasting at line 127.
Is that because information has been filled previously on the above lines?
I'd have to hard delete and not clear contents to remove?

(EDIT) Looks like that was the issue! Thank you so much for the help!
Are you able to explain to me what each line of code does?