Looping a find window

[anichols]

Hello all,

I really haven't mastered the concept of doing a loop in VBA (seriously need to find a good resource to practice with), however, I have a code that will find a window and pull it to the foreground, but if the window doesn't exist, I want to wait for five seconds and check again, now as I safety measure, I should perhaps put a two minute limit to prompt the user to retry for another two minutes or kill the code. Any help if getting the loop setup would be appreciated.

Sub ShowIt2()
    Dim hWnd As Long
   
    hWnd = FindWindow(vbNullString, "Save As")
    If hWnd > 0 Then SetForegroundWindow hWnd
    Else
    Application.Wait (Now + TimeValue("0:0:05"))

 

[Domenic]

Maybe something like this?

Sub ShowIt2()

    Const MAX_WAIT_SECS As Long = 120
    Const WAIT_SECS As Long = 5

    Dim hWnd As Long
    Dim ans As VbMsgBoxResult
    Dim endTime As Single
  
    endTime = Timer + MAX_WAIT_SECS
  
    Do
        hWnd = FindWindow(vbNullString, "Save As")
        If hWnd > 0 Then
            SetForegroundWindow hWnd
            Exit Do
        End If
        If Timer > endTime Then
            ans = MsgBox("Window not found, try again?", vbQuestion + vbYesNo)
            If ans = vbYes Then
                endTime = Timer + MAX_WAIT_SECS
            Else
                Exit Do
            End If
        Else
            PauseMacro WAIT_SECS
        End If
    Loop

End Sub

Sub PauseMacro(ByVal secs As Long)

    Dim endTime As Single
    endTime = Timer + secs
  
    Do
        DoEvents
    Loop Until Timer > endTime
  
End Sub

 

[anichols]

That works wonderfully! thank you.

 

[Domenic]

That's great, glad I could help.

Cheers!