How to append a number to the beginning of a spill?

[Rnkhch]

Hello,

How can I add a number to the beginning of a spill? For example, in the spill from the solution of my previous post:

How to find and spill the positions of all occurrences of a specific character in a string?

Hello, This question is related to the FIND or SEARCH functions, but both of these functions return the position of only the first occurrence of the specified character(s) in a string. But how can I get a spill of all positions if the specific character occurs more than once? For example, in...

www.mrexcel.com

I want to append a number "1" to the beginning of the spill. I tried the strategy that was used in the solution of one of my other posts below, but it doesn't work well (B3):

How to 'append' cells to a spill?

Hello, I use FILTER to get an output spill of numbers with the needed conditions, as shown in the attached XL2BB, but I was wondering if there is any way I could append the SUM of the spilled cells at the beginning of the spill, followed by the actual spill? 😂 In the example, I put the spill...

www.mrexcel.com

Blank power workbook1.xlsx
	A	B	C	D	E	F	G	H	I
1	45 , 33, A- ,17,88 , 12 ,39	15	24	36	39	46	57
2
3	My attempt:	1	24	36	39	46	57	#N/A
4
5	Desired output:	1	15	24	36	39	46	57
6
Sheet6

Cell Formulas
Range	Formula
B1:G1	B1	=LET(s, SEQUENCE(1,LEN(A1)), n, (MID(A1,s,1)=",")*s, FILTER(n,n<>0))
B3:H3	B3	=LET(x,LET(s, SEQUENCE(1,LEN(A1)), n, (MID(A1,s,1)=",")*s, FILTER(n,n<>0)),z,COUNT(x),a,TRANSPOSE(SEQUENCE(z+1)),IF(a>1,x,1))
Dynamic array formulas.

Thanks for any input!

 

[JEC]

replace the A1 in yoir formula with(both of them)

“,”&A1

 

[JEC]

=LET(s,SEQUENCE(1,LEN(A1)),N,(MID(","&A1,s,1)=",")*s,IFERROR(1/(1/(FILTER(N,N<>0)-1)),1))

 

[Fluff]

Another option

=LET(s,SEQUENCE(,LEN(A1)),n,(MID(","&A1,s,1)=",")*s,f,FILTER(n,n<>0),IF(f=1,1,f-1))

 

[Rnkhch]

Thank you both, for the solutions!!

 

[Fluff]

Glad we could help & thanks for the feedback.