Formula or Code for writing the difference between the 2 highest number

[carole CD]

Good afternoon

I need some help with a file (betting scores). I need a formula or some code to be able to calculate the difference between the highest score (column W) and write it in front of the highest score in column Y.
But on the same page I have the different race (can be 7 or 15)I have empty rows between the races. If you do a code a need to go through every sheet in the workbook.
I have tried few thing but my code always come back like it's done nothing and my formula work if I give a range but I can not change all the time (daily file).

 

[Akuini]

First column (with the word Tab) is in col A and Points Total is in col W, correct?
Try this:

Sub caroleCD_1()
Dim c As Range, f As Range, g As Range
Dim k As Long, h1 As Double, h2 As Double
Dim sAddress As String
Dim ws As Worksheet
Application.ScreenUpdating = False
 
For Each ws In ThisWorkbook.Worksheets  'If you do a code a need to go through every sheet in the workbook.
    ws.Activate
    With Range("A:A")
        Set c = .Find(What:="Tab", LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, _
        SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
        If Not c Is Nothing Then
            sAddress = c.Address
            Do
               k = c.End(xlDown).Row
               Set f = Range(Cells(c.Row + 1, "W"), Cells(k, "W"))
               h1 = WorksheetFunction.Large(f, 1)
               h2 = WorksheetFunction.Large(f, 2)
               '=INDEX(K:K,MATCH(LARGE(L:L,1),L:L,FALSE),1)
    '           Debug.Print h1 & " : " & h2
               For Each g In f
                    If g = h1 Then g.Offset(, 2) = h1 - h2
               Next
               
               Set c = .FindNext(c)
            Loop While Not c Is Nothing And c.Address <> sAddress
        End If
    
    End With
Next
Application.ScreenUpdating = True
End Sub

carole CD 1.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA
1																						DOD	Points Total	No of 3's	High Pts Gap	Previous Form Points	Class
2	1		AMELIA PARK PLATE [80,000]
3			Type : 2 OPEN
4	11:59		1000m, TURF S(7)
5
6	Tab	Form L3	Wgt	Horse	BP	Jockey	Trainer
7	1	3x1	58.0	WEST STAR	5	CHRIS PARNHAM	S MILLER															-8	35	11	18	3	3
8	2	45x	58.0	BRAZEN BID	1	B PARNHAM	S MILLER															0	17	3		0	1
9	3	0x	56.0	SOUTHERN SCANDAL	2	W PIKE	DANIEL & BEN PEARCE															0	15	4		0	1
10	4	8	56.0	COONDLE	4	J WHITING	LOU LUCIANI
11	5	-	56.0	CAPORETTO	6	LUKE CAMPBELL (a2)	N PARNHAM															0	8	3		0	1
12	6	-	56.0	SALSA SMASH	4	J BROWN	J TAYLOR															0	9	2		0	1
13	7	-	54.0	FAVOURITE SONGS	3	JADE MC NAUGHT	LUKE FERNIE															0	6	2		0	1
14
15
16
17	2		BISLEY WORKWEAR HANDICAP [80,000]
18			Type : 2U BM78+
19	12:34		1000m, TURF S(7)
20
21	Tab	Form L3	Wgt	Horse	BP	Jockey	Trainer
22	1	846	59.0	BEADS	1	P HARVEY	S WOLFE															4	22	5		1	1
23	2	41x	58.0	YONGA LASS	7	W PIKE	G & A WILLIAMS															0	19	3		0	1
24	3	9x1	57.0	CASH AWAY	6	HOLLY WATSON	MISTY BAZELEY															2.5	26	7		3	2
25	4	17x	57.0	RUSSIAN TO THE BAR	5	CHRIS PARNHAM	LUKE FERNIE															0	20	4		0	1
26	5	90x	56.0	EEYORE WAYZ	4	P CARBERY	RAQUEL REID															0	18	5		0	1
27	6	x32	55.0	GODDESS OF GIVING	2	J WHITING	LOU LUCIANI															1.5	29	6	3	2	1
28	7	69x	55.0	TOP OF THE POPS	3	B PARNHAM	C & M GANGEMI															0	21	4		0	1
29
30
31
32	3		NATIONAL PUMP AND ENERGY HANDICAP [60,000]
33			Type : 2U 1MW
34	13:09		1000m, TURF S(7)
35
36	Tab	Form L3	Wgt	Horse	BP	Jockey	Trainer
37	1	25x	60.0	BAYEZID	2	MADI DERRICK (a1.5)	T ROBERTSON															0	25	6		0	1
38	2	421	59.0	CAPRE OMNIA	5	S PARNHAM	DYLAN BAIRSTOW															1.5	24	5		3	1
39	3	51x	58.5	BERBERE	4	W PIKE	G & A WILLIAMS															0	28	8	2	0	1
40	4	67x	57.5	OUR ROCKY BAY	3	B LOUIS	T MARTINOVICH															0	13	3		0	1
41	5	178	57.0	BARNEY'S WORLD	8	CHRIS PARNHAM	LUKE FERNIE															-0.5	26	6		1	2
42	6	x58	56.5	LITTLE STRAWBERRY	6	HOLLY WATSON	MITCHELL PATEMAN															3	19	4		1	1
43	7	65x	56.5	MISS DRAKOVA	7	B PARNHAM	N PARNHAM															0	20	4		0	1
44	8	0x6	56.5	ON THE FULL	1	LAQDAR RAMOLY	J TAYLOR															5	24	6		1	1
Sheet2

 

[carole CD]

You are magical!! thanks

 

[Akuini]

You're welcome, glad to help & thanks for the feedback.