List boxes on user forms

[Pauljj]

I have 8 list boxes on a user form but I want to make sure that the user always selects an option in each list box, my efforts have so far failed

I initially tried by checking the list box had been selected by using...

If LB6.Value = "" Then

That didn't work, as when I stepped through the code it suggested that LB6 was 'Null'

So I changed the code to

If LB6.Value = Null Then

That then suggested LB6 was ""

So I changed it again to say

If LB6.Value = Null or LB6.Value = "" Then

But it doesn't even acknowledge it now and skips past it

Any ideas please ?

 

[Rick Rothstein]

Try testing if the ListIndex property is greater than -1 (minus one)...

If LB6.ListIndex > -1 Then
  MsgBox "Something is selected"
End If

 

[dmt32]

Hi,
try this

Function IsSelected(ByVal Form As Object) As Boolean
	Dim i As Integer
	For i = 1 To 8
		With Form.Controls("LB" & i)
			IsSelected = CBool(.ListIndex <> -1)
			If Not IsSelected Then
				MsgBox "Please Make A Selection From ListBox " & .Name, 16, "Selection Required"
				.SetFocus
				Exit Function
			End If
		End With
	Next
End Function

call from your code

If Not IsSelected(Me) Then Exit Sub

Solution assumes that your Listboxes are named LB1, LB2 etc etc.

Dave

 

[Pauljj]

Many thanks to you both, really helpful