Highlighting item on userform listbox without selecting it.

[Herakles]

Hi All.

Using the vertical position of the mouse pointer when hovering over a listbox and then identifying which item is selected I want to
highlight the listbox item without selecting it.

Subsequently, the user may want to click on it to invoke the click event.

Is this possible?

Thanks

 

[kevin9999]

Does this help? Highlighting Listbox Item when Mouseover on Item

 

[Jaafar Tribak]

Here is an example but don't use the Click event as it will iterfere. Instead, use the MouseDown event as follows:

UserForm Module:

Option Explicit

Private Type POINTAPI
    X As Long
    Y As Long
End Type

#If VBA7 Then
    Private Declare PtrSafe Function GetCursorPos Lib "user32.dll" (lpPoint As POINTAPI) As Long
#Else
    Private Declare Function GetCursorPos Lib "user32.dll" (lpPoint As POINTAPI) As Long
#End If

Private Sub UserForm_Initialize()
    Dim i As Long
    For i = 1& To 100&
        ListBox1.AddItem "Option " & i
    Next i
End Sub

Private Sub ListBox1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    MsgBox "You Clicked Item: '" & ListBox1.Value & "'"
End Sub

Private Sub ListBox1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    Dim tXYPos As POINTAPI, oiA As IAccessible, vKid As Variant
    If Button = 0& Then
        Set oiA = ListBox1
        Call GetCursorPos(tXYPos)
        vKid = oiA.accHitTest(tXYPos.X, tXYPos.Y)
        If VarType(vKid) <> vbEmpty Then
            ListBox1.Selected(CLng(vKid) - 1&) = True
        End If
    End If
End Sub