HOW TO CALCULATE STUDENT AGGREGATE

[peterappiahkubi]

In creating an excel app to calculate the aggregate for students in their exams as used by WAEC to determine the student aggregate in BECE . The Excel has to select Six Subjects from ine Subjects, with Four being compulsory and Two other best I want an excel formular that will add the grade value of four compulsory subjects : English, Maths, Science, Social. And then automatically select 2 other subjects from the rest with best grade value.

For Instance, If a student has the following result:
1. English - 2
2. Maths - 1
3. Science - 1
4. Social - 2
5. ICT - 3
6. BDT - 3
7. RME - 1
8. French - 2
9. Twi -

I want a formular for this calculation :
English(2)+Maths(1)+Science(1)+Social(2) and randomly select best other two subjects from the rest : RME(1)+French(2) = 10

Kindly help me.

 

[J.Ty.]

Hi,

Welcome to MrExcel forum!

I have made a simple solution, which assumes that the four compulsory subjects always come at the top of the list. If this is not the case, please let me know.

Book1
	A	B	C
1	English	2	9
2	Maths	1
3	Science	1
4	Social	2
5	ICT	3
6	BDT	3
7	RME	1
8	French	2
9	Twi
Sheet1

Cell Formulas
Range	Formula
C1	C1	=SUM(B1:B4)+SMALL(B5:B9,1)+SMALL(B5:B9,2)

 

[etaf]

randomly select best other two subjects from the rest : RME(1)+French(2) = 10

The BEST other 2 are ICT & BDT worth 3 each
English(2)+Maths(1)+Science(1)+Social(2) and randomly select best other two subjects from the rest : ICT(3)+BDT(3) = 6+ 6 = 12

Otherwise its just a random selection of the other subjects NOT the BEST other subjects

Not sure how you got 10

 

[Misca]

Welcome to the board!

You're going to need a subject table that has listed all the subjects in the first column and the type ( ie. compulsory or voluntary) in the second. Once you've created this you can write the actual formula.
I've used named ranges in my formulas to make them easier to read / understand:
The subject table is named SubjectTable.
The Subject and Grade are the columns where the calculations data is found.

=SUMPRODUCT(--(VLOOKUP(Subject,SubjectTable,2,0)="Compulsory"),Grade)
+AGGREGATE(15,6,Grade/((VLOOKUP(Subject,SubjectTable,2,0)="Voluntary")*(Grade<>"")),1)
+AGGREGATE(15,6,Grade/((VLOOKUP(Subject,SubjectTable,2,0)="Voluntary")*(Grade<>"")),2)

The whole thing looks like a nightmare but it's quite simple once you break it down to parts:

The SUMPRODUCT totals the grades for the compulsory subjects. First the VLOOKUP goes through each subject row by row and checks if the subject is marked as "Compulsory" in the subject table. This same check is used in the other parts of this formula as well.

The two AGGREGATE functions are basically the same. The only difference is the "k" value in the "SMALL" part.

The first number (15) means you're using the AGGREGATE as a SMALL function. If you want to use it as a LARGE function, change the 15 to 14.
The second number (6) means you want the AGGREGATE to ignore error values.
We're going to create errors by dividing the grades with the double check:
First there's the same VLOOKUP checking that the subject is marked as "Voluntary" in the grade table. And the second check makes sure the grade is not blank.
Excel handles blanks as zeroes in calculations and we don't want that because we're trying to find the smallest (and second smallest) grade that's not a "blank zero".
The double checks return combinations of TRUEs and FALSEs and when they're used in calculations TRUEs become ones and FALSEs become zeroes.
The divider returns a one only when both checks return TRUE. This means we're going to get lots of zeroes in the divider and whenever a value is divided with a zero, the result is an error. We've told AGGREGATE to ignore errors so the resulting values in the calculation range are the ones where the subject is voluntary and the grade is not a blank cell.

The AGGREGATE is used twice to return the smallest and the second smallest values.

 

[Dave Patton]

N.B.
Your post did not define the terms "WAEC to determine the student aggregate in BECE"
Based on your example Best is lowest number.

2 alternatives that you can try.

Aggregate_a.xlsm
	A	B	C	D
1	Type	Subject	Grade	Result
2	Compulsory	English	2
3	Compulsory	Maths	1	9
4	Compulsory	Science	1
5	Compulsory	Social	2	9
6	Other	ICT	3
7	Other	BDT	3
8	Other	RME	1
9	Other	French	2
10	Other	Twi
11
12
3b

Cell Formulas
Range	Formula
D3	D3	=SUMIFS(Grade,Type,"Compulsory")+MINIFS(Grade,Type,"Other")+MINIFS(Grade,Type,"Other",Grade,">"&MINIFS(Grade,Type,"Other"))
D5	D5	=AGGREGATE(15,6,Grade/((Type="Other")*(Grade<>"")),2)+AGGREGATE(15,6,Grade/((Type="Other")*(Grade<>"")),1)+SUMIFS(Grade,Type,"Compulsory")

Named Ranges
Name	Refers To	Cells
Grade	='3b'!$C$2:$C$10	D5, D3
Type	='3b'!$A$2:$A$10	D5, D3

 

[peterappiahkubi]

wow it worked. thanks so much

 

[peterappiahkubi]

very good. it's successful. I am grateful

 

[peterappiahkubi]

I am very grateful that all your answers given me worked.

 

[Dave Patton]

Thanks for the feedback.

Which suggestion did you decide to use?

 

[peterappiahkubi]

Thanks for the feedback.

Which suggestion did you decide to use?

=SUM(B1:B4)+SMALL(B5:B9,1)+SMALL(B5:B9,2)