list all unique combinations from list

[palaeontology]

I have the following dynamic list (and yes, the list can sometimes [like in this example] have some blank entries at the beginning) ...

Is there a way (either through formula or vb code .. I'm trying to avoid the need for the user to click a series of ribbon options, etc) to return a list of all possible unique combinations of letters from that list ?

For example, the unique combinations for the list above would be ....

BK
BO
KO

Note: I don't want BB, KK or OO to be returned.

Here's another example ...

This list should yield the following unique combinations ...

RG
RA
RF
RJ
GA
GF
GJ
AF
AJ
FJ

I've tried to set up a matrix solution, but not sure how to do that in excel, or even if that will return the result that I need.

I know that the number of unique combinations follows Pascal's Triangle. So ...
2 letters will have 1 possible combination
3 letters will have 3 possible combination
4 letters will have 6 possible combination
5 letters will have 10 possible combination
etc

but not sure how to use that knowledge in deriving a solution.

Any assistance would be greatly appreciated.

Very kind regards,

Chris

 

[Peter_SSs]

You're welcome.

 

[BigBeachBananas]

Another approach that you could consider.

Sub All2Combos()
  Dim a As Variant, b As Variant
  Dim i As Long, j As Long, x As Long, y As Long
 
  a = Range("A2", Range("A" & Rows.Count).End(xlUp)).Value
  ReDim b(1 To UBound(a))
  For i = 1 To UBound(a)
    If Len(a(i, 1)) > 0 Then
      x = x + 1: b(x) = a(i, 1)
    End If
  Next i
  ReDim a(1 To WorksheetFunction.Combin(x, 2), 1 To 1)
  For i = 1 To x - 1
    For j = i + 1 To x
      y = y + 1: a(y, 1) = b(i) & b(j)
    Next j
  Next i
  Range("C2").Resize(y).Value = a
End Sub

Hi, your code works wonderfully, but I'm looking for something similar but don't omit the combination if the elements are repeated. For example, I want to keep RR, GG, KK. How would I modify the code?

 

[Peter_SSs]

Hi, your code works wonderfully, but I'm looking for something similar but don't omit the combination if the elements are repeated. For example, I want to keep RR, GG, KK. How would I modify the code?

You have quoted the code from post #5. That code, modified to allow letters to be repeated would be:

Sub All2CombosWithDupes()
  Dim a As Variant, b As Variant
  Dim i As Long, j As Long, x As Long, y As Long
  
  a = Range("A2", Range("A" & Rows.Count).End(xlUp)).Value
  ReDim b(1 To UBound(a))
  For i = 1 To UBound(a)
    If Len(a(i, 1)) > 0 Then
      x = x + 1: b(x) = a(i, 1)
    End If
  Next i
  ReDim a(1 To WorksheetFunction.Combin(x + 1, 2), 1 To 1)
  For i = 1 To x
    For j = i To x
      y = y + 1: a(y, 1) = b(i) & b(j)
    Next j
  Next i
  Range("C2").Resize(y).Value = a
End Sub

My sample data and results:

BigBeachBananas.xlsm
	A	B	C
1
2			RR
3			RG
4	R		RA
5	G		RF
6	A		RJ
7	F		GG
8	J		GA
9			GF
10			GJ
11			AA
12			AF
13			AJ
14			FF
15			FJ
16			JJ
17
Sheet1