Input Box is Not working

[bobsburgers]

Hi, all -

I'm having difficulty with the second InputBox in my code.

Ideally when asked for the "Employee ID Number," the user would scan a barcode to populate a corresponding cell in Column C; however, although I can get the scanner to read and recognize the barcode on the ID cards, the ID number does not populate its respective cell.

The macro then loops back to the search function, as planned.

Here's the code I'm working with:

Sub iPad_SignOut()

    Dim scanstring As String
    Dim foundscan As Range
    Dim ws As Worksheet
    Dim foundscan_address As String
    Dim myValue As Variant
    
Set ws = ActiveSheet

scanstring = InputBox("Please enter a value to search for", "Enter value")
If scanstring = "" Then Exit Sub

With ws.Columns("A")
    
    Set foundscan = .Find(What:=scanstring, LookIn:=xlValues, LookAt:=xlWhole, _
                          SearchOrder:=xlByRows, SearchDirection:=xlNext, _
                          MatchCase:=False, SearchFormat:=False)
                      
    If Not foundscan Is Nothing Then
foundscan_address = foundscan.Address

Do
        foundscan.Offset(0, 1).Value = Now
        ws.Activate
        foundscan.Activate
        ActiveWindow.ScrollRow = foundscan.Row
        Set foundscan = .FindNext(foundscan)
        ActiveCell.Offset(0, 2).Activate
        myValue = InputBox("Please enter Employee ID Number", "Enter value")
   

Loop While Not foundscan Is Nothing And foundscan.Address <> foundscan_address
    
    
    Else
        MsgBox scanstring & "  was not found"
    End If
    
End With

    Call iPad_SignOut

End Sub

Please let me know if you can catch my mistake(s)! haha

Best,
bob

 

[wideboydixon]

You have recursion there by calling the sub again at the end. I've also refactored the code a little and indented it properly. I haven't tested this thoroughly but it seems to be working:

Sub iPad_SignOut()

Dim scanstring As String
Dim foundscan As Range
Dim ws As Worksheet
Dim foundscan_address As String
    
Set ws = ActiveSheet

Do While True
    scanstring = InputBox("Please enter a value to search for", "Enter value")
    If scanstring = "" Then Exit Do
    
    With ws.Columns("A")
        Set foundscan = .Find(What:=scanstring, LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
        If foundscan Is Nothing Then
            MsgBox scanstring & "  was not found"
        Else
            foundscan_address = foundscan.Address
            Do
                foundscan.Offset(0, 1).Value = Now
                ws.Activate
                foundscan.Activate
                ActiveWindow.ScrollRow = foundscan.Row
                ActiveCell.Offset(0, 2).Activate
                foundscan.Offset(0, 2).Value = InputBox("Please enter Employee ID Number", "Enter value")
                Set foundscan = .FindNext(foundscan)
            Loop While Not foundscan Is Nothing And foundscan.Address <> foundscan_address
        End If
    End With
Loop

End Sub

WBD

 

[bobsburgers]

Thank you so much WBD!

I've tested it with our equipment and everything seems to be working great!

Also, thank you very much for showing me a more appropriate way to go about this! I'm still learning (thanks in large part to this site! haha)

best,
bob