INSERTBLANKAT

[smozgur]

INSERTBLANKAT function inserts blank cells at every X row in a given range.

The mini-sheet - G:O columns - shows the steps to build the final Lambda formula.

=LAMBDA(data,atRow,
    LET(rows, ROWS(data),
        cols, COLUMNS(data),
        rowsWithBlanks, SEQUENCE(rows+rows/(atRow-1)),
        blankRow,MOD(rowsWithBlanks,atRow),
        rowIndex, rowsWithBlanks-INT(rowsWithBlanks/atRow),
        IF(blankRow,INDEX(data,rowIndex, SEQUENCE(,cols)),"")
))

INSERTATBLANK.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S
1	Field1	Field2	Field3		At Row		Rows	Cols	Rows with Blanks	0 is blank row	Row Index		Result				Lambda function
2	January	65	165		3		12	3	1	1	1		January	65	165		January	65	165
3	February	66	166						2	2	2		February	66	166		February	66	166
4	March	67	167						3	0	2
5	April	68	168						4	1	3		March	67	167		March	67	167
6	May	69	169						5	2	4		April	68	168		April	68	168
7	June	70	170						6	0	4
8	July	72	172						7	1	5		May	69	169		May	69	169
9	August	73	173						8	2	6		June	70	170		June	70	170
10	September	69	169						9	0	6
11	October	70	170						10	1	7		July	72	172		July	72	172
12	November	72	172						11	2	8		August	73	173		August	73	173
13	December	73	173						12	0	8
14									13	1	9		September	69	169		September	69	169
15									14	2	10		October	70	170		October	70	170
16									15	0	10
17									16	1	11		November	72	172		November	72	172
18									17	2	12		December	73	173		December	73	173
19									18	0	12
20
INSERTBLANKAT

Cell Formulas
Range	Formula
G2	G2	=ROWS(A2:C13)
H2	H2	=COLUMNS(A2:C13)
I2:I19	I2	=SEQUENCE(G2+G2/(E2-1))
J2:J19	J2	=MOD(I2#,E2)
K2:K19	K2	=I2#-INT(I2#/E2)
M2:O19	M2	= IF(J2#,INDEX(A2:C13,K2#, SEQUENCE(,H2)),"")
Q2:S19	Q2	=LAMBDA(data,atRow, LET(rows, ROWS(data), cols, COLUMNS(data), rowsWithBlanks, SEQUENCE(rows+rows/(atRow-1)), blankRow,MOD(rowsWithBlanks,atRow), rowIndex, rowsWithBlanks-INT(rowsWithBlanks/atRow), IF(blankRow,INDEX(data,rowIndex, SEQUENCE(,cols)),"") ))(A2:C13,E2)
Dynamic array formulas.

 

[Xlambda]

Hi Suat, great function. I like how you've built the pattern equations. Then I thought, what if we include another argument, the gap size.
And since you did it already with math expressions I chose an alternative solution, using only arrays "geometry".
Here is the concept, step by step.

Book2
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R
1	Creating rows index pattern.
2					1. grouping x-1						3 flatten exp. array		4. exclude extra rows
3	rows (r)		q=seq(r)		w=wraprows(q,x-1)						t=tocol(e)		k=take(t,xmatch(r,t))
4	20		=SEQUENCE(A4)		=WRAPROWS(C5#,A7-1)						=TOCOL(E16#)		=TAKE(K5#,XMATCH(A4,K5#))
5			1		1	2	3				1		1
6	at row (x)		2		4	5	6				2		2		5. final
7	4		3		7	8	9				3		3		=iferr(INDEX(a,k,seq(clms(a))),"")
8			4		10	11	12				#N/A		#N/A
9	gap (y)		5		13	14	15				#N/A		#N/A
10	2		6		16	17	18				4		4
11			7		19	20	#N/A				5		5
12			8								6		6
13			9		2. expanding y gap						#N/A		#N/A
14			10		e=expand(w,,x-1+y)						#N/A		#N/A
15			11		=EXPAND(E5#,,A7-1+A10)						7		7
16			12		1	2	3	#N/A	#N/A		8		8
17			13		4	5	6	#N/A	#N/A		9		9
18			14		7	8	9	#N/A	#N/A		#N/A		#N/A
19			15		10	11	12	#N/A	#N/A		#N/A		#N/A
20			16		13	14	15	#N/A	#N/A		10		10
21			17		16	17	18	#N/A	#N/A		11		11
22			18		19	20	#N/A	#N/A	#N/A		12		12
23			19								#N/A		#N/A
24			20								#N/A		#N/A
25											13		13
26											14		14
27											15		15
28											#N/A		#N/A
29											#N/A		#N/A
30											16		16
31											17		17
32											18		18
33											#N/A		#N/A
34											#N/A		#N/A
35											19		19
36											20		20
37											#N/A
38											#N/A
39											#N/A
40
Sheet1

Cell Formulas
Range	Formula
C4,E4,E15,K4,M4	C4	=FORMULATEXT(C5)
C5:C24	C5	=SEQUENCE(A4)
E5:G11	E5	=WRAPROWS(C5#,A7-1)
K5:K39	K5	=TOCOL(E16#)
M5:M36	M5	=TAKE(K5#,XMATCH(A4,K5#))
E16:I22	E16	=EXPAND(E5#,,A7-1+A10)
Dynamic array formulas.

 

[Xlambda]

The function:
INSRWS(a,x,[g]) INSert RoWS
a: array
x: at row x , integer >1
[g]: gap size, integer >0 , if omitted g=1

=LAMBDA(a, x, [g],
    LET(
        y, IF(g, g, 1),
        r, ROWS(a),
        t, TOCOL(EXPAND(WRAPROWS(SEQUENCE(r), x - 1), , x - 1 + y)),
        IFERROR(INDEX(a, TAKE(t, XMATCH(r, t)), SEQUENCE(, COLUMNS(a))), "")
    )
)

Book2
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1						x,3,g,omitted				x,4,g,omitted				x,5,g,2
2		a				=INSRWS(B3:D14,3)				=INSRWS(B3:D14,4)				=INSRWS(B3:D14,5,2)
3		January	65	165		January	65	165		January	65	165		January	65	165
4		February	66	166		February	66	166		February	66	166		February	66	166
5		March	67	167						March	67	167		March	67	167
6		April	68	168		March	67	167						April	68	168
7		May	69	169		April	68	168		April	68	168
8		June	70	170						May	69	169
9		July	72	172		May	69	169		June	70	170		May	69	169
10		August	73	173		June	70	170						June	70	170
11		September	69	169						July	72	172		July	72	172
12		October	70	170		July	72	172		August	73	173		August	73	173
13		November	72	172		August	73	173		September	69	169
14		December	73	173
15						September	69	169		October	70	170		September	69	169
16						October	70	170		November	72	172		October	70	170
17										December	73	173		November	72	172
18						November	72	172						December	73	173
19						December	73	173
20
21						x,6,g,2				x,6,g,3				x,7,g,3
22						=INSRWS(B3:D14,6,2)				=INSRWS(B3:D14,6,3)				=INSRWS(B3:D14,7,3)
23						January	65	165		January	65	165		January	65	165
24						February	66	166		February	66	166		February	66	166
25						March	67	167		March	67	167		March	67	167
26						April	68	168		April	68	168		April	68	168
27						May	69	169		May	69	169		May	69	169
28														June	70	170
29
30						June	70	170
31						July	72	172		June	70	170
32						August	73	173		July	72	172		July	72	172
33						September	69	169		August	73	173		August	73	173
34						October	70	170		September	69	169		September	69	169
35										October	70	170		October	70	170
36														November	72	172
37						November	72	172						December	73	173
38						December	73	173
39										November	72	172
40										December	73	173
41
Sheet2

Cell Formulas
Range	Formula
F2,N22,J22,F22,N2,J2	F2	=FORMULATEXT(F3)
F3:H19	F3	=INSRWS(B3:D14,3)
J3:L17	J3	=INSRWS(B3:D14,4)
N3:P18	N3	=INSRWS(B3:D14,5,2)
F23:H38	F23	=INSRWS(B3:D14,6,2)
J23:L40	J23	=INSRWS(B3:D14,6,3)
N23:P37	N23	=INSRWS(B3:D14,7,3)
Dynamic array formulas.

 

[Xlambda]

A minor note: Just noticed that your function leaves a blank last row. I thought that was a design choice, but for other values of "atRow" it doesn't happen.

Book2
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1						atRow,3				x,3
2		a				=INSERTBLANKAT(B3:D14,3)				=INSRWS(B3:D14,3)				check rows
3		January	65	165		January	65	165		January	65	165		=ROWS(F3#)
4		February	66	166		February	66	166		February	66	166		18
5		March	67	167
6		April	68	168		March	67	167		March	67	167		=ROWS(J3#)
7		May	69	169		April	68	168		April	68	168		17
8		June	70	170
9		July	72	172		May	69	169		May	69	169
10		August	73	173		June	70	170		June	70	170
11		September	69	169
12		October	70	170		July	72	172		July	72	172
13		November	72	172		August	73	173		August	73	173
14		December	73	173
15						September	69	169		September	69	169
16						October	70	170		October	70	170
17
18						November	72	172		November	72	172
19						December	73	173		December	73	173
20
21
22						atRow,6				x,6
23						=INSERTBLANKAT(B3:D14,6)				=INSRWS(B3:D14,6)				check rows
24						January	65	165		January	65	165		=ROWS(F24#)
25						February	66	166		February	66	166		14
26						March	67	167		March	67	167
27						April	68	168		April	68	168		=ROWS(J24#)
28						May	69	169		May	69	169		14
29
30						June	70	170		June	70	170
31						July	72	172		July	72	172
32						August	73	173		August	73	173
33						September	69	169		September	69	169
34						October	70	170		October	70	170
35
36						November	72	172		November	72	172
37						December	73	173		December	73	173
38
Sheet3

Cell Formulas
Range	Formula
F2,N27,N24,J23,F23,N6,N3,J2	F2	=FORMULATEXT(F3)
F3:H20	F3	=INSERTBLANKAT(B3:D14,3)
J3:L19	J3	=INSRWS(B3:D14,3)
N4,N25	N4	=ROWS(F3#)
N7,N28	N7	=ROWS(J3#)
F24:H37	F24	=INSERTBLANKAT(B3:D14,6)
J24:L37	J24	=INSRWS(B3:D14,6)
Dynamic array formulas.

 

[smozgur]

@Xlambda: I like how you used WRAPROWS and EXPAND in INSRWS. The "gap size" idea is great. Thanks for the improvement!

What I like more, seeing alternative formulas created and posted with different functions for the Lambda functions I am building. I am learning a lot. Otherwise, it is impossible to know that there is other useful functions/logic that exist to be used to do the same thing.
Another thing is, I also like creating the functions with steps by extracting each step in separate ranges and then imploding them as the actual function at the end. I understand the used functions much easier that way. Again, F9 doesn't work in LET or Lambda, anything that is calculated as a name returns #NAME? error (I understand F9 has a scope and can't see other than the selected section in a formula) and it really makes it harder to read it on the function directly.

The blank last row - if the last group had enough items, 5, then it would have also put a blank row for that too. Since there are only November and December left after the group of fives, no blank is added to the end. But I like how INSRWS works and doesn't add an extra blank at the end where it is necessary according to the logic in the initial formula. On second thought, the last blank is not that useful.