Get the color of a cell from its hexadecimal value

[quemuenchatocha]

Ejemplo_1.xlsm
	A	B	C	D	E	F	G	H
1	Color	Hexadecimal	Color Code	RGB	R	G	B	Name Color
2		#0048BA						Absolute Zero
3		#B0BF1A						Acid green
4		#7CB9E8						Aero
5		#C0E8D5						Aero blue
6		#B284BE						African violet
7		#72A0C1						Air superiority blue
8		#EDEAE0						Alabaster
9		#F0F8FF						Alice blue
10		#C46210						Alloy orange
11		#EFDECD						Almond
12		#E52B50						Amaranth
13		#9F2B68						Amaranth (M&P)
14		#F19CBB						Amaranth pink
15		#AB274F						Amaranth purple
16		#D3212D						Amaranth red
17		#3B7A57						Amazon
18		#FFBF00						Amber
List Of Colors

Dear Best regards, in search of your best advice I am trying to obtain a function that will allow me to get the color of a cell [A2:A975] from the hexadecimal values recorded in another cell [B2:B975]. So far I have only gotten the following basic lines:

Sub SetHexCol()
Dim i As Integer, LastRow As Integer
LastRow = Range("B" & Rows.Count).End(xlUp).Row
For i = 2 To LastRow
    Cells(i, "A").Interior.Color = HexToRgb(Cells(i, "B"))
Next
End Sub

Function HexToRgb(HexColor As String) As Long
Dim R As String, G As String, B As String
HexColor = Replace(HexColor, "#", "")
R = CLng("&H" & Left(HexColor, 2))
G = CLng("&H" & Mid(HexColor, 3, 2))
B = CLng("&H" & Right(HexColor, 2))
HexToRgb = rgb(R, G, B)
End Function

My idea is that regardless of the cell where the hexadecimal value is located (not just in column B for my case), the function will allow me to fill a cell with the color resulting from the six-character string given to the function.

Thanking you for your valuable help and suggestions to obtain the desired result, I say goodbye

 

[Fluff]

If you are just looking to get the long & rgb values for the hex string, have a look here Convert color codes (RGB, HSL, Hex, Long, CMYK) - Excel Off The Grid

 

[quemuenchatocha]

In that case I don't understand what you are asking for. The code you supplied applies the relevant colour to col A based on the Hex code in col B

No, what I am really looking for is a function that allows me to fill the color of a cell from its hexadecimal value.

The lines I have so far allow me to do this but not directly through a UDF, but through a sub()

What I'm looking for is something similar to a function like this one (Change a cell's background color dynamically according to a RGB value stored in other cells), but instead of using the RGB values, I will use the hexadecimal values recorded, in the case of my example, in column "B", to obtain the background color of a cell [column "A"].

Basically I am trying to change the background color of a cell [column A] dynamically, from a hexadecimal value stored in another cell [column B], but from the use of a UDF.

Excuse me if I have not been very clear from the beginning, I tried to save text so as not to extend so much when I asked the question.

 

[Fluff]

Ok, how about

Function ColourCell(HexColor As String)
Dim R As String, G As String, B As String, x
HexColor = Replace(HexColor, "#", "")
HexColor = Right("000000" & HexColor, 6)
R = Left(HexColor, 2)
G = Mid(HexColor, 3, 2)
B = Right(HexColor, 2)
Clr = Application.Hex2Dec(B & G & R)
x = Evaluate("cellcolour(" & Application.ThisCell.Address & "," & Clr & ")")
ColourCell = ""
End Function
Function CellColour(Cl As Range, Clr As Variant)
Cl.Interior.Color = Clr
End Function

 

[quemuenchatocha]

Dear @Fluff , I want to tell you that you are a genius, you got it right, that's really what I was looking for. Excuse me if I wasn't very clear at first, but I didn't want to be so long explaining the procedure which would imply the use of a lot of text in the message.
Thank you very much for your patience and valuable help, and as always be attentive to resolve the doubts of users.
Once again I thank you for your collaboration, a big hug.

 

[Fluff]

You're welcome & thanks for the feedback.

 

[ateeqsindhu]

Dear @Fluff , I want to tell you that you are a genius, you got it right, that's really what I was looking for. Excuse me if I wasn't very clear at first, but I didn't want to be so long explaining the procedure which would imply the use of a lot of text in the message.
Thank you very much for your patience and valuable help, and as always be attentive to resolve the doubts of users.
Once again I thank you for your collaboration, a big hug.

dear can u share me the file/sheet where you applied this cell coloring VBA Code as i am also trying to apply the code but its not working with me.