Filter data in listbox on form based on matching part of item in two comboboxes

A

Ali M

Active Member
Joined
Oct 10, 2021
Messages
304
Office Version
  1. 2019
  2. 2013
Platform
  1. Windows
Hello
I search for codes in this forum but I don't find what I want .
so I have many sheets contains items in column C,D theses standers to match with combobox1,2
pp.xlsm
ABCDE
1DATECLIENT NAMEINFORMATIONTYP OF PAYINGTOTAL
201/01/2024ALISALES INVOICE NO SAL2333CASH IN NO CS200010,000.00
301/01/2024ALISALES INVOICE NO SAL2333CASH IN NO CS200010,000.00
402/01/2024ALISALES INVOICE NO SAL2334BANK IN NO BC20022320,000.00
502/01/2024ALISALES INVOICE NO SAL2334BANK IN NO BC20022320,000.00
605/01/2024OMARBUYING INVOICE NO BU23323BANK OUT NO BC20022430,000.00
705/01/2024OMARBUYING INVOICE NO BU23323BANK OUT NO BC20022430,000.00
805/01/2024OMARBUYING INVOICE NO BU23323BANK OUT NO BC20022430,000.00
908/01/2024ALISALES INVOICE NO SAL2335 DEFERRED PAYMENT NO BDF200015,000.00
1009/01/2024OMARBUYING INVOICE NO BU23324PUT OFF PAYMENT PFP NO R7000 10,000.00
1109/01/2024OMARBUYING INVOICE NO BU23324PUT OFF PAYMENT PFP NO R7000 10,000.00
1211/01/2024OMAIRSALES RETURNS INVOICE NO ST21233BANK OUT NO BC200224410,000.00
1311/01/2024OMAIRSALES RETURNS INVOICE NO ST21233BANK OUT NO BC200224410,000.00
1413/01/2024OMARBUYING RETURNS INVOICE NO SP23366BANK IN NO BC2002255430,000.00
1513/01/2024OMARBUYING RETURNS INVOICE NO SP23366BANK IN NO BC2002255430,000.00
1613/01/2024OMARBUYING RETURNS INVOICE NO SP23366BANK IN NO BC2002255430,000.00
1714/01/2024OMARBUYING INVOICE NO BU23325CASH OUT NO BC2002252,000.00
1814/01/2024OMARBUYING INVOICE NO BU23325CASH OUT NO BC2002252,000.00
1913/01/2024OMARBUYING RETURNS INVOICE NO SP23367CASH IN NO CS20022322230,000.00
SDR


pp.xlsm
ABCDE
1DATECLIENT NAMEINFORMATIONTYP OF PAYINGTOTAL
211/01/2024ALIBUYING INVOICE NO BU23444PUT OFF PAYMENT PFP NO R7001 7,000.00
311/01/2024ALIBUYING INVOICE NO BU23444PUT OFF PAYMENT PFP NO R7001 6,000.00
411/01/2024ALIBUYING INVOICE NO BU23444PUT OFF PAYMENT PFP NO R7001 20,000.00
511/01/2024ALIBUYING INVOICE NO BU23444PUT OFF PAYMENT PFP NO R7001 20,000.00
612/01/2024OMARSALES INVOICE NO SAL2334565DEFERRED PAYMENT NO BDF20013,000.00
712/01/2024OMARSALES INVOICE NO SAL2334565DEFERRED PAYMENT NO BDF20012,000.00
812/01/2024OMARSALES INVOICE NO SAL2334565DEFERRED PAYMENT NO BDF20012,300.00
912/01/2024OMARSALES INVOICE NO SAL2334565DEFERRED PAYMENT NO BDF20011,200.00
1012/01/2024OMARSALES INVOICE NO SAL2334565DEFERRED PAYMENT NO BDF20011,400.00
1113/01/2024OMARSALES RETURNS INVOICE NO ST2123113BANK OUT NO BC2002244111,000.00
1213/01/2024OMARSALES RETURNS INVOICE NO ST2123113BANK OUT NO BC2002244111,200.00
1313/01/2024OMARSALES RETURNS INVOICE NO ST2123113BANK OUT NO BC200224411400.00
1413/01/2024OMARSALES RETURNS INVOICE NO ST2123113CASH OUT NO CS200224411130,000.00
FMR


pp.xlsm
ABCDE
1DATECLIENT NAMEINFORMATIONTYP OF PAYINGTOTAL
211/01/2024OMRANBUYING INVOICE NO BU2332411PUT OFF PAYMENT PFP NO R70011 10,000.00
311/01/2024OMRANBUYING INVOICE NO BU2332411PUT OFF PAYMENT PFP NO R70011 10,000.00
412/01/2024OMRANBUYING LOW INVOICE NO LU2332411BANK IN NO BC2002231111,200.00
512/01/2024OMRANBUYING LOW INVOICE NO LU2332411BANK IN NO BC2002231118,000.00
612/01/2024OMRANBUYING LOW INVOICE NO LU2332411BANK IN NO BC200223111900.00
713/01/2024OMRANEXPENSES INVOICE NO EX23323BANK OUT NO BBC200224112,000.00
813/01/2024OMAREXPENSES INVOICE NO EX23324BANK OUT NO BBC20022422,000.00
914/01/2024ALISALES LOW INVOICE NO LAL233511BANK OUT NO BSABC20022431115,000.00
1014/01/2024OMARSALES RETURNS INVOICE NO ST1221233DEFERRED PAYMENT NO BDF20011010,000.00
1114/01/2024OMAIRSALES RETURNS INVOICE NO ST1221233DEFERRED PAYMENT NO BDF20011010,000.00
1214/01/2024OMAIRSALES RETURNS INVOICE NO ST1221233DEFERRED PAYMENT NO BDF20011010,000.00
1314/01/2024ALISALES LOW INVOICE NO LAL233511CASH OUT NO CS20345780015,000.00
1415/01/2024OMARSALES INVOICE NO SAL2334565CASH IN NO CS6000011,400.00
BR


combobox1,2 as show
CB1.PNG


CB2.PNG


I would filter data based on many cases
the part of item in combobox1 will match with column C, part of item in combobox2 will match with column D and textbox1,textbox2 will match dates within column A
so here is cases
case1
CM1.PNG


CASE2
CM2.PNG




CASE3



CM2.PNG


CASE4
CM3.PNG



CASE5
CM4.PNG


CASE6
CM5.PNG

should populate data in list box across sheets and insert TOTAL ro in listbox to sum whole column contains amount.
I will add new items for each sheet , data about 6500 rows for each sheet.
thanks
 

Excel Facts

Which Excel functions can ignore hidden rows?
The SUBTOTAL and AGGREGATE functions ignore hidden rows. AGGREGATE can also exclude error cells and more.
Sort by date Sort by votes
Ali M said:
I would filter data based on many cases
the part of item in combobox1 will match with column C
Click to expand...
The items BUYING and SALES are ambiguous, since in SALES it is in "SALES RETURNS", "SALES INVOICE" and it is also in "SALES LOW", that means that when you choose "SALES" it will show you those 3 concepts, which includes "SALES LOW". For you to consider.
Note: If you need "SALES LOW" not to appear when you select "SALES", you should have commented on it in your OP. So you'll have to clarify it in another thread.

Having said the above.

I ran tests with 7500 records on each sheet.
Each query takes less than a second to complete.

Try the following code in your userform:

VBA Code: 
Option Explicit

Dim a As Variant

Sub FilterData()
  Dim cmb1 As Variant, cmb2 As Variant, txt1 As String, txt2 As String
  Dim i As Long, j As Long, k As Long
  Dim b As Variant, c As Variant
  Dim tot As Double
  
  ListBox1.Clear
  tot = 0
  ReDim b(1 To UBound(a, 1) + 1, 1 To 5)
  For i = 1 To UBound(a)
    If ComboBox1.Value = "" Then cmb1 = a(i, 3) Else cmb1 = ComboBox1.Value
    If ComboBox2.Value = "" Then cmb2 = a(i, 4) Else cmb2 = ComboBox2.Value
    
    If TextBox1.Value <> "" And TextBox2.Value <> "" Then
      txt1 = checkDate(TextBox1.Value, a(i, 1))
      txt2 = checkDate(TextBox2.Value, a(i, 1))
    Else
      txt1 = a(i, 1)
      txt2 = a(i, 1)
    End If
    
    If a(i, 3) Like cmb1 & "*" And a(i, 4) Like cmb2 & "*" And _
       a(i, 1) >= CDate(txt1) And a(i, 1) <= CDate(txt2) Then
      k = k + 1
      b(k, 1) = Format(a(i, 1), "dd/mm/yyyy")
      b(k, 2) = a(i, 2)
      b(k, 3) = a(i, 3)
      b(k, 4) = a(i, 4)
      b(k, 5) = Format(a(i, 5), "#,##0.00;-#,##0.00;")
      tot = tot + a(i, 5)
    End If
  Next
  k = k + 1
  b(k, 1) = "TOTAL"
  b(k, 5) = Format(tot, "#,##0.00;-#,##0.00;")
  
  ReDim c(1 To k, 1 To 5)
  For i = 1 To k
    For j = 1 To 5
      c(i, j) = b(i, j)
    Next
  Next
  ListBox1.List = c
End Sub

Function checkDate(valText, fec)
  If valText = "" Or Not IsDate(valText) Or Len(valText) <> 10 Or _
     Mid(valText, 3, 1) <> "/" Or Mid(valText, 6, 1) <> "/" Then
    checkDate = fec
  Else
    checkDate = valText
  End If
End Function

Private Sub ComboBox1_Change()
  If ComboBox1.ListIndex = -1 Then Exit Sub
  Call FilterData
End Sub

Private Sub ComboBox2_Change()
  If ComboBox2.ListIndex = -1 Then Exit Sub
  Call FilterData
End Sub

Private Sub TextBox1_Change()
  With TextBox1
    If .Value = "" Or Not IsDate(.Value) Or Len(.Value) <> 10 Or _
     Mid(.Value, 3, 1) <> "/" Or Mid(.Value, 6, 1) <> "/" Then
    Else
      If TextBox2.Value <> "" Then
        Call FilterData
      End If
    End If
  End With
End Sub

Private Sub TextBox2_Change()
  With TextBox2
    If .Value = "" Or Not IsDate(.Value) Or Len(.Value) <> 10 Or _
     Mid(.Value, 3, 1) <> "/" Or Mid(.Value, 6, 1) <> "/" Then
    Else
      If TextBox2.Value <> "" Then
        Call FilterData
      End If
    End If
  End With
End Sub

Private Sub UserForm_Initialize()
  Dim itm As Variant, b As Variant, arr As Variant
  Dim lr As Long, i As Long, j As Long, k As Long
  arr = Array("SDR", "FMR", "BR")
  For Each itm In arr
    lr = lr + Sheets(itm).Range("A" & Rows.Count).End(3).Row - 1
  Next
  ReDim a(1 To lr, 1 To 5)
  
  For Each itm In arr
    b = Sheets(itm).Range("A2", Sheets(itm).Range("E" & Rows.Count).End(3)).Value
    For i = 1 To UBound(b, 1)
      k = k + 1
      For j = 1 To UBound(b, 2)
        a(k, j) = b(i, j)
      Next
    Next
  Next
  
  With ListBox1
    .RowSource = ""
    .ColumnCount = 5
  End With
  
  Call FilterData
End Sub

🧙‍♂️
 
Upvote 0
Thanks Dante for the code and your time to write this code for me.:)
The items BUYING and SALES are ambiguous, since in SALES it is in "SALES RETURNS", "SALES INVOICE" and it is also in "SALES LOW", that means that when you choose "SALES" it will show you those 3 concepts, which includes "SALES LOW". For you to consider.
Click to expand...
I expect to say that .

I'm not sure if the excel can do that as I posted . in my mind match whole items in combobox with columns without effect after matching when repeat the same part of the item is existed with the others.

example: SALES RETURNS will just show data for these words without show data for items contains SALES : when show data for SALES RETURNS it must search for two words together ignore every individual word
when search for SALES word then will show based on this word because contains one part
SALES RETURNS : will show based on theses words together ignoring data for SALES ,SALES LOW
SALES LOW :will show based on theses words together ignoring data for SALES ,SALES RETURNS.
so if you have any simple idea to do that I accept that.
 
Upvote 0
Ali M said:
Thanks Dante for the code and your time to write this code for me
Click to expand...
Did you try the code?

In the code You have individual filters by combo, combined filters of combos, individual filters of dates and combined filters of combos and dates. And it works for more than 6000 records on 3 sheets.
That's what you asked for.

What you asked for was this:
Ali M said:
the part of item in combobox1 will match with column C
Click to expand...

If you select "SALES"
Obviously SALES, SALES low and SALES return, contain the word SALES.

What you didn't ask for is if you select SALES, exclude records containing "SALES LOW" and also exclude "SALES RETURN". Can I explain?

Since you did not request it in your OP that is why it is not considered.

I would like you to review the code with what you did ask for.
If it doesn't work for what you asked for, then you just throw it away.

But if it works for what you asked for, I would like you to comment on it.

And as I already told you, for what you didn't ask for, create a new thread and explain in detail what you want to include and what you want to exclude.

----- --
I hope to hear from you soon.
Respectfully
Dante Amor
----- --
 

Attachments

  • 1729088232666.png
    1729088232666.png
    18.8 KB · Views: 0
Upvote 0
Did you try the code?
Click to expand...
Surely yes.:)
That's what you asked for.
Click to expand...
based on pictures of course not !
see the picture 3 for userform when I select SALES
it doesn't contain SALES RETURNS ,SALES LOW
you didn't ask me why SALES RETURNS ,SALES LOW don't show in the picture 3 for the form !
What you asked for was this:
Click to expand...
Ali M said:
the part of item in combobox1 will match with column C
Click to expand...
what I meant the item in combobox match with part of item in column C because of contains items after target item for matching .
What you didn't ask for is if you select SALES, exclude records containing "SALES LOW" and also exclude "SALES RETURN". Can I explain?
Click to expand...
when select SALES LOW
AS1.PNG



when select SALES RETURNS
AS2.PNG



the same thing for BUYING,BUYING RETURNS,BUYING LOW
 
Upvote 0
Ali M said:
Surely yes.:)
Click to expand...
Any comment about that. Or you're just going to judge my work by what you don't have and not by what you do have.

Ali M said:
you didn't ask me why SALES RETURNS ,SALES LOW don't show in the picture 3 for the form !
Click to expand...
I don't think it's my fault. I'm trying to help you. If you don't see it that way, then you can throw my effort away.

I suggest that you be more specific when you have an ambiguity in your information.
 
Upvote 0
Any comment about that
Click to expand...
I Answered you .
based on pictures of course not !
Click to expand...
Or you're just going to judge my work by what you don't have and not by what you do have.
Click to expand...
no this is not like that as you think .
I don't think it's my fault
Click to expand...
I don't blame you for that, sorry if you think that !

I'm trying to help you.
Click to expand...
always you're welcome.

If you don't see it that way, then you can throw my effort away
Click to expand...
it's really close !
I suggest that you be more specific when you have an ambiguity in your information.
Click to expand...
I thought the pictures reflect my requirements , sorry!
 
Upvote 0
VBA Code: 
Option Explicit

Dim a As Variant

Sub FilterData()
  Dim cmb1 As Variant, cmb2 As Variant, txt1 As String, txt2 As String
  Dim i As Long, j As Long, k As Long, m As Long, LItm As Long
  Dim b As Variant, c As Variant, itm As Variant
  Dim tot As Double
  Dim bExclude As Boolean
  
  ListBox1.Clear
  tot = 0
  ReDim b(1 To UBound(a, 1) + 1, 1 To 5)
  For i = 1 To UBound(a)
    If ComboBox1.Value = "" Then cmb1 = a(i, 3) Else cmb1 = ComboBox1.Value
    If ComboBox2.Value = "" Then cmb2 = a(i, 4) Else cmb2 = ComboBox2.Value
    
    If TextBox1.Value <> "" And TextBox2.Value <> "" Then
      txt1 = checkDate(TextBox1.Value, a(i, 1))
      txt2 = checkDate(TextBox2.Value, a(i, 1))
    Else
      txt1 = a(i, 1)
      txt2 = a(i, 1)
    End If
    
    If a(i, 3) Like cmb1 & "*" And a(i, 4) Like cmb2 & "*" And _
       a(i, 1) >= CDate(txt1) And a(i, 1) <= CDate(txt2) Then
      
      bExclude = False
      For m = 0 To ComboBox1.ListCount - 1
        If m <> ComboBox1.ListIndex And ComboBox1.ListIndex <> -1 Then
          itm = Split(a(i, 3), " ")(0) & " " & Split(a(i, 3), " ")(1)
          If itm = ComboBox1.List(m) Then
              bExclude = True
              Exit For
          End If
        End If
      Next
      
      If bExclude = False Then
        k = k + 1
        b(k, 1) = Format(a(i, 1), "dd/mm/yyyy")
        b(k, 2) = a(i, 2)
        b(k, 3) = a(i, 3)
        b(k, 4) = a(i, 4)
        b(k, 5) = Format(a(i, 5), "#,##0.00;-#,##0.00;")
        tot = tot + a(i, 5)
      End If
    End If
  Next
  k = k + 1
  b(k, 1) = "TOTAL"
  b(k, 5) = Format(tot, "#,##0.00;-#,##0.00;")
  
  ReDim c(1 To k, 1 To 5)
  For i = 1 To k
    For j = 1 To 5
      c(i, j) = b(i, j)
    Next
  Next
  ListBox1.List = c
End Sub

Function checkDate(valText, fec)
  If valText = "" Or Not IsDate(valText) Or Len(valText) <> 10 Or _
     Mid(valText, 3, 1) <> "/" Or Mid(valText, 6, 1) <> "/" Then
    checkDate = fec
  Else
    checkDate = valText
  End If
End Function

Private Sub ComboBox1_Change()
  If ComboBox1.ListIndex = -1 Then Exit Sub
  Call FilterData
End Sub

Private Sub ComboBox2_Change()
  If ComboBox2.ListIndex = -1 Then Exit Sub
  Call FilterData
End Sub

Private Sub TextBox1_Change()
  With TextBox1
    If .Value = "" Or Not IsDate(.Value) Or Len(.Value) <> 10 Or _
     Mid(.Value, 3, 1) <> "/" Or Mid(.Value, 6, 1) <> "/" Then
    Else
      If TextBox2.Value <> "" Then
        Call FilterData
      End If
    End If
  End With
End Sub

Private Sub TextBox2_Change()
  With TextBox2
    If .Value = "" Or Not IsDate(.Value) Or Len(.Value) <> 10 Or _
     Mid(.Value, 3, 1) <> "/" Or Mid(.Value, 6, 1) <> "/" Then
    Else
      If TextBox2.Value <> "" Then
        Call FilterData
      End If
    End If
  End With
End Sub

Private Sub UserForm_Initialize()
  Dim itm As Variant, b As Variant, arr As Variant
  Dim lr As Long, i As Long, j As Long, k As Long
  arr = Array("SDR", "FMR", "BR")
  For Each itm In arr
    lr = lr + Sheets(itm).Range("A" & Rows.Count).End(3).Row - 1
  Next
  ReDim a(1 To lr, 1 To 5)
  
  For Each itm In arr
    b = Sheets(itm).Range("A2", Sheets(itm).Range("E" & Rows.Count).End(3)).Value
    For i = 1 To UBound(b, 1)
      k = k + 1
      For j = 1 To UBound(b, 2)
        a(k, j) = b(i, j)
      Next
    Next
  Next
  
  With ListBox1
    .RowSource = ""
    .ColumnCount = 5
  End With
  
  Call FilterData
End Sub
 
Upvote 0
VBA Code: 
Option Explicit

Dim a As Variant

Sub FilterData()
  Dim cmb1 As Variant, cmb2 As Variant, txt1 As String, txt2 As String
  Dim i As Long, j As Long, k As Long, m As Long, LItm As Long
  Dim b As Variant, c As Variant, itm As Variant
  Dim tot As Double
  Dim bExclude As Boolean
  
  ListBox1.Clear
  tot = 0
  ReDim b(1 To UBound(a, 1) + 1, 1 To 5)
  For i = 1 To UBound(a)
    If ComboBox1.Value = "" Then cmb1 = a(i, 3) Else cmb1 = ComboBox1.Value
    If ComboBox2.Value = "" Then cmb2 = a(i, 4) Else cmb2 = ComboBox2.Value
    
    If TextBox1.Value <> "" And TextBox2.Value <> "" Then
      txt1 = checkDate(TextBox1.Value, a(i, 1))
      txt2 = checkDate(TextBox2.Value, a(i, 1))
    Else
      txt1 = a(i, 1)
      txt2 = a(i, 1)
    End If
    
    If a(i, 3) Like cmb1 & "*" And a(i, 4) Like cmb2 & "*" And _
       a(i, 1) >= CDate(txt1) And a(i, 1) <= CDate(txt2) Then
      
      bExclude = False
      For m = 0 To ComboBox1.ListCount - 1
        If m <> ComboBox1.ListIndex And ComboBox1.ListIndex <> -1 Then
          itm = Split(a(i, 3), " ")(0) & " " & Split(a(i, 3), " ")(1)
          If itm = ComboBox1.List(m) Then
              bExclude = True
              Exit For
          End If
        End If
      Next
      
      If bExclude = False Then
        k = k + 1
        b(k, 1) = Format(a(i, 1), "dd/mm/yyyy")
        b(k, 2) = a(i, 2)
        b(k, 3) = a(i, 3)
        b(k, 4) = a(i, 4)
        b(k, 5) = Format(a(i, 5), "#,##0.00;-#,##0.00;")
        tot = tot + a(i, 5)
      End If
    End If
  Next
  k = k + 1
  b(k, 1) = "TOTAL"
  b(k, 5) = Format(tot, "#,##0.00;-#,##0.00;")
  
  ReDim c(1 To k, 1 To 5)
  For i = 1 To k
    For j = 1 To 5
      c(i, j) = b(i, j)
    Next
  Next
  ListBox1.List = c
End Sub

Function checkDate(valText, fec)
  If valText = "" Or Not IsDate(valText) Or Len(valText) <> 10 Or _
     Mid(valText, 3, 1) <> "/" Or Mid(valText, 6, 1) <> "/" Then
    checkDate = fec
  Else
    checkDate = valText
  End If
End Function

Private Sub ComboBox1_Change()
'  If ComboBox1.ListIndex = -1 Then Exit Sub
  Call FilterData
End Sub

Private Sub ComboBox2_Change()
'  If ComboBox2.ListIndex = -1 Then Exit Sub
  Call FilterData
End Sub

Private Sub TextBox1_Change()
  With TextBox1
    If .Value = "" Or Not IsDate(.Value) Or Len(.Value) <> 10 Or _
     Mid(.Value, 3, 1) <> "/" Or Mid(.Value, 6, 1) <> "/" Then
    Else
      If TextBox2.Value <> "" Then
        Call FilterData
      End If
    End If
  End With
End Sub

Private Sub TextBox2_Change()
  With TextBox2
    If .Value = "" Or Not IsDate(.Value) Or Len(.Value) <> 10 Or _
     Mid(.Value, 3, 1) <> "/" Or Mid(.Value, 6, 1) <> "/" Then
    Else
      If TextBox2.Value <> "" Then
        Call FilterData
      End If
    End If
  End With
End Sub

Private Sub UserForm_Initialize()
  Dim itm As Variant, b As Variant, arr As Variant
  Dim lr As Long, i As Long, j As Long, k As Long
  arr = Array("SDR", "FMR", "BR")
  For Each itm In arr
    lr = lr + Sheets(itm).Range("A" & Rows.Count).End(3).Row - 1
  Next
  ReDim a(1 To lr, 1 To 5)
  
  For Each itm In arr
    b = Sheets(itm).Range("A2", Sheets(itm).Range("E" & Rows.Count).End(3)).Value
    For i = 1 To UBound(b, 1)
      k = k + 1
      For j = 1 To UBound(b, 2)
        a(k, j) = b(i, j)
      Next
    Next
  Next
  
  With ListBox1
    .RowSource = ""
    .ColumnCount = 5
  End With
  
  Call FilterData
End Sub
 
Upvote 1
Solution
Awesome !(y)
I will choose code in post #9 this is better when clear combobox .;)
thank you so much.:)
 
Upvote 0
You must log in or register to reply here.

Similar threads

A
  • Question Question
Create report by matching part of item and populate for each cell under item across sheets
Replies
2
Views
198
Ali M
A
A
  • Solved
transpose data int listbox on userform based on two dates or without dates
Replies
2
Views
320
Alaa mg
A
M
  • Solved
How merge amounts into textbox based on two comboboxes instead of one combobox
Replies
6
Views
298
Maklil
M
O
  • Question Question
sum or subtract for the same cell based on match column between two sheets
2
Replies
13
Views
821
Omran Y
O
A
  • Solved
no experience for populate data in listbox based on selected item from another listbox
2
Replies
10
Views
448
Amer Omar
A

Forum statistics

Threads
1,222,771
Messages
6,168,137
Members
452,166
Latest member
MadDataEngineer

Share this page

We've detected that you are using an adblocker.

We have a great community of people providing Excel help here, but the hosting costs are enormous. You can help keep this site running by allowing ads on MrExcel.com.
Allow Ads at MrExcel

Which adblocker are you using?

Disable AdBlock

Follow these easy steps to disable AdBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the icon in the browser’s toolbar.
2)Click on the "Pause on this site" option.
Go back

Disable AdBlock Plus

Follow these easy steps to disable AdBlock Plus

1)Click on the icon in the browser’s toolbar.
2)Click on the toggle to disable it for "mrexcel.com".
Go back

Disable uBlock Origin

Follow these easy steps to disable uBlock Origin

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back

Disable uBlock

Follow these easy steps to disable uBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back
Back
Top