in power query, add a blank row with a change in value

[DrDebit]

I have a table of transactions with sales people that is cleaned and sorted so all transactions for a sales person are together in column A. In PQ, I would like to insert a blank row after each change in agent....similar to the subtotal function in Excel, except I would like to add a blank row to improve readability. Is it possible? Thank you so much in advance.

 

[XL Pro]

I know this is 3 years later, but I believe this technique would have been relevant then as it is now.
Instead of trying to null all the field values, you can use a Table.Combine() and only null 1 field as the rest of the fields will null automatically.
So, the query would look like this:

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    fnInsertNullRow = (TblRef as table) as table =>
        let     
            TblWithBlankRow =Table.Combine({TblRef, #table(List.FirstN(Table.ColumnNames(TblRef),1),{{null}})})
        in
            TblWithBlankRow,

    Grp  = Table.Group(Source, {"Name"}, {{"Tbl", each _, type table}}, GroupKind.Global),
    TransformCol = Table.TransformColumns(Table.SelectColumns(Grp, {"Tbl"}), {{"Tbl", fnInsertNullRow}}),

    FinalResult = Table.ExpandTableColumn(TransformCol, "Tbl", Table.ColumnNames(TransformCol{0}[Tbl]))

in
    FinalResult

Alternately, you could combined the blank row in the group statement, and wrap that in in the Table.SelectColumns() as such:

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    GrpInsert = Table.SelectColumns(Table.Group(Source, {"Name"}, {{"Tbl", each Table.Combine({_, #table(List.FirstN(Table.ColumnNames(_),1),{{null}})}), type table}}, GroupKind.Global),{"Tbl"}),
    ExpandeTbl = Table.ExpandTableColumn(GrpInsert, "Tbl", {"Name", "Amount"}, {"Name", "Amount"})
in
    ExpandeTbl