Filter by Designated Criteria

[Nawar Jameel]

Hello Everyone,

Hoping you are all well.

I've got the below formula which mainly filter the values (C01, C02, P01, P02, etc) available in column C based on the values in column A.

=IFERROR(TRANSPOSE(UNIQUE(FILTER(Raw_Data!$C$2:$C$50000,Raw_Data!$A$2:$A$50000='001200_Dwg_Trckr'!A16))),"")

I need this filter to start first with the P0s before the C0s.

Any ideas please.

Much appreciated.


Kind regards,

Nawar Jameel

 

[SunnyAlv]

so u just wanna sort the value ?

 

[Fluff]

Can you post some sample data, along with expected results.

MrExcel has a tool called “XL2BB” that lets you post samples of your data that will allow us to copy/paste it to our Excel spreadsheets, so we can work with the same copy of data that you are. Instructions on using this tool can be found here: XL2BB Add-in

Note that there is also a "Test Here” forum on this board. This is a place where you can test using this tool (or any other posting techniques that you want to test) before trying to use those tools in your actual posts.

 

[Nawar Jameel]

Hello

Hoping the below screenshot will meet your requirements

This is the main sheet:

This is the source data sheet / data feed:

 

[Fluff]

Ok, how about

=IFERROR(TRANSPOSE(SORT(UNIQUE(FILTER(Raw_Data!$C$2:$C$50000,Raw_Data!$A$2:$A$50000=A16)),,-1)),"")

 

[Nawar Jameel]

Ok, how about

=IFERROR(TRANSPOSE(SORT(UNIQUE(FILTER(Raw_Data!$C$2:$C$50000,Raw_Data!$A$2:$A$50000=A16)),,-1)),"")

Many thanks for your response.

However, it did partially resolve the problem, as screenshot below:

What actually I need please is as follows:

P01 P02 P03 C01 C02 C03

Or vice-versa as follows:

C03 C02 C01 P03 P02 P01

Is that possible to do please?

Appreciate your kind help.

 

[Fluff]

Try

=LET(u,UNIQUE(FILTER(Raw_Data!$C$2:$C$50000,Raw_Data!$A$2:$A$50000=A16)),IFERROR(TRANSPOSE(SORTBY(u,XMATCH(LEFT(u),{"P","C"}))),""))

 

[Nawar Jameel]

Try

=LET(u,UNIQUE(FILTER(Raw_Data!$C$2:$C$50000,Raw_Data!$A$2:$A$50000=A16)),IFERROR(TRANSPOSE(SORTBY(u,XMATCH(LEFT(u),{"P","C"}))),""))

Brilliant your formula did work perfectly

Many thanks for your kind help mate

 

[Fluff]

You're welcome & thanks for the feedback.