How would I combine these two formulas?

[Poppyrob]

I have two formulas that work. But I would like to combine them into one formula. I have tried and cannot get them nested together correctly.

=INDEX(C6:G10,XMATCH(K5,A6:A10),XMATCH(J5,C4:G4))

=INDEX(C6:G10,XMATCH(M5,A6:A10),XMATCH(L5,C4:G4))

I am using XMatch because if I use Match it will not work. I have 5 ratings, Very Low, Low, Moderate, High, Very High and if I try to match "Low" or "High" the formula will not work. I am guessing because there are other values with the same words in them and it is causing an error. If I select Very Low, Moderate, or Very High match will work.

 

[Peter_SSs]

As indicated above, one of the problems in trying to help you is that your data and layout changes with every post.
This is my best guess

24 07 27.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L
1
2		Very Low	Low	Moderate	High	Very High		Low	High	Moderate	High	Moderate
3	Very High	Low	Moderate	High	Very High	Very High		Low	Low	Moderate	High	Low
4	High	Low	Moderate	Moderate	High	Very High		Moderate	Moderate	Moderate	Moderate	Moderate
5	Moderate	Low	Low	Moderate	Moderate	High		High	Very High	Low	Moderate	Very High
6	Low	Very Low	Low	Low	Moderate	Moderate
7	Very Low	Very Low	Very Low	Low	Low	Low
Poppyrob

Cell Formulas
Range	Formula
L2:L5	L2	=INDEX(B$3:F$7,MATCH(INDEX(B$3:F$7,MATCH(H2,A$3:A$7,0),MATCH(I2,B$2:F$2,0)),A$3:A$7,0),MATCH(INDEX(B$3:F$7,MATCH(J2,A$3:A$7,0),MATCH(K2,B$2:F$2,0)),A$3:A$7,0))

 

[Poppyrob]

We can make the matrix be generic. I removed the matrix name and we just have a plain matrix.
The yellow is the index of the Likelihood. A low and low is Low.
The orange is the index of the Impact. A Moderate and High is Moderate
What I need is to get the index of the Likelihood (Low) and Impact (Moderate).

 

[Poppyrob]

That works .. Thank you!!!

 

[Peter_SSs]

That works .. Thank you!!!

You're welcome. Thanks for the follow-up.

In case it is of interest, below I have provided a slightly shorter version of the formula in column M.

24 07 27.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M
1
2		Very Low	Low	Moderate	High	Very High		Low	High	Moderate	High	Moderate	Moderate
3	Very High	Low	Moderate	High	Very High	Very High		Low	Low	Moderate	High	Low	Low
4	High	Low	Moderate	Moderate	High	Very High		Moderate	Moderate	Moderate	Moderate	Moderate	Moderate
5	Moderate	Low	Low	Moderate	Moderate	High		High	Very High	Low	Moderate	Very High	Very High
6	Low	Very Low	Low	Low	Moderate	Moderate
7	Very Low	Very Low	Very Low	Low	Low	Low
Poppyrob

Cell Formulas
Range	Formula
L2:L5	L2	=INDEX(B$3:F$7,MATCH(INDEX(B$3:F$7,MATCH(H2,A$3:A$7,0),MATCH(I2,B$2:F$2,0)),A$3:A$7,0),MATCH(INDEX(B$3:F$7,MATCH(J2,A$3:A$7,0),MATCH(K2,B$2:F$2,0)),A$3:A$7,0))
M2:M5	M2	=LET(R,B$3:F$7,H,B$2:F$2,V,A$3:A$7,INDEX(R,MATCH(INDEX(R,MATCH(H2,V,0),MATCH(I2,H,0)),V,0),MATCH(INDEX(R,MATCH(J2,V,0),MATCH(K2,H,0)),V,0)))